charset.plp

   1 <(common.inc.plp)><:
   2
   3 Html({
   4         title => 'charset cheat sheet',
   5         version => '1.0',
   6         description => [
   7                 "Reference sheet with all glyphs in common character encoding tables,",
   8                 "and an overview of Unicode ranges and UTF-8 bytes.",
   9         ],
  10         keywords => [qw'
  11                 charset codepage unicode ascii utf8 latin glyph character encoding
  12                 reference common overview table
  13         '],
  14         stylesheet => [qw'light'],
  15         data => [qw(
  16                 charset-encoding.inc.pl
  17                 charset-unicode.inc.pl charset-ucplanes.inc.pl charset-utf8.inc.pl
  18         )],
  19 });
  20
  21 my @tablist = split m{/+}, $Request || 'default';
  22
  23 use List::Util qw( first pairmap pairfirst pairs );
  24
  25 :>
  26 <h1>Character encodings</h1>
  27
  28 <p>
  29 <:
  30 if ($tablist[0] eq 'default') {
  31         say "Overview of Unicode allocation and common latin code pages.";
  32         say "Compare alternate charsets:";
  33 }
  34 else {
  35         say "Charset comparison:";
  36 }
  37
  38 sub optionlink {
  39         my ($title, $href, $selected) = @_;
  40         return sprintf(
  41                 $selected ? '<strong>%s</strong>' : '<a href="%2$s">%s</a>',
  42                 EscapeHTML($title), $href
  43         );
  44 }
  45
  46 print join " •\n", (
  47         map {
  48                 join " ·\n", pairmap {
  49                         optionlink($b || ucfirst $a, '/charset'.($a && "/$a?compare"), $a eq $Request);
  50                 } @{$_}
  51         }
  52         [
  53                 iso      => 'ISO',
  54                 win      => 'Windows',
  55                 dos      => 'DOS',
  56                 mac      => 'Apple',
  57                 ebcdic   => 'EBCDIC',
  58                 $tablist[0] eq 'default' ? () : ('' => 'common'),
  59         ],
  60         [
  61                 westeur  => 'West',
  62                 centeur  => 'Central',
  63                 norteur  => 'North European',
  64                 turkish  => 0,
  65                 greek    => 0,
  66                 cyrillic => 0,
  67                 hebrew   => 0,
  68         ],
  69 );
  70 :>.
  71 </p>
  72
  73 <:
  74 use POSIX qw( ceil );
  75 use Shiar_Sheet::FormatChar;
  76 my $glyphs = Shiar_Sheet::FormatChar->new;
  77 my @request;
  78
  79 my $INHERIT = do 'charset-encoding.inc.pl'
  80         or Alert('Encoding metadata could not be read', $@ || $!);
  81
  82 sub tabinput {
  83         # generate character table(s)
  84         my $input = shift or return;
  85
  86         state $ALIAS = {
  87                 default    => [qw( u+0-27F utf-8+realsize iso-8859-1 iso-8859-15 cp1252 cp437 cp850 )],
  88                 unicode    => [qw( uu+cols=32+realsize u+0-FFF u+1000-18AF u+18B0-1FFF )],
  89                 us         => [qw( cp437 cp863 gsm0338 AdobeStandardEncoding )],
  90                 ebcdic     => [qw( cp37 cp500 cp1047 posix-bc cp1026 cp875 )],
  91                 iso        => [map {"iso-8859-$_"} 1 .. 11, 13 .. 16],
  92                 dos        => [qw( cp437 cp865 cp861 cp860 cp863 cp850 cp857 cp852 cp775
  93                                    cp737 cp869 cp866 cp855 cp862 cp864 )],
  94                 aix        => [qw( cp1006 )],
  95                 win        => [qw( cp1252 cp1250 cp1254 cp1257 cp1258 cp1253 cp1251 cp1255 cp1256 cp874 )],
  96                 mac        => [qw( MacRoman MacRomanian MacRumanian MacCroatian MacCentralEurRoman MacTurkish MacIcelandic MacSami
  97                                    MacGreek MacCyrillic MacHebrew MacArabic MacFarsi MacThai )],
  98
  99                 # languages
 100                 westeur    => [qw( iso-8859-1 iso-8859-15 cp1252 iso-8859-14 cp850 hp-roman8 nextstep MacRoman )],
 101                 centeur    => [qw( iso-8859-2 iso-8859-16 cp1250 cp852 MacRomanian MacCroatian MacCentralEurRoman )], # MacRumanian only for DB
 102                 turkish    => [qw( iso-8859-9 iso-8859-3 cp1254 cp857 MacTurkish )],
 103                 norteur    => [qw( baltic nordic )],
 104                 baltic     => [qw( iso-8859-4 iso-8859-13 cp1257 cp775 )],
 105                 nordic     => [qw( iso-8859-10 cp865 cp861 MacIcelandic MacSami )],
 106                 cyrillic   => [qw( koi8-r koi8-u koi8-f iso-8859-5 cp1251 MacCyrillic cp866 cp855
 107                                    +400 +2DE0 +A640-A69F +500-52F )], # MacUkrainian is broken
 108                 arabic     => [qw( iso-8859-6 cp1256 MacArabic cp864 cp1006 MacFarsi
 109                                    +600 +8A0-8BF+8E0 +750-77F )],
 110                 greek      => [qw( iso-8859-7 cp1253 MacGreek cp737 cp869  +370 +1F00 )],
 111                 hebrew     => [qw( iso-8859-8 cp1255 MacHebrew cp862  +590 )],
 112                 thai       => [qw( iso-8859-11 cp874 MacThai )],
 113                 vietnamese => [qw( viscii cp1258 MacVietnamese )],
 114                 symbols    => [qw( symbol dingbats MacDingbats wingdings wingdings2 wingdings3 webdings )],
 115
 116                 # iso-code shorthand
 117                 1 => 'westeur',
 118                 2 => 'centeur',
 119                 3 => 'turkish',
 120                 4 => 'baltic',
 121                 5 => 'cyrillic',
 122                 6 => 'arabic',
 123                 7 => 'greek',
 124                 8 => 'hebrew',
 125                 9 => 'turkish',
 126                 10 => 'nordic',
 127                 11 => 'thai',
 128         };
 129         if (my $follow = $ALIAS->{$input}) {
 130                 tabinput($_) for ref $follow ? @{$follow} : $follow;
 131                 return;
 132         }
 133
 134         state $visible = {'' => 1};  # all present tables
 135         my %row = (offset => 0, cols => 16);
 136         my $params = $input =~ s/[+](.*)\z// ? $1 : undef;
 137
 138         if (not defined $params) {
 139                 my @parents = @{ $INHERIT->{$input} || [] };
 140
 141                 if (my ($parent, $part) = pairfirst { defined $visible->{$a} } @parents) {
 142                         $row{parent} = $parent;
 143                         $params = $part;
 144                         $params = 80 unless $visible->{$parent}
 145                                 or ($input eq 'MacCroatian' and defined $visible->{MacRomanian});
 146                 }
 147                 elsif (defined $visible->{ascii}) {
 148                         $row{parent} = $parents[0];
 149                         $params = $parents[1] // 80;
 150                         $params = 80 if hex $params >= 0x80;  # ascii offset at most
 151                 }
 152                 elsif (@parents) {
 153                         $row{parent} = $parents[0];
 154                         $params = $parents[1] if hex $parents[1] == 0;  # apply ascii end
 155                 }
 156                 $visible->{$_} //= 0 for $row{parent} || ();
 157         }
 158
 159         for my $param (split /[+]+/, $params // '') {
 160                 if ($param eq 'realsize') {
 161                         $row{realsize}++;
 162                 }
 163                 elsif ($param =~ m{ \A cols = (\d+) \z }x) {
 164                         $row{cols} = $1;
 165                 }
 166                 elsif ($param =~ m{ \A (?<start> \p{AHex}+) (?: [-] (?<end> \p{AHex}+) )? \z }x) {
 167                         if (defined $row{endpoint}) {
 168                                 # extend earlier range
 169                                 my $skip = int(($row{endpoint} || $row{startpoint}) / $row{cols});
 170                                 for ($skip + 1 .. (hex($+{start}) / $row{cols}) - 1) {
 171                                         $row{skip}->{ $_ * $row{cols} - $row{startpoint} }++;
 172                                 }
 173                         }
 174                         else {
 175                                 $row{startpoint} = hex $+{start};
 176                         }
 177                         $row{endpoint} = hex($+{end} || 0);
 178                 }
 179                 else {
 180                         Alert("Unknown option <q>$param</q> for charset $input");
 181                 }
 182         }
 183
 184         if ($input =~ m{ \A (?:wing|web)dings \d* \z }ix) {
 185                 eval "require Encode::\u$input";
 186         }
 187
 188         if ($input eq '') {
 189                 $row{offset} = delete $row{startpoint};
 190                 $row{set} = 'Unicode characters';
 191                 my $block = $row{offset} >> 8;
 192                 $row{endpoint} ||= ($block + 1 << 8) - 1;
 193                 $block == ($row{endpoint} >> 8) or undef $block;
 194
 195                 $row{table} = join '', map { chr } $row{offset} .. $row{endpoint};
 196                 utf8::upgrade($row{table});  # prevent latin1 output
 197
 198                 $row{endpoint} -= $row{offset};
 199
 200                 if (defined $block) {
 201                         $row{set} = sprintf 'Unicode block U+%02Xxx', $block;
 202                         $row{offset} %= 0x100;
 203                 }
 204         }
 205         elsif (lc $input eq 'uu') {
 206                 $row{cell} = do 'charset-ucplanes.inc.pl'
 207                         or Alert('Table data could not be read', $@ || $!);
 208                 $row{endpoint} ||= 0x3FF;
 209                 $row{set} = 'Unicode planes';
 210         }
 211         elsif (lc $input eq 'u') {
 212                 $row{cell} = do 'charset-unicode.inc.pl'
 213                         or Alert('Table data could not be read', $@ || $!);
 214
 215                 $row{endpoint} ||= 0x1FFF;
 216                 $row{set} = 'Unicode ' . (
 217                         $row{startpoint} <  0x1000 && $row{endpoint} < 0x1000 ? 'BMP' :
 218                         $row{startpoint} >= 0x1000 && $row{endpoint} < 0x2000 ? 'SMP' :
 219                         'allocations'
 220                 );
 221         }
 222         elsif ($input =~ m/^utf-*8$/i) {
 223                 $row{set} = 'UTF-8';
 224                 $row{cell} = do 'charset-utf8.inc.pl'
 225                         or Alert('Table data could not be read', $@ || $!);
 226                 $row{endpoint} = 0xFF;
 227         }
 228         elsif ($row{set} = Encode::resolve_alias($input)) {
 229                 $row{offset} = delete $row{startpoint};
 230                 $row{endpoint} ||= 0xFF;
 231                 if ($row{set} eq 'MacHebrew' or $row{set} eq 'MacThai') {
 232                         # array of possibly multiple characters per code point
 233                         $row{table} = [
 234                                 map { Encode::decode($row{set}, pack 'C*', $_) } $row{offset} .. $row{endpoint}
 235                         ];
 236                 }
 237                 else {
 238                         # ~16x faster than decoding in loop;
 239                         # substr strings is twice as fast as splitting to an array
 240                         $row{table} = Encode::decode($row{set}, pack 'C*', $row{offset} .. $row{endpoint});
 241                 }
 242
 243                 if ($row{set} eq 'cp437') {
 244                         if ($row{offset} <= 0xED and $row{endpoint} >= 0xED) {
 245                                 # replace phi glyph
 246                                 substr($row{table}, 0xED - $row{offset}, 1) = 'ϕ';
 247                         }
 248                         if ($row{offset} < 0x20) {
 249                                 # replace control characters by visible variants
 250                                 my $sub = substr ' ☺☻♥♦♣♠•◘○◙♂♀♪♫☼►◄↕‼¶§▬↨↑↓→←∟↔▲▼', $row{offset};
 251                                 substr($row{table}, 0, length $sub) = $sub;
 252                         }
 253                 }
 254                 elsif ($row{set} eq 'symbol') {
 255                         if ($row{offset} <= 0x60 and $row{endpoint} >= 0x60) {
 256                                 # replace radical extender by closest unicode equivalent
 257                                 substr($row{table}, 0x60 - $row{offset},  1) = '│';
 258                         }
 259                         if ($row{offset} <= 0xBD and $row{endpoint} >= 0xFF) {
 260                                 substr($row{table}, 0xBD - $row{offset},  2) = '⏐⎯'; # arrow extenders
 261                                 substr($row{table}, 0xD2 - $row{offset},  3) = '®©™'; # serif variants
 262                                 substr($row{table}, 0xE0 - $row{offset},  1) = '◊'; # replace lookalike, should match AdobeSymbol
 263                                 substr($row{table}, 0xE2 - $row{offset},  3) = '®©™'; # sans-serif variants
 264                                 substr($row{table}, 0xE6 - $row{offset}, 10) = '⎛⎜⎝⎡⎢⎣⎧⎨⎩⎪';
 265                                 substr($row{table}, 0xF0 - $row{offset},  1) = '€';
 266                                 substr($row{table}, 0xF4 - $row{offset}, 11) = '⎮⌡⎞⎟⎠⎤⎥⎦⎫⎬⎭';
 267                         }
 268                 }
 269
 270                 $row{endpoint} -= $row{offset};
 271
 272                 $visible->{ascii} =  # assume common base
 273                 $visible->{ $row{set} } = 1;
 274         }
 275         else {
 276                 Alert("Encoding <q>$input</q> unknown");
 277                 return;
 278         }
 279         push @request, \%row;
 280 }
 281 tabinput($_) for @tablist;
 282
 283 my $NOCHAR = chr 0xFFFD;
 284
 285 sub range_cell {
 286         my ($info, $offset) = @_;
 287         my $table = $info->{cell} or return;
 288         my $def = $table->{$offset} or return;
 289         my ($len, $class, $name, $title) = @{$def};
 290
 291         my $cols = $info->{cols};
 292         my $colsize = $table->{colsize} || 1;
 293         my $attr = '';
 294         $len /= $colsize;
 295         $name //= $len <= 2 ? 'res' : 'reserved';
 296
 297         if (my $part = ($offset/$colsize - $info->{startpoint}) % $cols) {
 298                 # continued row
 299                 my $rest = $cols - $part;  # remaining
 300                 $rest = $len if $len < $rest; #TODO: optimise
 301                 if ($len -= $rest) {
 302                         # continued on new row
 303                         my @next = ($len * $colsize, "$class joinu");
 304                         my $separate = $cols - $len > $rest;  # columns not on next row
 305                         if ($len > $rest) {
 306                                 # minority remains
 307                                 push @next, $name, $title;
 308                                 $title ||= $name;
 309                                 $name = $separate && '…';
 310                         }
 311                         else {
 312                                 # minority on next row
 313                                 push @next, $separate && '"', $title || $name;
 314                         }
 315                         $table->{$offset + $colsize*$rest} //= \@next;
 316                         $class .= ' joind';
 317                 }
 318                 $len = $rest;
 319         }
 320         elsif (my $rows = int($len / $cols)) {
 321                 # multiple full rows
 322                 my $rowsize = $colsize * $cols;
 323                 if ($len -= $rows * $cols) {
 324                         # partial row remains
 325                         $table->{$offset + $rowsize * $rows} //= [$len*$colsize, "$class joinu", '', $title];
 326                         $class .= ' joind';
 327                 }
 328
 329                 unless ($info->{realsize}) {
 330                         # coalesce multiple rows
 331                         while ($rows > 3) {
 332                                 $info->{skip}->{$offset += $rowsize}++;
 333                                 $rows--;
 334                         }
 335                         if ($rows > 2) {
 336                                 $info->{skip}->{$offset += $rowsize} = 0;
 337                         }
 338                 }
 339
 340                 $attr .= sprintf ' rowspan=%d', $rows;
 341                 $len = $cols;
 342         }
 343
 344         $attr .= sprintf ' colspan=%d', $len unless $len == 1;
 345         $attr .= $1 if $class and $class =~ s/( \w+="[^"]*")//;
 346         $attr .= sprintf ' class="%s"', $class if $class;
 347         $attr .= sprintf ' title="%s"', EscapeHTML($title) if $title;
 348         return "<td$attr>$name\n";
 349 }
 350
 351 for my $row (@request) {
 352         my $cols = $row->{cols};
 353         my $colsize = $row->{cell} && $row->{cell}->{colsize} || 1;
 354         my $coldigits = ceil(log($colsize * $cols) / log(16));  # uniform length of hexadecimal header
 355         my $rowdiv = 16 ** $coldigits;  # row divide for column digits
 356         $rowdiv = 1 if $rowdiv != $cols * $colsize;  # divide only if all columns are matched
 357         my $offset = $row->{startpoint} * $colsize || 0;
 358
 359         printf '<div class="section"><table class="glyphs%s">', !$row->{cell} && ' charmap';
 360         my $title = $row->{set};
 361         $title .= " <aside>(over $_)</aside>"
 362                 for $row->{parent} || ();
 363         printf '<caption>%s</caption>', $title;
 364         print '<col>' x ($cols + 1);
 365         for my $section (qw{thead}) {
 366                 print "<$section><tr><th>", $rowdiv == 1 ? '+' : '↱';
 367                 printf '<th>%0*X', $coldigits, $_ * $colsize for 0 .. $cols - 1;
 368                 print "\n";
 369         }
 370
 371         print '<tbody>';
 372         while ($offset <= $row->{endpoint} * $colsize) {
 373                 if ($row->{skip}->{$offset}) {
 374                         $offset += $cols * $colsize;
 375                         next;
 376                 }
 377
 378                 print '<tr><th>';
 379                 if (defined $row->{skip}->{$offset}) {
 380                         print '⋮';
 381                 }
 382                 else {
 383                         if (my $rowmod = $offset % $rowdiv) {
 384                                 # offset in column units
 385                                 printf '<small>+%X</small>', $rowmod;
 386                         }
 387                         else {
 388                                 # divided row offset
 389                                 printf '%X', ($offset + $row->{offset}) / $rowdiv;
 390                         }
 391                 }
 392                 say '';
 393
 394                 for (1 .. $cols) {
 395                         if ($row->{cell}) {
 396                                 print range_cell($row, $offset);
 397                                 next;
 398                         }
 399
 400                         my $cp = $offset + $row->{offset};
 401                         my $glyph = ref $row->{table} eq 'ARRAY' ? $row->{table}->[$offset] :
 402                                 substr $row->{table}, $offset, 1;
 403                         my ($cell, $name, $class) = $glyph eq $NOCHAR ? () :
 404                                 $glyphs->glyph_html($glyph);
 405
 406                         if (exists $get{compare}) {
 407                                 state $visible = {};
 408                                 $class = (
 409                                         $cp == ord $glyph ? 'l4' :
 410                                         $row->{parent} && $glyph eq
 411                                                 Encode::decode($row->{parent}, pack 'C', $cp) ? 'l3' :
 412                                         !$class ? undef :
 413                                         $visible->{$glyph} ? 'l2' :
 414                                         'l1'
 415                                 );
 416                                 $visible->{$glyph}++;
 417                         }
 418
 419                         say sprintf $class ? '<td title="%s" class="X %s">%s' : '<td title="%s">',
 420                                 $name, $class, $cell;
 421                 }
 422                 continue {
 423                         $offset += $colsize;
 424                 }
 425         }
 426         say '</table></div>';
 427 }
 428
 429 :>
 430 <hr>
 431
 432 <div class="legend">
 433         <table class="glyphs"><tr><: if (exists $get{compare}) { :>
 434         <td class="X l4">unicode
 435         <td class="X l3">inherited
 436         <td class="X l2">existing
 437         <td class="X l1">original
 438         <td class="">unassigned
 439 <: } else { :>
 440         <td class="X Cc">control
 441         <td class="X Zs"><span>whitespace</span>
 442         <td class="X Mn">diacritic<table class="glyphs"><tr>
 443                 <td class="X Sk">letter
 444                 </table>
 445         <td class="X Po">punctuation<table class="glyphs"><tr>
 446                 <td class="X Pf">quote
 447                 </table>
 448         <td class="X So">symbol<table class="glyphs"><tr>
 449                 <td class="X Sm">math
 450                 <td class="X Sc">currency
 451                 </table>
 452         <td class="X No">numeric
 453         <td class="X Greek">greek<table class="glyphs"><tr>
 454                 <td class="X Latin">latin
 455                 <td class="X Cyrillic">cyrillic
 456                 </table>
 457         <td class="X Aramaic">aramaic<table class="glyphs"><tr>
 458                 <td class="X Brahmic">brahmic
 459                 <td class="X Arabic">arabic
 460                 </table>
 461         <td class="X Syllabic">syllabic<table class="glyphs"><tr>
 462                 <td class="X African">african
 463                 <td class="X Hiragana">japanese
 464                 <td class="X Han">cjk
 465                 <td class="X Bopomofo">chinese
 466                 </table>
 467         <td class="X Alpha">alphabetic
 468         </table>
 469
 470         <table class="glyphs"><tr>
 471         <td class="X">unicode 7.0
 472         <td class="X Xr">proposed
 473         <td class="X Xd">deprecated
 474         <td class="">unassigned
 475         <td class="X Xi">invalid
 476 <: } :> </table>
 477 </div>
 478