termcol.plp

   1 <:
   2 use utf8;
   3 use strict;
   4 use warnings;
   5 use open IO => ':utf8';
   6 use List::Util 'min';
   7
   8 our $VERSION = 'v1.0';
   9
  10 $header{content_type} = 'text/html; charset=utf-8';
  11
  12 :><!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN"
  13  "http://www.w3.org/TR/html4/loose.dtd">
  14 <html>
  15
  16 <head>
  17 <title>terminal colour cheat sheet</title>
  18 <meta http-equiv="content-type" content="utf-8">
  19 <link rel="stylesheet" type="text/css" media="all" href="/base.css">
  20 </head>
  21
  22 <body id="colour">
  23 <h1>Terminal colours</h1>
  24
  25 <ul>
  26 <:
  27 sub luminance {
  28         # perceived brightness (using ITU-R recommendation 601 luma co-efficients)
  29         my ($r, $g, $b) = @_;
  30         return $r*.299 + $g*.587 + $b*.114;
  31 }
  32
  33 sub colcell {
  34         my $id = shift;
  35         my @rgb = @_ >= 3 ? @_ : (map {hex} $_[0] =~ /(..)/g);
  36         my $rgb24 = '';
  37         $rgb24 .= sprintf '%X', min($_ / 17 + .5, 15) for @rgb[0..2];
  38         my $rgb48 = '';
  39         $rgb48 .= sprintf '%02X', $_ for @rgb[0..2];
  40         my $inverse = sprintf('%X', luminance(@rgb)/255 < .3 ? 12 : 0) x 3;
  41         return sprintf '<td style="%s; padding:0 1ex">%s<td style="%s">%s<td style="%s">%s'."\n",
  42                 "background:#$rgb48; color:#$inverse",
  43                 $id,
  44                 "background:#000; color:#$rgb48",
  45                 $rgb24,
  46                 "background:#FFF; color:#$rgb48",
  47                 $rgb24,
  48 }
  49
  50 my %col = (
  51         -name => [
  52                 qw/black maroon green olive  navy purple  cyan silver
  53                    gray  red    lime  yellow blue fuchsia aqua white/,
  54                 qw/reset bold dim italic underline blink fastblink
  55                    reverse hidden/,
  56         ],
  57         html => [
  58                 qw/000000 CCCCCC/,
  59                 qw/000000 800000 008000 808000 000080 800080 008080 C0C0C0
  60                    808080 FF0000 00FF00 FFFF00 0000FF FF00FF 00FFFF FFFFFF/,
  61         ],
  62         cga => [
  63                 qw/000000 CCCCCC/,
  64                 qw/000000 AA0000 00AA00 AA5500 0000AA AA00AA 00AAAA AAAAAA
  65                    555555 FF5555 55FF55 FFFF55 5555FF FF55FF 55FFFF FFFFFF/,
  66         ],
  67         xterm => [
  68                 qw/000000 CCCCCC/,
  69                 qw/000000 CC0000 00CC00 CCCC00 4682B4 CC00CC 00CCCC E5E5E5
  70                    4C4C4C FF0000 00FF00 FFFF00 1E90FF FF00FF 00FFFF FFFFFF/,
  71         ],
  72         tango => [
  73                 qw/000000 CCCCCC/,
  74                 qw/2E3436 CC0000 4E9A06 C4A000 3465A4 75507B 06989A D3D7CF
  75                    555753 EF2929 8AE234 FCE94F 729FCF AD7FA8 34E2E2 EEEEEC/,
  76         ],
  77 );
  78
  79 for my $term (qw/html cga xterm tango/) {
  80         print '<li>', "\n";
  81         print '<table>', "\n";
  82         print "<caption>$term</caption>\n";
  83         for my $num (0 .. 15) {
  84                 my $rgb = $col{$term}[$num + 2];
  85                 print '<tr>',
  86                         colcell($term eq 'html' ? $col{-name}[$num] : $num, $rgb, $col{$term}[0]);
  87         }
  88         print "</table></li>\n\n";
  89 }
  90 :></ul>
  91
  92 <hr>
  93 <h2>88-colour space</h2><ul>
  94 <:
  95 for my $r (0 .. 3) {
  96         print '<li><table>';
  97         for my $g (0 .. 3) {
  98                 print '<tr>';
  99                 for my $b (0 .. 3) {
 100                         print colcell($r*4*4 + $g*4 + $b + 16, map {(0, 139, 205, 255)[$_]} $r, $g, $b);
 101                 }
 102         }
 103         print "</table>\n";
 104 }
 105 print "\n";
 106
 107 print '<li><table><tr>', map { colcell(80, ($_) x 3) } 46, 92, 115, 139, 162, 185, 208, 231;
 108 print "</table>\n\n";
 109 :></li>
 110 </ul>
 111
 112 <hr>
 113 <h2>256-colour space</h2><ul>
 114 <:
 115 for my $r (0 .. 5) {
 116         print '<li><table>';
 117         for my $g (0 .. 5) {
 118                 print '<tr>';
 119                 for my $b (0 .. 5) {
 120                         print colcell($r*6*6 + $g*6 + $b + 16, map { $_ && $_*40 + 55 } $r, $g, $b);
 121                 }
 122         }
 123         print "</table>\n";
 124 }
 125 print "\n";
 126
 127 print '<li><table><tr>', (map { colcell(232+$_, ($_*10 + 8) x 3) } $_ .. $_+11), "</table>\n"
 128         for 0, 12;
 129 print "\n";
 130 :></li>
 131 </ul>
 132
 133 <hr>
 134
 135 <p class="footer">
 136         <a href="/" rel="home">sheet.shiar.nl</a>/termcol
 137         <a href="git://git.shiar.nl/sheet" rel="vcs-git" title="Git repository"><:= $VERSION :></a>
 138         created by <a href="http://shiar.nl/" rel="author">Shiar</a> •
 139         <a title="Licensed under the GNU Affero General Public License, version 3" rel="copyright"
 140            href="http://www.fsf.org/licensing/licenses/agpl-3.0.html">AGPLv3</a>
 141 </p>
 142
 143 </html>