charset.plp

   1 <(common.inc.plp)><:
   2
   3 Html({
   4         title => 'charset cheat sheet',
   5         version => '1.0',
   6         description => [
   7                 "Reference sheet with all glyphs in common character encoding tables,",
   8                 "and an overview of Unicode ranges and UTF-8 bytes.",
   9         ],
  10         keywords => [qw'
  11                 charset codepage unicode ascii utf8 latin glyph character encoding
  12                 reference common overview table
  13         '],
  14         stylesheet => [qw'light'],
  15         data => [qw'charset-unicode.inc.pl charset-ucplanes.inc.pl charset-utf8.inc.pl'],
  16 });
  17
  18 my @tablist = split m{/+}, $Request || 'default';
  19
  20 use List::Util qw( first pairmap pairfirst pairs );
  21
  22 :>
  23 <h1>Character encodings</h1>
  24
  25 <p>
  26 <:
  27 if ($tablist[0] eq 'default') {
  28         say "Overview of Unicode allocation and common latin code pages.";
  29         say "Compare alternate charsets:";
  30 }
  31 else {
  32         say "Charset comparison:";
  33 }
  34
  35 sub optionlink {
  36         my ($title, $href, $selected) = @_;
  37         return sprintf(
  38                 $selected ? '<strong>%s</strong>' : '<a href="%2$s">%s</a>',
  39                 EscapeHTML($title), $href
  40         );
  41 }
  42
  43 print join " •\n", (
  44         map {
  45                 join " ·\n", pairmap {
  46                         optionlink($b || ucfirst $a, '/charset'.($a && "/$a?compare"), $a eq $Request);
  47                 } @{$_}
  48         }
  49         [
  50                 iso      => 'ISO',
  51                 win      => 'Windows',
  52                 dos      => 'DOS',
  53                 mac      => 'Apple',
  54                 ebcdic   => 'EBCDIC',
  55                 $tablist[0] eq 'default' ? () : ('' => 'common'),
  56         ],
  57         [
  58                 westeur  => 'West',
  59                 centeur  => 'Central',
  60                 norteur  => 'North European',
  61                 turkish  => 0,
  62                 greek    => 0,
  63                 cyrillic => 0,
  64                 hebrew   => 0,
  65         ],
  66 );
  67 :>.
  68 </p>
  69
  70 <:
  71 use POSIX qw( ceil );
  72 use Shiar_Sheet::FormatChar;
  73 my $glyphs = Shiar_Sheet::FormatChar->new;
  74 my @request;
  75
  76 sub tabinput {
  77         # generate character table(s)
  78         my $input = shift or return;
  79
  80         state $ALIAS = {
  81                 default    => [qw( u+0-639 utf-8+realsize iso-8859-1 iso-8859-15 cp1252 cp437 cp850 )],
  82                 unicode    => [qw( uu+cols=32+realsize u+0-4095 u+4096-6319 u+6320-8191 )],
  83                 us         => [qw( cp437 cp863 gsm0338 AdobeStandardEncoding )],
  84                 ebcdic     => [qw( cp37 cp500 cp1047 posix-bc cp1026 cp875 )],
  85                 iso        => [map {"iso-8859-$_"} 1 .. 11, 13 .. 16],
  86                 dos        => [qw( cp437 cp865 cp861 cp860 cp863 cp850 cp857 cp852 cp775
  87                                    cp737 cp869 cp866 cp855 cp862 cp864 )],
  88                 aix        => [qw( cp1006 )],
  89                 win        => [qw( cp1252 cp1250 cp1254 cp1257 cp1258 cp1253 cp1251 cp1255 cp1256 cp874 )],
  90                 mac        => [qw( MacRoman MacRomanian MacRumanian MacCroatian MacCentralEurRoman MacTurkish MacIcelandic MacSami
  91                                    MacGreek MacCyrillic MacHebrew MacArabic MacFarsi MacThai )],
  92
  93                 # languages
  94                 westeur    => [qw( iso-8859-1 iso-8859-15 cp1252 iso-8859-14 cp850 hp-roman8 nextstep MacRoman )],
  95                 centeur    => [qw( iso-8859-2 iso-8859-16 cp1250 cp852 MacRomanian MacCroatian MacCentralEurRoman )], # MacRumanian only for DB
  96                 turkish    => [qw( iso-8859-9 iso-8859-3 cp1254 cp857 MacTurkish )],
  97                 norteur    => [qw( baltic nordic )],
  98                 baltic     => [qw( iso-8859-4 iso-8859-13 cp1257 cp775 )],
  99                 nordic     => [qw( iso-8859-10 cp865 cp861 MacIcelandic MacSami )],
 100                 cyrillic   => [qw( koi8-r koi8-u koi8-f iso-8859-5 cp1251 MacCyrillic cp866 cp855
 101                                    U4 U2DE-2DF UA64-A69 U50-52 )], # MacUkrainian is broken
 102                 arabic     => [qw( iso-8859-6 cp1256 MacArabic cp864 cp1006 MacFarsi
 103                                    U6 U8A-8F+0-31+64 U75-77 )],
 104                 greek      => [qw( iso-8859-7 cp1253 MacGreek cp737 cp869  U37-3F U1F )],
 105                 hebrew     => [qw( iso-8859-8 cp1255 MacHebrew cp862  U59-5F )],
 106                 thai       => [qw( iso-8859-11 cp874 MacThai )],
 107                 vietnamese => [qw( viscii cp1258 MacVietnamese )],
 108                 symbols    => [qw( symbol dingbats MacDingbats wingdings wingdings2 wingdings3 webdings )],
 109
 110                 # iso-code shorthand
 111                 1 => 'westeur',
 112                 2 => 'centeur',
 113                 3 => 'turkish',
 114                 4 => 'baltic',
 115                 5 => 'cyrillic',
 116                 6 => 'arabic',
 117                 7 => 'greek',
 118                 8 => 'hebrew',
 119                 9 => 'turkish',
 120                 10 => 'nordic',
 121                 11 => 'thai',
 122         };
 123         if (my $follow = $ALIAS->{$input}) {
 124                 tabinput($_) for ref $follow ? @{$follow} : $follow;
 125                 return;
 126         }
 127
 128         state $visible = {'' => 1};  # all present tables
 129         my %row = (offset => 0, cols => 16);
 130         my $params = $input =~ s/[+](.*)\z// ? $1 : undef;
 131
 132         if (not defined $params) {
 133                 state $INHERIT = {
 134                         'cp437'       => ['cp850' => 0, 'ascii' => '0-31+128'], # ascii range overridden later
 135                         'gsm0338'     => ['ascii' => '0-127'],
 136                         'dingbats'    => ['' => '32-127+160'],
 137                         'MacDingbats' => ['dingbats' => '128-159'],
 138                         'AdobeZdingbat'=> ['MacDingbats' => '128-159'], # should be identical but maps to private use
 139                         'symbol'      => ['' => '32-127+160'],
 140                         'AdobeSymbol' => ['symbol' => '32-127+160', '' => '32-127+160'], # minor differences, irrelevant except for different '€'
 141                         'wingdings'   => ['' => '32'],
 142                         'wingdings2'  => ['' => '32'],
 143                         'wingdings3'  => ['' => '32'],
 144                         'webdings'    => ['' => '32'],
 145
 146                         'iso-8859-2'  => ['iso-8859-1' => '160'],
 147                         'iso-8859-3'  => ['iso-8859-1' => '160'], #TODO: also apply to iso-8859-9
 148                         'iso-8859-4'  => ['iso-8859-2' => '160'],
 149                         'iso-8859-5'  => ['iso-8859-1' => '160'],
 150                         'iso-8859-6'  => ['cp1256' => '128', 'iso-8859-1' => '160'],
 151                         'iso-8859-7'  => ['iso-8859-1' => '160'],
 152                         'iso-8859-8'  => ['iso-8859-1' => '160'],
 153                         'iso-8859-9'  => ['iso-8859-1' => '208-223+240'],
 154                         'iso-8859-10' => ['iso-8859-4' => '160'],
 155                         'iso-8859-11' => ['iso-8859-1' => '160'],
 156                         'iso-8859-13' => ['iso-8859-4' => '160'],
 157                         'iso-8859-14' => ['iso-8859-1' => '160'],
 158                         'iso-8859-15' => ['iso-8859-1' => '160-191'],
 159                         'iso-8859-16' => ['iso-8859-2' => '160'],
 160                         'hp-roman8'   => ['iso-8859-1' => '160'],
 161
 162                         'cp1252'      => ['iso-8859-1' => '128-159'],
 163                         'cp1250'      => ['iso-8859-2' => '128-191', 'cp1252' => '128'],
 164                         'cp1254'      => ['iso-8859-9' => '128-159', 'cp1252' => '128-159+208'],
 165                         'cp874'       => ['iso-8859-11' => '128-159', 'cp1252' => '128'], # windows-874 actually cp1162
 166                         'cp1257'      => ['iso-8859-13' => '128-159+255', 'cp1252' => '128'],
 167                         'cp1251'      => ['cp1252' => '128'],
 168                         'cp1253'      => ['cp1252' => '128'],
 169                         'cp1255'      => ['iso-8859-8' => '128-223', 'cp1252' => '128'],
 170                         'cp1256'      => ['cp1252' => '128'],
 171                         'cp1258'      => ['cp1252' => '128-159+192'],
 172
 173                         'cp850'       => ['cp437' => '144'],
 174                         'cp860'       => ['cp437' => '128-175'],
 175                         'cp861'       => ['cp865' => '128-175'],
 176                         'cp863'       => ['cp437' => '128-175'],
 177                         'cp865'       => ['cp437' => '144-175'],
 178                         'cp852'       => ['cp850' => '128', 'cp437' => '128'],
 179                         'cp857'       => ['cp850' => '128-175+208-239', 'cp437' => '128'],
 180                         'cp775'       => ['cp850' => '128'],  # partial cp437
 181                         'cp866'       => ['cp437' => '128-175+224'],
 182                         'cp855'       => ['cp437' => '128'],
 183                         'cp1006'      => ['iso-8859-6' => '160', 'cp437' => '128'],
 184                         'cp737'       => ['cp437' => '128-175+224'],
 185                         'cp869'       => ['cp437' => '128'],
 186                         'cp862'       => ['cp437' => '128-159'],
 187                         'cp864'       => ['MacArabic' => '128', 'iso-8859-6' => '128', 'cp437' => '128'], #TODO: compare form variants
 188
 189                         'koi8-u'      => ['koi8-r' => '144-191'],
 190                         'koi8-f'      => ['koi8-u' => '144-191'],
 191
 192                         'MacRomanian' => ['MacRoman' => '160-191+208-223'],
 193                         'MacRumanian' => ['MacRomanian' => '160-191+208-223', 'MacRoman' => '160-191+208-223'],
 194                         'MacCroatian' => ['MacRoman' => '160'],
 195                         'MacCentralEurRoman' => ['MacRoman' => '128'],
 196                         'MacIcelandic'=> ['MacRoman' => '160-175+208-239'],
 197                         'MacTurkish'  => ['MacRoman' => '208-223'], # F5 is unassigned
 198                         'MacSami'     => ['MacIcelandic' => '144-191+208-223+240', 'MacRoman' => '144'],
 199                         'MacGreek'    => ['MacRoman' => '128'],
 200                         'MacCyrillic' => ['MacRoman' => '128'],
 201                         'MacHebrew'   => ['iso-8859-8' => '128', 'MacRoman' => '128-143+160'], # partial ascii
 202                         'MacArabic'   => ['iso-8859-6' => '128', 'cp864' => '128', 'MacRoman' => '128'], #TODO: multiple parents
 203                         'MacFarsi'    => ['MacArabic' => '176-191', 'MacRoman' => '128'],
 204
 205                         'cp37'        => ['posix-bc' => '0'],
 206                         'posix-bc'    => ['cp1047' => '64'],
 207                         'cp500'       => ['cp37' => '64-95+176-191'],
 208                         'cp1047'      => ['cp37' => '16-47+80-95+160-191'],
 209                         'cp1026'      => ['cp37' => '64'],
 210                         'cp875'       => ['cp37' => '48'],
 211
 212                 };
 213
 214                 my @parents = @{ $INHERIT->{$input} || [] };
 215
 216                 if (my ($parent, $part) = pairfirst { defined $visible->{$a} } @parents) {
 217                         $row{parent} = $parent;
 218                         $params = $part;
 219                         $params = 128 unless $visible->{$parent}
 220                                 or ($input eq 'MacCroatian' and defined $visible->{MacRomanian});
 221                 }
 222                 elsif (defined $visible->{ascii}) {
 223                         $row{parent} = $parents[0];
 224                         $params = $parents[1] // 128;
 225                         $params = 128 if $params >= 128;  # ascii offset at most
 226                 }
 227                 elsif (@parents) {
 228                         $row{parent} = $parents[0];
 229                         $params = $parents[1] if $parents[1] == 0;  # apply ascii end
 230                 }
 231                 $visible->{$_} //= 0 for $row{parent} || ();
 232         }
 233
 234         for my $param (split /[+]+/, $params // '') {
 235                 if ($param eq 'realsize') {
 236                         $row{realsize}++;
 237                 }
 238                 elsif ($param =~ m{ \A cols = (\d+) \z }x) {
 239                         $row{cols} = $1;
 240                 }
 241                 elsif ($param =~ m{ \A (?<offset> \d+) (?: [-] (?<endpoint> \d+) )? \z }x) {
 242                         if (defined $row{endpoint}) {
 243                                 # extend earlier range
 244                                 my $skip = int(($row{endpoint} || $row{offset}) / $row{cols});
 245                                 for ($skip + 1 .. ($+{offset} / $row{cols}) - 1) {
 246                                         $row{skip}->{ $_ * $row{cols} - $row{offset} }++;
 247                                 }
 248                         }
 249                         else {
 250                                 $row{offset} = $+{offset};
 251                         }
 252                         $row{endpoint} = $+{endpoint} || 0;
 253                 }
 254                 else {
 255                         Alert("Unknown option <q>$param</q> for charset $input");
 256                 }
 257         }
 258
 259         if ($input =~ m{ \A (?:wing|web)dings \d* \z }ix) {
 260                 eval "require Encode::\u$input";
 261         }
 262
 263         if ($input =~ m{ \A u ([0-9a-f]+) (?:-([0-9a-f]+))? \z }ix) {
 264                 my $start = hex($1) << ($2 ? 4 : 8);
 265                 my $end = $2 ? (hex($2) << 4) + $row{cols} - 1 : $start + 255;
 266                 $row{table} = join '', map { chr } $start .. $end;
 267                 utf8::upgrade($row{table});  # prevent latin1 output
 268                 $row{endpoint} = $end - $start;
 269                 $row{set} = sprintf 'Unicode block U+%02Xxx', $start >> 8;
 270                 $row{offset} = $start % 256;
 271         }
 272         elsif (lc $input eq 'uu') {
 273                 $row{set} = 'Unicode planes';
 274                 $row{cell} = do 'charset-ucplanes.inc.pl'
 275                         or Alert('Table data could not be read', $@ || $!);
 276                 $row{endpoint} = 1023 * $row{cell}->{colsize};
 277         }
 278         elsif (lc $input eq 'u') {
 279                 $row{cell} = do 'charset-unicode.inc.pl'
 280                         or Alert('Table data could not be read', $@ || $!);
 281
 282                 $row{endpoint} ||= 8191;
 283                 $row{endpoint}  *= $row{cell}->{colsize};
 284                 $row{startpoint} = $row{cell}->{colsize} * $row{offset};
 285                 $row{offset} = 0;
 286                 $row{set} = 'Unicode ' . (
 287                         $row{startpoint} <  0x10000 && $row{endpoint} < 0x10000 ? 'BMP' :
 288                         $row{startpoint} >= 0x10000 && $row{endpoint} < 0x20000 ? 'SMP' :
 289                         'allocations'
 290                 );
 291         }
 292         elsif ($input =~ m/^utf-*8$/i) {
 293                 $row{set} = 'UTF-8';
 294                 $row{cell} = do 'charset-utf8.inc.pl'
 295                         or Alert('Table data could not be read', $@ || $!);
 296                 $row{endpoint} = 255;
 297         }
 298         elsif ($row{set} = Encode::resolve_alias($input)) {
 299                 $row{endpoint} ||= 255;
 300                 if ($row{set} eq 'MacHebrew' or $row{set} eq 'MacThai') {
 301                         # array of possibly multiple characters per code point
 302                         $row{table} = [
 303                                 map { Encode::decode($row{set}, pack 'C*', $_) } $row{offset} .. $row{endpoint}
 304                         ];
 305                 }
 306                 else {
 307                         # ~16x faster than decoding in loop;
 308                         # substr strings is twice as fast as splitting to an array
 309                         $row{table} = Encode::decode($row{set}, pack 'C*', $row{offset} .. $row{endpoint});
 310                 }
 311                 $row{endpoint} -= $row{offset};
 312
 313                 if ($row{set} eq 'cp437') {
 314                         if ($row{offset} <= 0xED and $row{endpoint} >= 0xED - $row{offset}) {
 315                                 # replace phi glyph
 316                                 substr($row{table}, 0xED - $row{offset}, 1) = 'ϕ';
 317                         }
 318                         if ($row{offset} < 0x20) {
 319                                 # replace control characters by visible variants
 320                                 my $sub = substr ' ☺☻♥♦♣♠•◘○◙♂♀♪♫☼►◄↕‼¶§▬↨↑↓→←∟↔▲▼', $row{offset};
 321                                 substr($row{table}, 0, length $sub) = $sub;
 322                         }
 323                 }
 324                 elsif ($row{set} eq 'symbol') {
 325                         if ($row{offset} <= 0x60 and $row{endpoint} >= 0x60 - $row{offset}) {
 326                                 # replace radical extender by closest unicode equivalent
 327                                 substr($row{table}, 0x60 - $row{offset},  1) = '│';
 328                         }
 329                         if ($row{offset} <= 0xBD and $row{endpoint} >= 0xFF - $row{offset}) {
 330                                 substr($row{table}, 0xBD - $row{offset},  2) = '⏐⎯'; # arrow extenders
 331                                 substr($row{table}, 0xD2 - $row{offset},  3) = '®©™'; # serif variants
 332                                 substr($row{table}, 0xE0 - $row{offset},  1) = '◊'; # replace lookalike, should match AdobeSymbol
 333                                 substr($row{table}, 0xE2 - $row{offset},  3) = '®©™'; # sans-serif variants
 334                                 substr($row{table}, 0xE6 - $row{offset}, 10) = '⎛⎜⎝⎡⎢⎣⎧⎨⎩⎪';
 335                                 substr($row{table}, 0xF0 - $row{offset},  1) = '€';
 336                                 substr($row{table}, 0xF4 - $row{offset}, 11) = '⎮⌡⎞⎟⎠⎤⎥⎦⎫⎬⎭';
 337                         }
 338                 }
 339
 340                 $visible->{ascii} =  # assume common base
 341                 $visible->{ $row{set} } = 1;
 342         }
 343         else {
 344                 Alert("Encoding <q>$input</q> unknown");
 345                 return;
 346         }
 347         push @request, \%row;
 348 }
 349 tabinput($_) for @tablist;
 350
 351 my $NOCHAR = chr 0xFFFD;
 352
 353 sub range_cell {
 354         my ($info, $offset) = @_;
 355         my $table = $info->{cell} or return;
 356         my $def = $table->{$offset} or return;
 357         my ($len, $class, $name, $title) = @{$def};
 358
 359         my $cols = $info->{cols};
 360         my $colsize = $table->{colsize} || 1;
 361         my $attr = '';
 362         $len /= $colsize;
 363         $name //= $len <= 2 ? 'res' : 'reserved';
 364
 365         if (my $part = $offset/$colsize % $cols) {
 366                 # continued row
 367                 my $rest = $cols - $part;  # remaining
 368                 $rest = $len if $len < $rest; #TODO: optimise
 369                 if ($len -= $rest) {
 370                         # continued on new row
 371                         my @next = ($len * $colsize, "$class joinu");
 372                         my $separate = $cols - $len > $rest;  # columns not on next row
 373                         if ($len > $rest) {
 374                                 # minority remains
 375                                 push @next, $name, $title;
 376                                 $title ||= $name;
 377                                 $name = $separate && '…';
 378                         }
 379                         else {
 380                                 # minority on next row
 381                                 push @next, $separate && '"', $title || $name;
 382                         }
 383                         $table->{$offset + $colsize*$rest} //= \@next;
 384                         $class .= ' joind';
 385                 }
 386                 $len = $rest;
 387         }
 388         elsif (my $rows = int($len / $cols)) {
 389                 # multiple full rows
 390                 my $rowsize = $colsize * $cols;
 391                 if ($len -= $rows * $cols) {
 392                         # partial row remains
 393                         $table->{$offset + $rowsize * $rows} //= [$len*$colsize, "$class joinu", '', $title];
 394                         $class .= ' joind';
 395                 }
 396
 397                 unless ($info->{realsize}) {
 398                         # coalesce multiple rows
 399                         while ($rows > 3) {
 400                                 $info->{skip}->{$offset += $rowsize}++;
 401                                 $rows--;
 402                         }
 403                         if ($rows > 2) {
 404                                 $info->{skip}->{$offset += $rowsize} = 0;
 405                         }
 406                 }
 407
 408                 $attr .= sprintf ' rowspan=%d', $rows;
 409                 $len = $cols;
 410         }
 411
 412         $attr .= sprintf ' colspan=%d', $len unless $len == 1;
 413         $attr .= $1 if $class and $class =~ s/( \w+="[^"]*")//;
 414         $attr .= sprintf ' class="%s"', $class if $class;
 415         $attr .= sprintf ' title="%s"', EscapeHTML($title) if $title;
 416         return "<td$attr>$name\n";
 417 }
 418
 419 for my $row (@request) {
 420         my $cols = $row->{cols};
 421         my $colsize = $row->{cell} && $row->{cell}->{colsize} || 1;
 422         my $coldigits = ceil(log($colsize * $cols) / log(16));  # uniform length of hexadecimal header
 423         my $rowdiv = 16 ** $coldigits;  # row divide for column digits
 424         $rowdiv = 1 if $rowdiv != $cols * $colsize;  # divide only if all columns are matched
 425         my $offset = $row->{startpoint} || 0;
 426
 427         printf '<div class="section"><table class="glyphs%s">', !$row->{cell} && ' charmap';
 428         my $title = $row->{set};
 429         $title .= " <aside>(over $_)</aside>"
 430                 for $row->{parent} || ();
 431         printf '<caption>%s</caption>', $title;
 432         print '<col>' x ($cols + 1);
 433         for my $section (qw{thead}) {
 434                 print "<$section><tr><th>", $rowdiv == 1 ? '+' : '↱';
 435                 printf '<th>%0*X', $coldigits, $_ * $colsize for 0 .. $cols - 1;
 436                 print "\n";
 437         }
 438         print '<tbody>';
 439         while ($offset < $row->{endpoint}) {
 440                 if ($row->{skip}->{$offset}) {
 441                         $offset += $cols * $colsize;
 442                         next;
 443                 }
 444
 445                 print '<tr><th>';
 446                 if (defined $row->{skip}->{$offset}) {
 447                         print '⋮';
 448                 }
 449                 else {
 450                         if (my $rowmod = $offset % $rowdiv) {
 451                                 # offset in column units
 452                                 printf '<small>+%X</small>', $rowmod;
 453                         }
 454                         else {
 455                                 # divided row offset
 456                                 printf '%X', ($offset + $row->{offset}) / $rowdiv;
 457                         }
 458                 }
 459                 say '';
 460
 461                 for (1 .. $cols) {
 462                         if ($row->{cell}) {
 463                                 print range_cell($row, $offset);
 464                                 next;
 465                         }
 466
 467                         my $cp = $offset + $row->{offset};
 468                         my $glyph = ref $row->{table} eq 'ARRAY' ? $row->{table}->[$offset] :
 469                                 substr $row->{table}, $offset, 1;
 470                         my ($cell, $name, $class) = $glyph eq $NOCHAR ? () :
 471                                 $glyphs->glyph_html($glyph);
 472
 473                         if (exists $get{compare}) {
 474                                 state $visible = {};
 475                                 $class = (
 476                                         $cp == ord $glyph ? 'l4' :
 477                                         $row->{parent} && $glyph eq
 478                                                 Encode::decode($row->{parent}, pack 'C', $cp) ? 'l3' :
 479                                         !$class ? undef :
 480                                         $visible->{$glyph} ? 'l2' :
 481                                         'l1'
 482                                 );
 483                                 $visible->{$glyph}++;
 484                         }
 485
 486                         say sprintf $class ? '<td title="%s" class="X %s">%s' : '<td title="%s">',
 487                                 $name, $class, $cell;
 488                 }
 489                 continue {
 490                         $offset += $colsize;
 491                 }
 492         }
 493         say '</table></div>';
 494 }
 495
 496 :>
 497 <hr>
 498
 499 <div class="legend">
 500         <table class="glyphs"><tr><: if (exists $get{compare}) { :>
 501         <td class="X l4">unicode
 502         <td class="X l3">inherited
 503         <td class="X l2">existing
 504         <td class="X l1">original
 505         <td class="">unassigned
 506 <: } else { :>
 507         <td class="X Cc">control
 508         <td class="X Zs"><span>whitespace</span>
 509         <td class="X Mn">diacritic<table class="glyphs"><tr>
 510                 <td class="X Sk">letter
 511                 </table>
 512         <td class="X Po">punctuation<table class="glyphs"><tr>
 513                 <td class="X Pf">quote
 514                 </table>
 515         <td class="X So">symbol<table class="glyphs"><tr>
 516                 <td class="X Sm">math
 517                 <td class="X Sc">currency
 518                 </table>
 519         <td class="X No">numeric
 520         <td class="X Greek">greek<table class="glyphs"><tr>
 521                 <td class="X Latin">latin
 522                 <td class="X Cyrillic">cyrillic
 523                 </table>
 524         <td class="X Aramaic">aramaic<table class="glyphs"><tr>
 525                 <td class="X Brahmic">brahmic
 526                 <td class="X Arabic">arabic
 527                 </table>
 528         <td class="X Syllabic">syllabic<table class="glyphs"><tr>
 529                 <td class="X African">african
 530                 <td class="X Hiragana">japanese
 531                 <td class="X Han">cjk
 532                 <td class="X Bopomofo">chinese
 533                 </table>
 534         <td class="X Alpha">alphabetic
 535         </table>
 536
 537         <table class="glyphs"><tr>
 538         <td class="X">unicode 7.0
 539         <td class="X Xr">proposed
 540         <td class="X Xd">deprecated
 541         <td class="">unassigned
 542         <td class="X Xi">invalid
 543 <: } :> </table>
 544 </div>
 545