tools/mkdigraphlist

   1 #!/usr/bin/env perl
   2
   3 use strict;
   4 use warnings;
   5 use utf8;
   6
   7 use open OUT => ':utf8', ':std';
   8
   9 our $VERSION = '1.03';
  10
  11 # create a hash of desired input
  12 my $di = do 'data/digraphs-rfc.inc.pl'
  13         or die "error reading digraphs include: ", $@ // $!;
  14
  15 # personal addendums
  16 my $extra = do 'data/digraphs-shiar.inc.pl'
  17         or warn "could not include shiar proposals: ", $@ // $!;
  18 my $vim = do 'data/digraphs-vim.inc.pl'
  19         or warn "could not include vim extensions ", $@ // $!;
  20 $di = { %{$vim // {}}, %{$di}, %{$extra // {}} };
  21
  22 # optionally get unicode character information
  23 my $uninfo = do 'unicode-char.inc.pl'
  24         or warn "could not include unicode details: ", $@ // $!;
  25
  26 # output perl code of hash
  27 # (assume no backslashes or curlies, so we can just q{} w/o escaping)
  28 print "# automatically generated by $0\n";
  29 print "use utf8;\n";
  30 print "+{\n";
  31 printf '(map {$_=>0} qw{%s}),'."\n", join(' ',
  32         grep { !defined $di->{$_} }
  33         map { substr($_, 1, 1).substr($_, 0, 1) } sort keys %{$di}
  34 );
  35 printf "q{%s}=>[%s],\n", $_, join(',',
  36         $di->{$_},   # original code point
  37         map {"'$_'"}
  38         $uninfo->{ chr $di->{$_} }->[1],  # name
  39         $uninfo->{ chr $di->{$_} }->[0],  # class
  40         (map {('', $_)} $uninfo->{ chr $di->{$_} }->[4] // ()),  # string
  41 ) for sort keys %{$di};
  42 print "}\n";
  43
  44 __END__
  45
  46 =head1 NAME
  47
  48 mkdigraphlist - Output character list of combined digraph data
  49
  50 =head1 SYNOPSIS
  51
  52     mkdigraphlist >digraphs.inc.pl
  53     perl -e'$di = do "digraphs.inc.pl"; print chr $di->{DO}->[0]'
  54
  55 =head1 DESCRIPTION
  56
  57 Combines precompiled digraph includes of rfc (1345), vim, and shiar
  58 and outputs a complete map including character details and usage classes.
  59
  60 The value can either be a scalar string containing another
  61 digraph which can be considered identical (usually inverted),
  62 or an array ref containing at least the resulting character's
  63 Unicode code point value.  If available, the following UCD data
  64 is appended: character name, category, script, and output string.
  65 For example:
  66
  67  +{
  68    AE => [198, 'LATIN CAPITAL LETTER AE', 'Lu Xl', 'Latin'],
  69    EA => 'AE',
  70   }
  71
  72 =head1 AUTHOR
  73
  74 Mischa POSLAWSKY <perl@shiar.org>
  75
  76 =head1 LICENSE
  77
  78 Licensed under the GNU Affero General Public License version 3.
  79