termcol.plp

   1 <(common.inc.plp)><:
   2
   3 Html({
   4         title => ($Request ? 'terminal colour' : 'colour palettes') . ' cheat sheet',
   5         version => '1.1',
   6         description => [!$Request ? "Comparison of various colour palettes." : (
   7                 "Index of all terminal/console colour codes,",
   8                 "with an example result of various environments.",
   9         )],
  10         keywords => [qw'
  11                 color colour code terminal console escape table xterm rxvt
  12                 ansi vt100 8bit 4bit cga ega vga rgb hsv game emulator display
  13         '],
  14         data => ['termcol.inc.pl'],
  15         stylesheet => [qw'light dark'],
  16 });
  17
  18 my @draw = map { [$_, s/\W+\z//] } grep { $_ } split m(/),
  19         $get{img} // exists $get{img} && 'indi.png';
  20
  21 my @termlist;
  22 push @termlist, split /\W+/, $Request || 'default';
  23
  24 say "<h1>$_</h1>\n" for $Request ? 'Colour palettes' : 'Terminal colours';
  25
  26 say '<p>';
  27 if ("@termlist" eq 'default') {
  28         say '<span title="ECMA-48">ANSI</span> (VT100, ISO-6429) 16-colour text palette';
  29         say 'as implemented by various systems and programs.';
  30         say 'Also see <a href="/termcol/legacy">8-bit legacy hardware</a> palettes.';
  31 }
  32 elsif ("@termlist" eq 'legacy') {
  33         say 'Colour palettes of various 8-bit legacy systems and retro games.';
  34         say 'Also see <a href="/termcol">ANSI console</a> palettes.';
  35 }
  36 else {
  37         say 'Comparison of requested colour palettes.';
  38 }
  39 :>
  40
  41 <div class="section">
  42 <:
  43 use Shiar_Sheet::Colour 1.04;
  44 use List::Util qw( min max );
  45 use POSIX qw( ceil );
  46
  47 my $palettes = do 'termcol.inc.pl';
  48 die "Cannot open palette data: $_\n" for $@ || $! || ();
  49
  50 sub colcell {
  51         my $name = shift // return "<td>\n";
  52         my $col = Shiar_Sheet::Colour->new(@_);
  53         my $minhex = $col->rgb24;
  54         my $css     = '#' . $col->rgb48;
  55         my $inverse = '#' . sprintf('%X', $col->luminance/255 < .3 ? 12 : 0) x 3;
  56
  57         my $sample = [ qw(#000 #FFF) ];
  58         ($name, $sample) = @$name if ref $name eq 'ARRAY';
  59
  60         my $out = sprintf('<td title="%s" style="%s">%s',
  61                 join(',', map { int } @$col),
  62                 "background:$css; color:$inverse",
  63                 $name,
  64         );
  65         $out .= sprintf('<samp style="%s"><small>%s</small></samp>',
  66                 "background:$_; color:$css", $minhex
  67         ) for @$sample;
  68         return "$out\n";
  69 }
  70
  71 sub img_egapal {
  72         my ($palette, $imgfile, $reindex) = @_;
  73         return eval {
  74                 require Imager;
  75                 require MIME::Base64;
  76
  77                 my @imgpal = map { Imager::Color->new(ref $_ ? @$_ : $_) } @{$palette};
  78                 state $imgcache = {};
  79                 my $img = $imgcache->{$imgfile}
  80                         //= Imager->new(file => "data/palimage/$imgfile")
  81                         or die Imager->errstr.$/;
  82
  83                 do {
  84                         if ($reindex) {
  85                                 $img->to_paletted({
  86                                         make_colors => 'none',
  87                                         colors => \@imgpal,
  88                                         translate => 'closest',
  89                                 });
  90                         }
  91                         else {
  92                                 @{[ $img->getcolors ]} == @imgpal
  93                                         or die "incompatible palette size\n";
  94                                 $img->setcolors(colors => \@imgpal);
  95                                 $img;
  96                         }
  97                 }->write(data => \my $imgdata, type => 'png');
  98                 return sprintf '<img src="data:image/png;base64,%s">',
  99                         MIME::Base64::encode_base64($imgdata);
 100         } || $@;
 101 }
 102
 103 sub coltable {
 104         my ($term) = @_;
 105         my $info = $palettes->{$term};
 106
 107         if (ref $info eq 'ARRAY') {
 108                 coltable($_) for @{$info};
 109                 return;
 110         }
 111
 112         if (ref $info eq 'CODE') {
 113                 coltable($_) for $info->($palettes);
 114                 return;
 115         }
 116
 117         ref $info eq 'HASH' or return;
 118
 119         my $caption = $info->{name} // $term;
 120         $caption = sprintf('<%s %s>%s</%1$s>',
 121                 $info->{href} ? 'a' : 'span',
 122                 join(' ',
 123                         map { sprintf '%s="%s"', $_, $info->{$_} }
 124                         grep { defined $info->{$_} }
 125                         qw( href title )
 126                 ),
 127                 $caption,
 128         ) if $info->{href} or $info->{title};
 129
 130         if ($info->{table} or $info->{rgbmap}) {
 131                 say '<table class="color mapped">';
 132                 say sprintf '<caption>%s</caption>', $caption;
 133
 134                 print coltable_hsv(@{$_}) for $info->{rgbmap} || ();
 135
 136                 if (my $table = $info->{table}) {
 137                         for my $row (@$table) {
 138                                 if (!$row) {
 139                                         say '<tbody>';
 140                                         next;
 141                                 }
 142                                 print '<tr>';
 143                                 print colcell(ref $_ ? @$_ : $_ ? reverse split /:/ : undef) for @$row;
 144                         }
 145
 146                         if (@draw) {
 147                                 my $width = scalar @{ $table->[0] };
 148                                 my @imgpal = map {
 149                                         [ ref $_ ? @{$_}[1 .. 3] : map {hex} /(..)(..)(..)/ ]
 150                                 } map { @{$_} } @{$table};
 151                                 for (@draw) {
 152                                         print "<tr><td colspan=$width>", img_egapal(\@imgpal, @{$_});
 153                                 }
 154                         }
 155                 }
 156
 157                 say "</table>\n";
 158         }
 159
 160         if (my $palette = $info->{list}) {
 161                 my $order = $get{order} && $get{order}.'order';
 162                 my $colours = colorder($palette,
 163                         $info->{$order} // $palettes->{ $info->{parent} }->{$order}
 164                 );
 165
 166                 my $rows = 8;
 167                 my $columns = ceil(@{$palette} / $rows);
 168
 169                 say '<table class=color>';
 170                 say sprintf '<caption>%s</caption>', $caption;
 171                 for my $row (0 .. $rows - 1) {
 172                         print '<tr>';
 173                         for my $col (0 .. $columns - 1) {
 174                                 my $num = $row + $col * $rows;
 175                                 my ($rgb, $name) = split /:/, $colours->[$num], 3;
 176                                 $name //= $rgb && $num;
 177                                 $name = [ $name, [] ] if $term =~ /^msx/ and !$num;
 178                                 $name = [ $name, ['#333'] ] if $term eq 'xkcd';
 179                                 print colcell($name, $rgb);
 180                         }
 181                 }
 182
 183                 for (@draw) {
 184                         my $imgpal = colorder($palette,
 185                                 $info->{ansiorder} // $palettes->{ $info->{parent} }->{ansiorder}
 186                         );
 187                         print "<tr><td colspan=$columns>", img_egapal($imgpal, @{$_});
 188                 }
 189                 say "</table>\n";
 190         }
 191 }
 192
 193 sub colorder {
 194         my ($palette, $reorder) = @_;
 195         return [ map { $palette->[$_] =~ s/:(?![^:])|$/:$_/r } @{$reorder} ]
 196                 if $reorder;
 197         return $palette;
 198 }
 199
 200 sub coltable_hsv {
 201         my ($dim, $rgbval, $greyramp) = @_;
 202
 203         my $hmax = 2 * $dim * 3;  # each face of the rgb cube
 204         my $vmax = $dim - 1;
 205         my $smax = $dim - 1;
 206         $rgbval ||= sub { join('', @_), map { int $_ * 255 / $vmax } @_ };
 207
 208         my @greymap = @{$greyramp || []};  # [name, r, g=l, b]
 209         my @colmap;  # saturation => value => hue => [name, r,g,b]
 210
 211         for my $r (0 .. $dim - 1) {
 212                 for my $g (0 .. $dim - 1) {
 213                         for my $b (0 .. $dim - 1) {
 214                                 my @rgb = ($r, $g, $b);
 215
 216                                 my ($h, $s, $v) = Shiar_Sheet::Colour->new(@rgb)->hsv;
 217
 218                                 if (!$s) {
 219                                         if (@greymap) {
 220                                                 push @greymap, [ $rgbval->(@rgb) ];
 221                                                 next;
 222                                         }
 223
 224                                         $h = 1;  # greyscale hue
 225                                         $s = $smax - $v + 1;  # spread brightness over saturation groups
 226                                         $v &&= $smax  # highest saturation
 227                                                 or $v = $s = 1;  # black at initial column
 228                                 }
 229
 230                                 $h *= $hmax;
 231                                 $v = $vmax - $v;
 232                                 $s = $smax - $s - $v;
 233
 234                                 $colmap[$s][$v][$h] = [ $rgbval->(@rgb) ];
 235                         }
 236                 }
 237         }
 238
 239         my $out = '';
 240         $out .= sprintf '<colgroup span=%d>', scalar @{$_} for @colmap;
 241         my $huerow = $colmap[0][0]; # first {$_} map { @{$_} } @colmap;
 242         for my $h (grep { $huerow->[$_] } 0 .. $#{$huerow}) {
 243                 $out .= '<tr>';
 244                 $out .= colcell(@$_) for map { $_->[$h] } map { reverse @{$_} } @colmap;
 245         }
 246
 247         if (@greymap) {
 248                 $out .= '<tbody>';
 249                 my $col = 0;
 250                 my $colbreak = scalar map { @$_ } @colmap;  # same width as hue rows
 251                 for my $cell (sort { $a->[1] <=> $b->[1] || $a->[0] <=> $b->[0] } @greymap) {
 252                         $out .= '<tr>' unless $col++ % $colbreak;
 253                         $out .= colcell(@{$cell});
 254                 }
 255         }
 256
 257         if (@draw) {
 258                 my @palette = map { [ @{$_}[1 .. 3] ] } @greymap, map {@$_} map {@$_} @colmap;
 259                 my $tablespan = scalar map { @$_ } @colmap;
 260                 my $imgdata = img_egapal(\@palette, @{ $draw[0] });
 261                 $out .= "<tr><td colspan=$tablespan>$imgdata";
 262         }
 263
 264         return $out;
 265 }
 266
 267 coltable($_) for @termlist;
 268 :></div>
 269 <hr>
 270