charset.plp

   1 <(common.inc.plp)><:
   2
   3 Html({
   4         title => 'charset cheat sheet',
   5         version => '1.0',
   6         description => [
   7                 "Reference sheet with all glyphs in common character encoding tables,",
   8                 "and an overview of Unicode ranges and UTF-8 bytes.",
   9         ],
  10         keywords => [qw'
  11                 charset codepage unicode ascii utf8 latin glyph character encoding
  12                 reference common overview table
  13         '],
  14         stylesheet => [qw'light'],
  15         data => [qw'charset-unicode.inc.pl charset-utf8.inc.pl'],
  16 });
  17
  18 my @tablist = split m{/+}, $Request || 'default';
  19
  20 use List::Util qw( first pairmap pairfirst pairs );
  21
  22 :>
  23 <h1>Character encodings</h1>
  24
  25 <p>
  26 <:
  27 if ($tablist[0] eq 'default') {
  28         say "Overview of Unicode allocation and common latin code pages.";
  29         say "Compare alternate charsets:";
  30 }
  31 else {
  32         say "Charset comparison:";
  33 }
  34
  35 sub optionlink {
  36         my ($title, $href, $selected) = @_;
  37         return sprintf(
  38                 $selected ? '<strong>%s</strong>' : '<a href="%2$s">%s</a>',
  39                 EscapeHTML($title), $href
  40         );
  41 }
  42
  43 print join " •\n", (
  44         map {
  45                 join " ·\n", pairmap {
  46                         optionlink($b || ucfirst $a, "/charset/$a?compare", $a eq $Request);
  47                 } @{$_}
  48         }
  49         [
  50                 iso      => 'ISO',
  51                 dos      => 'DOS',
  52                 mac      => 'Apple',
  53                 ebcdic   => 'EBCDIC',
  54         ],
  55         [
  56                 westeur  => 'West',
  57                 centeur  => 'Central',
  58                 norteur  => 'North European',
  59                 turkish  => 0,
  60                 greek    => 0,
  61                 cyrillic => 0,
  62                 hebrew   => 0,
  63         ],
  64         [ uc => 'Unicode' ],
  65 );
  66 :>.
  67 </p>
  68
  69 <:
  70 use POSIX qw( ceil );
  71 use Shiar_Sheet::FormatChar;
  72 my $glyphs = Shiar_Sheet::FormatChar->new;
  73 my @request;
  74
  75 sub tabinput {
  76         # generate character table(s)
  77         my $input = shift or return;
  78
  79         state $ALIAS = {
  80                 default    => [qw( unicode+0-639 utf-8 iso-8859-1 iso-8859-15 cp1252 cp437 cp850 )],
  81                 uc         => [qw( U++ unicode+0-4095 unicode+4096-6319  unicode+6320-8191 )],
  82                 us         => [qw( cp437 cp863 gsm0338 AdobeStandardEncoding )],
  83                 ebcdic     => [qw( cp37 cp500 cp1047 posix-bc cp1026 cp875 )],
  84                 iso        => [map {"iso-8859-$_"} 1 .. 11, 13 .. 16],
  85                 dos        => [qw( cp437 cp865 cp861 cp860 cp863 cp850 cp857 cp852 cp775
  86                                    cp737 cp869 cp866 cp855 cp862 cp864 )],
  87                 aix        => [qw( cp1006 )],
  88                 win        => [qw( cp1252 cp1250 cp1254 cp1257 cp1258 cp1253 cp1251 cp1255 cp1256 cp874 )],
  89                 mac        => [qw( MacRoman MacRomanian MacRumanian MacCroatian MacCentralEurRoman MacTurkish MacIcelandic MacSami
  90                                    MacGreek MacCyrillic MacHebrew MacArabic MacFarsi MacThai )],
  91
  92                 # languages
  93                 westeur    => [qw( iso-8859-1 iso-8859-15 cp1252 iso-8859-14 cp850 hp-roman8 nextstep MacRoman )],
  94                 centeur    => [qw( iso-8859-2 iso-8859-16 cp1250 cp852 MacRomanian MacCroatian MacCentralEurRoman )], # MacRumanian only for DB
  95                 turkish    => [qw( iso-8859-9 iso-8859-3 cp1254 cp857 MacTurkish )],
  96                 norteur    => [qw( baltic nordic )],
  97                 baltic     => [qw( iso-8859-4 iso-8859-13 cp1257 cp775 )],
  98                 nordic     => [qw( iso-8859-10 cp865 cp861 MacIcelandic MacSami )],
  99                 cyrillic   => [qw( koi8-r koi8-u koi8-f iso-8859-5 cp1251 MacCyrillic cp866 cp855
 100                                    U4 U2DE-2DF UA64-A69 U50-52 )], # MacUkrainian is broken
 101                 arabic     => [qw( iso-8859-6 cp1256 MacArabic cp864 cp1006 MacFarsi
 102                                    U6 U8A-8F+0-31+64 U75-77 )],
 103                 greek      => [qw( iso-8859-7 cp1253 MacGreek cp737 cp869  U37-3F U1F )],
 104                 hebrew     => [qw( iso-8859-8 cp1255 MacHebrew cp862  U59-5F )],
 105                 thai       => [qw( iso-8859-11 cp874 MacThai )],
 106                 vietnamese => [qw( viscii cp1258 MacVietnamese )],
 107                 symbol     => [qw( symbol dingbats MacDingbats AdobeZdingbat AdobeSymbol )],
 108
 109                 # iso-code shorthand
 110                 1 => 'westeur',
 111                 2 => 'centeur',
 112                 3 => 'turkish',
 113                 4 => 'baltic',
 114                 5 => 'cyrillic',
 115                 6 => 'arabic',
 116                 7 => 'greek',
 117                 8 => 'hebrew',
 118                 9 => 'turkish',
 119                 10 => 'nordic',
 120                 11 => 'thai',
 121         };
 122         if (my $follow = $ALIAS->{$input}) {
 123                 tabinput($_) for ref $follow ? @{$follow} : $follow;
 124                 return;
 125         }
 126
 127         state $visible = {};  # all present tables
 128         my %row = (offset => 0, cols => 16);
 129         my $endpoint = 255;
 130         my $params = $input =~ s/[+](.*)\z// ? $1 : undef;
 131
 132         if (not defined $params) {
 133                 state $INHERIT = {
 134                         'cp437'       => ['cp850' => 0, 'ascii' => '0-31+128'], # ascii range overridden later
 135                         'gsm0338'     => ['ascii' => '0-127'],
 136
 137                         'iso-8859-2'  => ['iso-8859-1' => '160'],
 138                         'iso-8859-3'  => ['iso-8859-1' => '160'], #TODO: also apply to iso-8859-9
 139                         'iso-8859-4'  => ['iso-8859-2' => '160'],
 140                         'iso-8859-5'  => ['iso-8859-1' => '160'],
 141                         'iso-8859-6'  => ['cp1256' => '128', 'iso-8859-1' => '160'],
 142                         'iso-8859-7'  => ['iso-8859-1' => '160'],
 143                         'iso-8859-8'  => ['iso-8859-1' => '160'],
 144                         'iso-8859-9'  => ['iso-8859-1' => '208-223+240'],
 145                         'iso-8859-10' => ['iso-8859-4' => '160'],
 146                         'iso-8859-11' => ['iso-8859-1' => '160'],
 147                         'iso-8859-13' => ['iso-8859-4' => '160'],
 148                         'iso-8859-14' => ['iso-8859-1' => '160'],
 149                         'iso-8859-15' => ['iso-8859-1' => '160-191'],
 150                         'iso-8859-16' => ['iso-8859-2' => '160'],
 151                         'hp-roman8'   => ['iso-8859-1' => '160'],
 152
 153                         'cp1252'      => ['iso-8859-1' => '128-159'],
 154                         'cp1250'      => ['iso-8859-2' => '128-191', 'cp1252' => '128'],
 155                         'cp1254'      => ['iso-8859-9' => '128-159', 'cp1252' => '128-159+208'],
 156                         'cp874'       => ['iso-8859-11' => '128-159', 'cp1252' => '128'], # windows-874 actually cp1162
 157                         'cp1257'      => ['iso-8859-13' => '128-159+255', 'cp1252' => '128'],
 158                         'cp1251'      => ['cp1252' => '128'],
 159                         'cp1253'      => ['cp1252' => '128'],
 160                         'cp1255'      => ['iso-8859-8' => '128-223', 'cp1252' => '128'],
 161                         'cp1256'      => ['cp1252' => '128'],
 162                         'cp1258'      => ['cp1252' => '128-159+192'],
 163
 164                         'cp850'       => ['cp437' => '144'],
 165                         'cp860'       => ['cp437' => '128-175'],
 166                         'cp861'       => ['cp865' => '128-175'],
 167                         'cp863'       => ['cp437' => '128-175'],
 168                         'cp865'       => ['cp437' => '144-175'],
 169                         'cp852'       => ['cp850' => '128', 'cp437' => '128'],
 170                         'cp857'       => ['cp850' => '128-175+208-239', 'cp437' => '128'],
 171                         'cp775'       => ['cp850' => '128'],  # partial cp437
 172                         'cp866'       => ['cp437' => '128-175+224'],
 173                         'cp855'       => ['cp437' => '128'],
 174                         'cp1006'      => ['iso-8859-6' => '160', 'cp437' => '128'],
 175                         'cp737'       => ['cp437' => '128-175+224'],
 176                         'cp869'       => ['cp437' => '128'],
 177                         'cp862'       => ['cp437' => '128-159'],
 178                         'cp864'       => ['MacArabic' => '128', 'iso-8859-6' => '128', 'cp437' => '128'], #TODO: compare form variants
 179
 180                         'koi8-u'      => ['koi8-r' => 128],
 181                         'koi8-f'      => ['koi8-u' => 128],
 182
 183                         'MacRomanian' => ['MacRoman' => '160-191+208-223'],
 184                         'MacRumanian' => ['MacRomanian' => '160-191+208-223', 'MacRoman' => '160-191+208-223'],
 185                         'MacCroatian' => ['MacRoman' => '160'],
 186                         'MacCentralEurRoman' => ['MacRoman' => '128'],
 187                         'MacIcelandic'=> ['MacRoman' => '160-175+208-239'], #TODO: gaps at C/E
 188                         'MacTurkish'  => ['MacRoman' => '208-223'], # F5 is unassigned
 189                         'MacSami'     => ['MacIcelandic' => '144', 'MacRoman' => '144'],
 190                         'MacGreek'    => ['MacRoman' => '128'],
 191                         'MacCyrillic' => ['MacRoman' => '128'],
 192                         'MacHebrew'   => ['iso-8859-8' => '128', 'MacRoman' => '128-143+160'], # partial ascii
 193                         'MacArabic'   => ['iso-8859-6' => '128', 'cp864' => '128', 'MacRoman' => '128'], #TODO: multiple parents
 194                         'MacFarsi'    => ['MacArabic' => '176-191', 'MacRoman' => '128'],
 195
 196                         'cp37'        => ['posix-bc' => '0'],
 197                         'posix-bc'    => ['cp1047' => '64'],
 198                         'cp500'       => ['cp37' => '64-95+176-191'],
 199                         'cp1047'      => ['cp37' => '16-95+160-191'], #TODO: gap at 3/4
 200                         'cp1026'      => ['cp37' => '64'],
 201                         'cp875'       => ['cp37' => '48'],
 202
 203                 };
 204
 205                 my @parents = @{ $INHERIT->{$input} || [] };
 206
 207                 if (my ($parent, $part) = pairfirst { defined $visible->{$a} } @parents) {
 208                         $row{parent} = $parent;
 209                         $params = $part;
 210                         $params = 128 unless $visible->{$parent}
 211                                 or ($input eq 'MacCroatian' and defined $visible->{MacRomanian});
 212                 }
 213                 elsif (defined $visible->{ascii}) {
 214                         $row{parent} = $parents[0];
 215                         $params = $parents[1] // 128;
 216                         $params = 128 if $params >= 128;  # ascii offset at most
 217                 }
 218                 elsif (@parents) {
 219                         $row{parent} = $parents[0];
 220                         $params = $parents[1] if $parents[1] == 0;  # apply ascii end
 221                 }
 222                 $visible->{$_} //= 0 for $row{parent} || ();
 223         }
 224
 225         if (length $params) {
 226                 # manual option to double table width
 227                 $row{cols} *= 2 if $params =~ s/[+]\z//;
 228         }
 229
 230         if (length $params) {
 231                 $params =~ m{
 232                         \A (?<offset> \d+)
 233                         (?: (?: [-] (?<stop> \d+) )? (?: [+] (?<restart> \d+) ) )?
 234                         (?: [-] (?<endpoint> \d+) )? \z
 235                 }x or Alert([
 236                         "Unknown range parameters for $input",
 237                         "<q>$params</q> is not in format start(-stop)(+restart(-end))",
 238                 ]);
 239
 240                 $row{offset} = $+{offset};
 241                 $endpoint = $+{endpoint} if $+{endpoint};
 242                 if (my $restart = $+{restart}) {
 243                         my $skip = int(($+{stop} || $row{offset}) / $row{cols});
 244                         for ($skip + 1 .. ($restart / $row{cols}) - 1) {
 245                                 $row{skip}->{ $_ * $row{cols} - $row{offset} }++;
 246                         }
 247                 }
 248         }
 249
 250         if ($input =~ /^U([0-9a-fA-F]+)(?:-([0-9a-fA-F]+))?/) {
 251                 my $start = hex($1) << ($2 ? 4 : 8);
 252                 my $end = $2 ? (hex($2) << 4) + $row{cols} - 1 : $start + 255;
 253                 $row{table} = join '', map { chr } $start .. $end;
 254                 utf8::upgrade($row{table});  # prevent latin1 output
 255                 $row{endpoint} = $end - $start;
 256                 $row{set} = sprintf 'Unicode block U+%02Xxx', $start >> 8;
 257                 $row{offset} = $start % 256;
 258         }
 259         elsif ($input eq 'U') {
 260                 $row{set} = 'Unicode planes';
 261                 $row{cell} = do 'charset-ucplanes.inc.pl'
 262                         or Alert('Table data could not be read', $@ || $!);
 263                 $row{endpoint} = 1023 * $row{cell}->{colsize};
 264         }
 265         elsif ($row{set} = Encode::resolve_alias($input)) {
 266                 if ($row{set} eq 'Internal') {
 267                         $row{cell} = do 'charset-unicode.inc.pl'
 268                                 or Alert('Table data could not be read', $@ || $!);
 269
 270                         $row{endpoint  } = $row{cell}->{colsize} * ($endpoint || 8191);
 271                         $row{startpoint} = $row{cell}->{colsize} * $row{offset};
 272                         $row{offset} = 0;
 273                         $row{set} = 'Unicode ' . (
 274                                 $row{startpoint} <  0x10000 && $row{endpoint} < 0x10000 ? 'BMP' :
 275                                 $row{startpoint} >= 0x10000 && $row{endpoint} < 0x20000 ? 'SMP' :
 276                                 'allocations'
 277                         );
 278                 }
 279                 elsif ($row{set} eq 'utf-8-strict') {
 280                         $row{set} = 'UTF-8';
 281                         $row{cell} = do 'charset-utf8.inc.pl'
 282                                 or Alert('Table data could not be read', $@ || $!);
 283                         $row{endpoint} = 255;
 284                 }
 285                 else {
 286                         if ($row{set} eq 'MacHebrew' or $row{set} eq 'MacThai') {
 287                                 # array of possibly multiple characters per code point
 288                                 $row{table} = [
 289                                         map { Encode::decode($row{set}, pack 'C*', $_) } $row{offset} .. $endpoint
 290                                 ];
 291                         }
 292                         else {
 293                                 # ~16x faster than decoding in loop;
 294                                 # substr strings is twice as fast as splitting to an array
 295                                 $row{table} = Encode::decode($row{set}, pack 'C*', $row{offset} .. $endpoint);
 296                         }
 297                         $row{endpoint} = $endpoint - $row{offset};
 298
 299                         if ($row{set} eq 'cp437' and !$row{offset}) {
 300                                 substr($row{table}, 237, 1) = pack 'U*', 0x3D5; # phi sign
 301                                 substr($row{table}, 0, 32) = pack 'U*', map {hex} qw(
 302                                         2007 263A 263B 2665 2666 2663 2660 2022
 303                                         25D8 25CB 25D9 2642 2640 266A 266B 263C
 304                                         25BA 25C4 2195 203C 00B6 00A7 25AC 21A8
 305                                         2191 2193 2192 2190 221F 2194 25B2 25BC
 306                                 );
 307                         }
 308
 309                         $visible->{ascii} =  # assume common base
 310                         $visible->{ $row{set} } = 1;
 311                 }
 312         }
 313         else {
 314                 Alert("Encoding <q>$input</q> unknown");
 315                 return;
 316         }
 317         push @request, \%row;
 318 }
 319 tabinput($_) for @tablist;
 320
 321 my $NOCHAR = chr 0xFFFD;
 322
 323 sub range_cell {
 324         my ($info, $offset) = @_;
 325         my $table = $info->{cell} or return;
 326         my $def = $table->{$offset} or return;
 327         my ($len, $class, $name, $title) = @{$def};
 328
 329         my $cols = $info->{cols};
 330         my $colsize = $table->{colsize} || 1;
 331         my $attr = '';
 332         $len /= $colsize;
 333         $name //= $len <= 2 ? 'res' : 'reserved';
 334
 335         if (my $part = $offset/$colsize % $cols) {
 336                 # continued row
 337                 my $rest = $cols - $part;  # remaining
 338                 $rest = $len if $len < $rest; #TODO: optimise
 339                 if ($len -= $rest) {
 340                         # continued on new row
 341                         my @next = ($len * $colsize, "$class joinu");
 342                         if ($len > $rest) {
 343                                 # minority remains
 344                                 push @next, $name, $title;
 345                                 $title ||= $name;
 346                                 $name = '';
 347                         }
 348                         else {
 349                                 # minority on next row
 350                                 push @next, '"', $title || $name;
 351                         }
 352                         $table->{$offset + $colsize*$rest} //= \@next;
 353                         $class .= ' joind';
 354                 }
 355                 $len = $rest;
 356         }
 357         elsif (my $rows = int($len / $cols)) {
 358                 # multiple full rows
 359                 my $rowsize = $colsize * $cols;
 360                 if ($len -= $rows * $cols) {
 361                         # partial row remains
 362                         $table->{$offset + $rowsize * $rows} //= [$len*$colsize, "$class joinu", '', $title];
 363                         $class .= ' joind';
 364                 }
 365
 366                 # coalesce multiple rows
 367                 while ($rows > 3) {
 368                         $info->{skip}->{$offset += $rowsize}++;
 369                         $rows--;
 370                 }
 371                 if ($rows > 2) {
 372                         $info->{skip}->{$offset += $rowsize} = 0;
 373                 }
 374
 375                 $attr .= sprintf ' rowspan=%d', $rows;
 376                 $len = $cols;
 377         }
 378
 379         $attr .= sprintf ' colspan=%d', $len unless $len == 1;
 380         $attr .= $1 if $class and $class =~ s/( \w+="[^"]*")//;
 381         $attr .= sprintf ' class="%s"', $class if $class;
 382         $attr .= sprintf ' title="%s"', EscapeHTML($title) if $title;
 383         return "<td$attr>$name";
 384 }
 385
 386 for my $row (@request) {
 387         my $cols = $row->{cols};
 388         my $colsize = $row->{cell} && $row->{cell}->{colsize} || 1;
 389         my $coldigits = ceil(log($colsize * $cols) / log(16));  # uniform length of hexadecimal header
 390         my $rowdiv = 16 ** $coldigits;  # row divide for column digits
 391         $rowdiv = 1 if $rowdiv != $cols * $colsize;  # divide only if all columns are matched
 392         my $offset = $row->{startpoint} || 0;
 393
 394         printf '<div class="section"><table class="glyphs%s">', !$row->{cell} && ' charmap';
 395         my $title = $row->{set};
 396         $title .= " <aside>(over $_)</aside>"
 397                 for grep { $_ ne 'iso-8859-1' } $row->{parent} // ();
 398         printf '<caption>%s</caption>', $title;
 399         print '<col>' x ($cols + 1);
 400         for my $section (qw{thead}) {
 401                 print "<$section><tr><th>", $rowdiv == 1 ? '+' : '↱';
 402                 printf '<th>%0*X', $coldigits, $_ * $colsize for 0 .. $cols - 1;
 403                 print "\n";
 404         }
 405         print '<tbody>';
 406         while ($offset < $row->{endpoint}) {
 407                 if ($row->{skip}->{$offset}) {
 408                         $offset += $cols * $colsize;
 409                         next;
 410                 }
 411
 412                 print '<tr><th>';
 413                 if (defined $row->{skip}->{$offset}) {
 414                         print '⋮';
 415                 }
 416                 else {
 417                         if (my $rowmod = $offset % $rowdiv) {
 418                                 # offset in column units
 419                                 printf '<small>+%X</small>', $rowmod;
 420                         }
 421                         else {
 422                                 # divided row offset
 423                                 printf '%X', ($offset + $row->{offset}) / $rowdiv;
 424                         }
 425                 }
 426                 for (1 .. $cols) {
 427                         if ($row->{cell}) {
 428                                 print range_cell($row, $offset);
 429                                 next;
 430                         }
 431
 432                         my $glyph = ref $row->{table} eq 'ARRAY' ? $row->{table}->[$offset] :
 433                                 substr $row->{table}, $offset, 1;
 434                         if ($glyph eq $NOCHAR) {
 435                                 print '<td>';
 436                                 next;
 437                         }
 438
 439                         if (exists $get{compare}) {
 440                                 state $visible = {};
 441                                 my $cp = $offset + $row->{offset};
 442                                 printf '<td class="%s" title="%3$s">%2$s',
 443                                         $cp == ord $glyph ? 'l4' :
 444                                         $row->{parent} && $glyph eq
 445                                                 Encode::decode($row->{parent}, pack 'C', $cp) ? 'l3' :
 446                                         $visible->{$glyph} ? 'l2' :
 447                                         'l1',
 448                                         $glyphs->glyph_html($glyph);
 449                                 $visible->{$glyph}++;
 450                                 next;
 451                         }
 452
 453                         print "\n".$glyphs->glyph_cell($glyph);
 454                 }
 455                 continue {
 456                         $offset += $colsize;
 457                 }
 458                 print "\n";
 459         }
 460         say '</table></div>';
 461 }
 462
 463 :>
 464 <hr>
 465
 466 <div class="legend">
 467         <table class="glyphs"><tr><: if (exists $get{compare}) { :>
 468         <td class="X l4">unicode
 469         <td class="X l3">inherited
 470         <td class="X l2">existing
 471         <td class="X l1">original
 472         <td class="">unassigned
 473 <: } else { :>
 474         <td class="X Cc">control
 475         <td class="X Zs"><span>whitespace</span>
 476         <td class="X Mn">diacritic<table class="glyphs"><tr>
 477                 <td class="X Sk">letter
 478                 </table>
 479         <td class="X Po">punctuation<table class="glyphs"><tr>
 480                 <td class="X Pf">quote
 481                 </table>
 482         <td class="X So">symbol<table class="glyphs"><tr>
 483                 <td class="X Sm">math
 484                 <td class="X Sc">currency
 485                 </table>
 486         <td class="X No">numeric
 487         <td class="X Greek">greek<table class="glyphs"><tr>
 488                 <td class="X Latin">latin
 489                 <td class="X Cyrillic">cyrillic
 490                 </table>
 491         <td class="X Aramaic">aramaic<table class="glyphs"><tr>
 492                 <td class="X Brahmic">brahmic
 493                 <td class="X Arabic">arabic
 494                 </table>
 495         <td class="X Syllabic">syllabic<table class="glyphs"><tr>
 496                 <td class="X African">african
 497                 <td class="X Hiragana">japanese
 498                 <td class="X Han">cjk
 499                 <td class="X Bopomofo">chinese
 500                 </table>
 501         <td class="X Alpha">alphabetic
 502         </table>
 503
 504         <table class="glyphs"><tr>
 505         <td class="X">unicode 7.0
 506         <td class="X Xr">proposed
 507         <td class="X Xd">deprecated
 508         <td class="">unassigned
 509         <td class="X Xi">invalid
 510 <: } :> </table>
 511 </div>
 512