Shiar_Sheet/Keyboard.pm

   1 package Shiar_Sheet::Keyboard;
   2
   3 use strict;
   4 use warnings;
   5 no  warnings 'uninitialized';  # save some useless checks for more legible code
   6 use Carp;
   7
   8 our $VERSION = 'v1.05';
   9
  10 my @casedesc = (undef, qw/shift ctrl meta/, 'shift meta');
  11 my @rowdesc = qw(numeric top home bottom);
  12 my %keyrows = do 'keys.inc.pl';
  13 # add first two cases of each row again with each char prepended by + (alt)
  14 push @$_, map { [map {"+$_"} @$_] } @$_[0,1] for map {@$_} values %keyrows;
  15
  16 my %keytrans = qw(
  17         ^@ NUL ^a SOH ^b STX ^c ETX  ^d EOT ^e ENQ ^f ACK ^g BEL
  18         ^h BS  ^i tab ^j LF  ^k VT   ^l FF  ^m CR  ^n SO  ^o SI
  19         ^p DLE ^q DC1 ^r DC2 ^s DC3  ^t DC4 ^u NAK ^v SYN ^w ETB
  20         ^x CAN ^y EM  ^z SUB ^[ ESC  ^\ FS  ^] GS  ^^ RS  ^_ US
  21         ^? DEL
  22 );
  23
  24 sub new {
  25         my $self = shift;
  26         my ($keys) = @_;
  27
  28         croak 'Invalid key table specified' unless ref $keys eq 'HASH';
  29         my $parent = (caller)[0];  # calling module
  30         my $sign = do {
  31                 no strict 'refs';  # temporarily allow variable references
  32                 \%{ $parent.'::sign' };  # return %sign from parent
  33         };
  34         croak "%${parent}::sign not found" unless %$sign;
  35
  36         bless {sign => $sign, keys => $keys, map => 'qwerty'}, $self;
  37 }
  38
  39 sub map {
  40         my $self = shift;
  41         my ($mapname) = @_;
  42
  43         return $self->{map} = $mapname if defined $keyrows{$mapname};
  44         return undef;
  45 }
  46
  47 sub escapeclass {
  48         local $_ = shift;
  49         s/\^/_c/g;
  50         s/\+/_m/g;
  51         s/\[/_sbo/g;
  52         s/\]/_sbc/g;
  53         s/^$/_/;
  54         return $_;
  55 }
  56
  57 sub escapehtml {
  58         local $_ = shift;
  59         s/</&lt;/g;
  60         s/>/&gt;/g;
  61         s/  / &nbsp;/g;
  62         return $_;
  63 }
  64
  65 sub keyunalias {
  66         my $self = shift;
  67         my ($key, $ancestry) = @_;
  68
  69         $key =~ s/(\S*?)(\+?\^?\S)($|\s.*)/$2/;
  70         my $mode = $1;
  71         my $keyinfo = $self->{keys}->{$mode}->{$key};
  72
  73         return [] unless defined $keyinfo;
  74         return $keyinfo if ref $keyinfo;
  75         return if $ancestry->{$key}++;  # endless loop failsafe
  76         return $self->keyunalias($keyinfo, $ancestry);
  77 }
  78
  79 sub print_key {
  80         my $self = shift;
  81         my ($mode, $key, $keyinfo) = @_;
  82
  83         $keyinfo = [ $self->{sign}->{alias}.$keyinfo, $self->keyunalias($keyinfo)->[1] . ' alias' ]
  84                 if defined $keyinfo and not ref $keyinfo;  # alias
  85         my ($desc, $flags, $mnem) = @$keyinfo if defined $keyinfo;
  86         defined $desc or $flags = $key eq '^0' ? 'ni' : 'no';
  87
  88 #       $key = $keytrans{$key} if defined $keytrans{$key};
  89         my $keytxt = $mode . escapehtml($key) if $key ne '^0';
  90            $keytxt .= $self->{sign}->{$1} while $flags =~ s/(?:^| )(arg[a-ln-z]?)\b//;  # arguments
  91            $keytxt .= "<small>$self->{sign}->{motion}</small>" if $flags =~ s/ ?\bargm\b//;  # motion argument
  92            $keytxt =~ s{\^(?=.)}{<small>^</small>};  # element around ctrl-identifier
  93            $keytxt =~ s{\+(?=.)}{<small>+</small>};  # meta
  94         my $keyhint = defined($mnem) && qq{ title="$mnem"};
  95            $keytxt  = "<b$keyhint>$keytxt</b>";
  96            $keytxt .= ' '.$desc if defined $desc;
  97            $keytxt = qq{<a href="/$1">$keytxt</a>} if $flags =~ s/ ?\blink(\S*)//;
  98         my $onclick = $flags =~ s/ ?\bmode(\S*)// && defined $self->{keys}{$1} && sprintf(
  99                 ' onclick="setmode(%s)"',
 100                 $1 eq '' ? '' : sprintf(q{'mode%s'}, escapeclass($1))
 101         );
 102         $flags .= ' chr'.ord(substr $key, -1) if $key ne '^0';
 103
 104         print qq{\t\t<li class="$flags"$onclick>$keytxt};
 105         print "\n";
 106 }
 107
 108 sub print_rows {
 109         my $self = shift;
 110         my %moderows = (
 111                 -DEFAULT => !@_ ? '' : split(/(?:\s*([^=\s]*)=\s*)/, shift),
 112                 # plus specific mode overrides prefixed by '='
 113         );
 114         my $defrows = shift || [2, 1, 0];
 115         my @modes = sort keys %{ $self->{keys} };
 116
 117         for (my $row = 0; $row <= $#{ $keyrows{$self->{map}} }; $row++) {
 118                 my $keyrow = $keyrows{$self->{map}}->[$row];
 119
 120                 print qq{<li class="row row$row"><ul>\n};
 121                 for my $basemode (@modes) {
 122                         my @moderows = split /\s+/,
 123                                 defined $moderows{$basemode} ? $moderows{$basemode} : $moderows{-DEFAULT};
 124
 125                 for my $submode (@moderows ? @moderows : '') {
 126                         my $mode = $basemode . $submode;
 127                         my @caserows = $mode =~ s/(\d+)(?:-(\d+))?$//
 128                                 ? (map {$_ - 1} split //, $row == 0 && $2 || $1)  # user override
 129                                 : @$defrows;  # default
 130                         my $modekeys = $self->{keys}{$mode};
 131
 132                         for my $case (@caserows) {
 133                                 my $keycase = $keyrow->[$case] or next;
 134                                   @$keycase or next;
 135
 136                                 printf "\t<li%s>", $basemode ne '' && sprintf(
 137                                         ' class="%s"', 'mode mode' . escapeclass($basemode)
 138                                 );
 139                                 printf("<h3>%s<small>: %s</small></h3>\n", # XXX insert &nbsp; here to fix msie<=6
 140                                                 $modekeys->{desc} || "mode $basemode",
 141                                                 "$rowdesc[$row] row $casedesc[$case]"
 142                                 );
 143                                 my $caseclass = 'keys';
 144                                    $caseclass .= ' lead' if defined $modekeys->{lead};  # leading command key shown
 145                                    $caseclass .= " $casedesc[$case]" if defined $casedesc[$case];
 146                                 print qq{\t\t<ul class="$caseclass">\n};
 147                                 $self->print_key($modekeys->{lead}, $_, $modekeys->{$_}) for @$keycase;
 148                                 print qq{\t\t</ul>\n};
 149                         } # case
 150
 151                 } # submode
 152
 153                 } # basemode
 154                 print qq{\t</ul>\n};
 155         } # row
 156 }
 157
 158 1;
 159
 160 =head1 NAME
 161
 162 Shiar_Sheet::Keyboard - Output HTML for key sheets
 163
 164 =head1 SYNOPSIS
 165
 166         our %sign = (alias => 'see: ');
 167
 168         my $keys = Shiar_Sheet::Keyboard({
 169                 'mode' => {
 170                         desc => 'mode description',
 171                         'A' => 'a', # alias
 172                         'a' => ['description', 'classes', 'comments (on hover)'],
 173                 },
 174         });
 175         $keys->map('dvorak') or die "Keyboard map not found";
 176
 177         $keys->print_rows;
 178
 179 =head1 DESCRIPTION
 180
 181 Used by http://sheet.shiar.nl to display keyboard sheets.
 182 Assumes specific stylesheets and javascript from this site,
 183 so probably not of much use elsewhere.
 184
 185 =head1 AUTHOR
 186
 187 Mischa POSLAWSKY <perl@shiar.nl>
 188
 189 =head1 LICENSE
 190
 191 Licensed under the GNU Affero General Public License version 3.
 192