browser.plp

   1 <(common.inc.plp)><:
   2 use List::Util qw(sum max first);
   3 no if $] >= 5.018, warnings => 'experimental::smartmatch';
   4
   5 Html({
   6         title => 'browser compatibility cheat sheet',
   7         version => '1.4',
   8         description => [
   9                 "Compatibility table of new web features (HTML5, CSS3, SVG, Javascript)",
  10                 "comparing support and usage share for all popular browser versions.",
  11         ],
  12         keywords => [qw'
  13                 web browser support compatibility usage matrix available feature
  14                 html html5 css css3 svg javascript js dom mobile
  15                 ie internet explorer firefox chrome safari webkit opera
  16         '],
  17         stylesheet => [qw'circus dark mono red light'],
  18         data => ['data/browser/support.inc.pl'],
  19 });
  20
  21 say "<h1>Browser compatibility</h1>\n";
  22
  23 my $caniuse = do 'data/browser/support.inc.pl' or die $@ || $!;
  24 $_->{verrelease} = {
  25         # mark last three (future) versions as unreleased, ensure current isn't
  26         map {
  27                 $_->[-1] => 0, $_->[-2] => 0, $_->[-3] => 0,
  28                 $_->[-4] => undef,
  29         } $_->{versions}
  30 } for values %{ $caniuse->{agents} };
  31
  32 my %CSTATS = (
  33         'n'   => 'l1',
  34         'n d' => 'l2',
  35         'n x d' => 'l2 ex',
  36         'p d' => 'l2',
  37         'a d' => 'l2',
  38         'y'   => 'l5',
  39         'y x' => 'l5 ex',
  40         'a'   => 'l3',
  41         'a x' => 'l3 ex',
  42         'p j' => 'l2',
  43         'j'   => 'l2',
  44         'p'   => 'l2',
  45         'p p' => 'l2',
  46         'u'   => 'l0',
  47 );
  48 my %DSTATS = (
  49         u => 'unknown',
  50         n => 'unsupported',
  51         p => 'plugin required',
  52         j => 'javascript required',
  53         a => 'partial',
  54         y => 'supported',
  55         d => 'disabled by default',
  56         x => sub {
  57                 join(' ',
  58                         'requires prefix',
  59                         map {"-$_-"}
  60                         ($caniuse->{agents}->{$_[0]}->{prefix_exceptions} // {})->{$_[1]}
  61                         // $caniuse->{agents}->{$_[0]}->{prefix} // (),
  62                 );
  63         },
  64 );
  65 my %PSTATS = (  # score percentage
  66         y => 1,  'y x' => .9,
  67         a => .5, 'a x' => .5, 'a d' => .1,
  68         j => .2, 'p j' => .2, 'n d' => .2, 'n x d' => .2,
  69         p => .2, 'p p' => .2, 'p d' => .1,
  70         n => 0,   u => 0,
  71 );
  72 my %CSTATUS = (
  73         unoff => 'l1', # unofficial
  74         wd    => 'l2', # draft
  75         cr    => 'l3', # candidate
  76         pr    => 'l3', # proposed
  77         rec   => 'l5', # recommendation
  78         ls    => 'l4', # whatwg
  79         ietf  => 'l0', # standard
  80         other => 'l0', # non-w3
  81 );
  82 my %versions;
  83 if (my ($somerow) = values %{ $caniuse->{data} }) {
  84         while (my ($browser, $row) = each %{ $somerow->{stats} }) {
  85                 $versions{$browser} = [ sort { paddedver($a) cmp paddedver($b) } keys %$row ];
  86         }
  87 }
  88
  89 print <<'';
  90 <p id="intro">Alternate rendition of Fyrd's <a href="http://caniuse.com/">when can I use...</a> page
  91
  92 my ($canihas, $usage);
  93 my $minusage = $get{threshold} // .7;
  94 given ($get{usage} // 'wm') {
  95         when (!$_) {
  96                 # none
  97         }
  98         when (!m{ \A [a-z]\w+ (?:/\d[\d-]*\d)? \z }x) {
  99                 printf "<p>Invalid browser usage data request: <em>%s</em>",
 100                         'identifier must be alphanumeric name or <q>0</q>';
 101         }
 102         $canihas = do "data/browser/usage-$_.inc.pl" or do {
 103                 printf "<p>Browser usage data not found: <em>%s</em>", $@ || $!;
 104                 break;
 105         };
 106         $usage = $_;
 107         my $ref = $canihas->{-title} || 'unknown';
 108         $ref = sprintf '<a href="%s">%s</a>', $_, $ref
 109                 for $canihas->{-site} || $canihas->{-source} || ();
 110         $ref .= " $_" for $canihas->{-date} || ();
 111         print "\nwith $ref browser usage statistics";
 112 }
 113
 114 my @browsers;
 115 if ($usage) { # first() does not work inside given >:(
 116         # adapt version usage to actual support data
 117         my %engineuse;  # prefix => usage sum
 118         for my $browser (keys %versions) {
 119                 my $row = $canihas->{$browser} // {};
 120                 my $verlist = $versions{$browser} or next;
 121                 if ($minusage and sum(values %$row) < $minusage) {
 122                         delete $versions{$browser};
 123                         next;
 124                 }
 125                 my %supported = map { $_ => 1 } @$verlist;
 126
 127                 # cascade unknown versions
 128                 $row->{$_} //= undef for @$verlist;  # ensure stable keys during iteration
 129                 while (my ($version, $usage) = each %$row) {
 130                         next if defined $supported{$version};
 131                         my $next = first { paddedver($_) ge paddedver($version) } @$verlist
 132                                 or warn("No fallback found for $browser v$version; $usage% ignored"), next;
 133                         $row->{$next} += $usage;
 134                         $row->{$version} = 0;  # balance browser total
 135                 }
 136
 137                 # build row list for each version
 138                 if ($minusage) {
 139                         my @vershown;  # $verlist replacement
 140                         my ($rowusage, @verrow) = (0);  # replacement row tracking
 141                         for (@$verlist) {
 142                                 push @verrow, $_;  # queue each version
 143                                 if (($rowusage += $row->{$_}) >= $minusage) {
 144                                         push @vershown, [@verrow];   # add row
 145                                         ($rowusage, @verrow) = (0);  # reset row tracking
 146                                 }
 147                         }
 148                         push @vershown, \@verrow if @verrow;  # always add latest
 149                         @$verlist = @vershown;
 150                 }
 151                 else {
 152                         @$verlist = map { [$_] } @$verlist;
 153                 }
 154
 155                 # reusable aggregates (grouped by prefix (engine) and browser)
 156                 $engineuse{ $caniuse->{agents}->{$browser}->{prefix} } +=
 157                 $row->{-total} = sum(values %$row);
 158         }
 159
 160         # order browser columns by usage grouped by engine
 161         @browsers = sort {
 162                 $engineuse{ $caniuse->{agents}->{$b}->{prefix} } <=>
 163                 $engineuse{ $caniuse->{agents}->{$a}->{prefix} }
 164                         ||
 165                 $canihas->{$b}->{-total} <=> $canihas->{$a}->{-total}
 166         } keys %versions;
 167 }
 168 else {
 169         # order browser columns by name grouped by engine
 170         @{$_} = map { [$_] } @{$_} for values %versions;
 171         @browsers = sort {
 172                 $caniuse->{agents}->{$b}->{prefix} cmp
 173                 $caniuse->{agents}->{$a}->{prefix}
 174                         ||
 175                 $a cmp $b
 176         } keys %versions;
 177 }
 178 :>.
 179 </p>
 180
 181 <:
 182 $canihas ||= {
 183         map {
 184                 $_ => +{
 185                         map {
 186                                 my $zero = $#$_ - 2;  # baseline index
 187                                 ($_->[$zero - 2] =>  .5), # past
 188                                 ($_->[$zero - 1] => 10 ), # previous
 189                                 ($_->[$zero + 2] =>  0 ), # future
 190                                 ($_->[$zero + 1] =>  .5), # next
 191                                 ($_->[$zero    ] => 30 ), # current
 192                         } $caniuse->{agents}->{$_}->{versions}
 193                 }
 194         } @browsers
 195 }; # fallback hash based on release semantics
 196 my $usagemax = (max(map { ref $_ eq 'HASH' && sum(values %$_) } values %$canihas) // 1) / 100;
 197
 198 my $usagepct = 1;  # score multiplier for 0..100 result
 199 # normalise usage percentage to only include shown browsers
 200 $usagepct = 100.01 / featurescore({  # yes for every possible version
 201         map { $_ => { map {$_ => 'y'} map { @{$_} } @{$versions{$_}} } } keys %versions
 202 });
 203
 204 print '<table class="mapped">';
 205 print '<col span="3">';  # should match first thead row
 206 printf '<colgroup span="%d">', scalar @{ $versions{$_} } for @browsers;
 207 say '</colgroup><col>';
 208
 209 my $header = join('',
 210         '<tr>',
 211         '<th colspan="3" rowspan="2">feature',
 212         (map {
 213                 my $name = $caniuse->{agents}->{$_}->{browser};
 214                 sprintf('<th colspan="%d" class="%s" title="%s">%s',
 215                         scalar @{ $versions{$_} },
 216                         join(' ', map {"b-a-$_"} grep {$_}
 217                                 $_, @{ $caniuse->{agents}->{$_} }{'prefix', 'type'},
 218                         ),
 219                         join(' ',
 220                                 sprintf('%.1f%%', $canihas->{$_}->{-total} * $usagepct),
 221                                 $name,
 222                         ),
 223                         do {
 224                                 length $name <= (3 * @{ $versions{$_} }) ? $name
 225                                         : $caniuse->{agents}->{$_}->{abbr};
 226                         },
 227                 )
 228         } @browsers),
 229         '<th rowspan="2">%',
 230 );
 231 print '<thead>', $header;
 232 # preceding row without any colspan to work around gecko bug
 233 print "\n<tr>";
 234 for my $browser (@browsers) {
 235         for (@{ $versions{$browser} }) {
 236                 my $lastver = $_->[-1];
 237                 my $release = $caniuse->{agents}->{$browser}->{verrelease}->{$lastver};
 238                 my $future = defined $release;
 239                 printf('<td title="%s"%s>%s',
 240                         join(' ',
 241                                 sprintf('%.1f%%', sum(@{ $canihas->{$browser} }{@$_}) * $usagepct),
 242                                 $future ? 'development' : (),
 243                                 'version ' . join(', ', @{$_}),
 244                         ),
 245                         $future && ' class="ex"',
 246                         showversions($lastver),
 247                 );
 248         }
 249 }
 250 say '</thead>';
 251 say '<tfoot>', $header;
 252 {
 253         # prefix indicates browser family; count adjacent families
 254         my (@families, %familycount);
 255         for my $browser (@browsers) {
 256                 my $family = $caniuse->{agents}->{$browser}->{prefix};
 257                 push @families, $family unless $familycount{$family};
 258                 $familycount{$family} += @{ $versions{$browser} };
 259         }
 260
 261         print "\n", '<tr class="cat">';
 262         printf '<th colspan="%d">%s', $familycount{$_}, $_ for @families;
 263 }
 264 say '</tfoot>';
 265
 266 sub featurescore {
 267         # relative amount of support for given feature
 268         my $rank = 0;
 269         if (my $row = shift) {
 270                 if ($canihas) {
 271                         while (my ($browser, $versions) = each %$row) {
 272                                 ref $versions eq 'HASH' or next;
 273                                 while (my ($version, $status) = each %$versions) {
 274                                         $status =~ s/\h\#\d+//g;
 275                                         $rank += ($canihas->{$browser}->{$version} || .001) * $PSTATS{$status};
 276                                 }
 277                         }
 278                         return $rank;
 279                 }
 280
 281                 while (my ($browser, $vercols) = each %versions) {
 282                         my $div = 0;  # multiplier exponent (decreased to lower value)
 283                         my @vers = map { $row->{$browser}->{$_} } @$vercols;
 284                         if (my $current = $caniuse->{agents}->{$browser}->{versions}->[-3]) {
 285                                 my @future;  # find upcoming releases (after current)
 286                                 for (reverse @$vercols) {
 287                                         last if $_ eq $current;
 288                                         push @future, pop @vers;
 289                                         $_ eq 'u' and $_ = $vers[-1] for $future[-1];  # inherit latest value if unknown
 290                                 }
 291                                 splice @vers, -1, 0, @future;  # move ahead to decrease precedence
 292                         }
 293                         $rank += $PSTATS{$_} * 2**($div--) for reverse @vers;
 294                 }
 295         }
 296         return $rank;
 297 }
 298
 299 sub formatnotes {
 300         my @html = @_;
 301         for (@html) {
 302                 s/\r\n?/\n/g;  # windows returns
 303                 s/\h* $//gmx;  # trailing whitespace
 304                 s/(?<= [^.\n]) $/./gmx;  # consistently end each line by a period
 305                 Entity($_);
 306                 s{  ` ([^`]*)  ` }{<code>$1</code>}gx;
 307                 s{ \[ ([^]]*) \] \( ([^)]*) \) }{<a href="$2">$1</a>}gx;
 308         }
 309         return @html;
 310 }
 311
 312 sub saytitlecol {
 313         my ($id) = @_;
 314         my $row = $caniuse->{data}->{$id};
 315
 316         for ($row->{categories}) {
 317                 my $cell = $_ ? lc $_->[0] : '-';
 318                 $cell =~ s/ api$//;  # trim unessential fluff in 'js api'
 319                 printf '<th title="%s">%s', join(' + ', @$_), $cell;
 320         }
 321
 322         print '<td>', map {
 323                 sprintf('<a href="%s" onclick="%s">%s</a>',
 324                         "#$id",
 325                         sprintf("try { %s; return false } catch(err) { return true }",
 326                                 "document.getElementById('$id').classList.toggle('target')",
 327                         ),
 328                         Entity($_),
 329                 );
 330         } $row->{title};
 331         print '<div class=aside>';
 332         print "<p>$_</p>"
 333                 for formatnotes($row->{description}, $row->{notes} || ());
 334         if (my %notes = %{ $row->{notes_by_num} }) {
 335                 say '<p>Browser-specific notes:';
 336                 say "<br>#$_: ", formatnotes($notes{$_}) for sort keys %notes;
 337                 say '</p>';
 338         }
 339         printf 'Resources: %s.', join(', ', map {
 340                 sprintf '<a href="%s">%s</a>', EscapeHTML($_->{url}), EscapeHTML($_->{title})
 341         } @$_) for grep { @$_ } $row->{links} // ();
 342         printf '<br>Parent feature: %s.', join(', ', map {
 343                 sprintf '<a href="%s">%s</a>', EscapeHTML("#$_"), $caniuse->{data}->{$_}->{title}
 344         } $_) for $row->{parent} || ();
 345         print '</div>';
 346 }
 347
 348 sub saystatuscol {
 349         my ($id) = @_;
 350         my $row = $caniuse->{data}->{$id};
 351
 352         for ($row->{status}) {
 353                 my $cell = $_ // '-';
 354                 $cell = sprintf '<a href="%s">%s</a>', $_, $cell for $row->{spec} // ();
 355                 printf '<td title="%s" class="l %s">%s',
 356                         $caniuse->{statuses}->{$_}, $CSTATUS{$_} // '', $cell;
 357         }
 358 }
 359
 360 sub saybrowsercols {
 361         my ($id, $browser) = @_;
 362         my $feature = $caniuse->{data}->{$id};
 363         my $data = $feature->{stats}->{$browser};
 364         if (ref $data eq 'ARRAY') {
 365                 # special case for unsupported
 366                 my $release = $caniuse->{agents}->{$browser}->{verrelease};
 367                 $data = {
 368                         map { $_ => defined $release->{$_} ? 'u' : 'n' } keys %$release
 369                 };
 370         }
 371
 372         my ($prev, @span);
 373         for my $ver (@{ $versions{$browser} }, undef) {
 374                 my $compare = (
 375                         !defined $ver ? undef :      # last column if nameless
 376                         ref $data ne 'HASH' ? '' :   # unclassified if no support hash
 377                         $data->{ $ver->[-1] } // $prev  # known or inherit from predecessor
 378                         // (grep { defined } @{$data}{ map { $_->[0] } @{ $versions{$browser} } })[0]
 379                            ~~ 'n' && 'n'             # first known version is unsupported
 380                         || 'u'                       # unsure
 381                 );
 382                 unless (!defined $prev or $prev ~~ $compare) {
 383                         my $usage = sum(@{ $canihas->{$browser} }{ map { @{$_} } @span });
 384
 385                         # strip #\d note references from support class
 386                         my @notes;
 387                         push @notes, $feature->{notes_by_num}->{$1}
 388                                 while $prev =~ s/\h \# (\d+) \b//x;
 389
 390                         # prepare version hover details
 391                         my $title = sprintf('%.1f%% %s', $usage * $usagepct, join(', ',
 392                                 map { ref $_ eq 'CODE' ? $_->($browser, $span[0]->[0]) : $_ }
 393                                 map { $DSTATS{$_} // () }
 394                                 map { split / /, $_ }
 395                                 $prev
 396                         ));
 397                         $title .= "\n".EscapeHTML($_) for @notes;
 398
 399                         printf('<td class="%s" colspan="%d" title="%s">%s',
 400                                 join(' ',
 401                                         X => $CSTATS{$prev},
 402                                         !$usage ? ('p0') : ('p',
 403                                                 sprintf('p%01d', $usage * ($usagepct - .0001) / 10),
 404                                                 sprintf('p%02d', $usage * ($usagepct - .0001)),
 405                                         ),
 406                                         sprintf('pp%02d', $usage / $usagemax),
 407                                 ),
 408                                 scalar @span,
 409                                 $title,
 410                                 showversions($span[0]->[0], @span > 1 ? ($span[-1]->[-1]) : ()),
 411                         );
 412                         undef $prev;
 413                         @span = ();
 414                 }
 415                 push @span, $ver && [ grep { $data->{ $_ } eq $data->{ $ver->[-1] } } @{$ver} ];
 416                 $prev = $compare;
 417         }
 418 }
 419
 420 sub sayusagecol {
 421         my ($id) = @_;
 422         print '<td>', int featurescore($caniuse->{data}->{$id}->{stats}) * $usagepct;
 423 }
 424
 425 say '<tbody>';
 426 for my $id (sort {
 427             featurescore($caniuse->{data}->{$b}->{stats})
 428         <=> featurescore($caniuse->{data}->{$a}->{stats})
 429 } keys %{ $caniuse->{data} }) {
 430         $caniuse->{data}->{$id}->{stats} or next;  # skip metadata [summary]
 431         printf '<tr id="%s">', $id;
 432         saytitlecol($id);
 433         saystatuscol($id);
 434         saybrowsercols($id, $_) for @browsers;
 435         sayusagecol($id);
 436         say '</tr>';
 437 }
 438 say '</tbody>';
 439 say '</table>';
 440
 441 sub paddedver {
 442         # normalised version number comparable as string (cmp)
 443         shift =~ /(?:.*-|^)(\d*)(.*)/;
 444         # matched (major)(.minor) of last value in range (a-B)
 445         return sprintf('%02d', $1 || 99) . $2;
 446 }
 447
 448 sub showversions {
 449         my @span = ($_[0], @_>1 ? $_[-1] : ());
 450         s/-.*// for $span[0];
 451         for (@span) {
 452                 s/^\./0./;
 453                 s/x$/.*/;
 454                 s/.*-//;
 455         }
 456         return join('‒', @span);
 457 }
 458
 459 :>
 460 <hr>
 461
 462 <div class="legend">
 463         <table class="glyphs"><tr>
 464         <td class="X l5">supported
 465         <td class="X l3">partial
 466         <td class="X l2">optional
 467         <td class="X l1">missing
 468         <td class="X l0">unknown
 469         <td class="X ex">prefixed
 470         </table>
 471
 472         <p><: if ($usage) { :>
 473                 Usage percentage:
 474                 <span class="  p0">0</span> -
 475                 <span class="p p0 p00">.01</span> -
 476                 <span class="p p0 p05">1-9</span> -
 477                 <span class="p p1">10</span> -
 478                 <span class="p p2">20</span> -
 479                 <span class="p p5">majority</span>
 480 <: } else { :>
 481                 <table class="glyphs"><tr>
 482                         <td class="p p1">previous version</td>
 483                         <td class="p p3">current</td>
 484                         <td class="p p0 p00">upcoming (within months)</td>
 485                         <td class="  p0">future (within a year)</td>
 486                 </table>
 487 <: } :> </p>
 488
 489         <div class="right">
 490                 <ul class="legend legend-set">
 491                 <li>default <strong>style</strong> is
 492                         <:= defined $get{style} && 'set to ' :><em><:= $style :></em>
 493                 <li><strong>usage</strong> source is
 494                         <:= !defined $get{usage} && 'default ' :><:= defined $usage ? "<em>$usage</em>" : 'not included (<em>0</em>)' :>
 495                 <li>usage <strong>threshold</strong> is
 496                         <:= defined $get{threshold} && 'changed to ' :><em><:= $minusage :>%</em>
 497                 </ul>
 498         </div>
 499 </div>
 500
 501 <script type="text/javascript" src="/searchlocal.js"></script>
 502 <script type="text/javascript"> prependsearch(document.getElementById('intro')) </script>
 503