Shiar_Sheet/FormatChar.pm

   1 package Shiar_Sheet::FormatChar;
   2
   3 use 5.010;
   4 use strict;
   5 use warnings;
   6
   7 use Data::Dump 'pp';
   8 use PLP::Functions 'EscapeHTML';
   9
  10 our $VERSION = '1.06';
  11
  12 our $uc = do 'unicode-char.inc.pl';
  13
  14 sub new {
  15         my ($class) = @_;
  16         bless { anno => ['di', 0], style => 'di' }, $class;
  17 }
  18
  19 sub glyph_info {
  20         my ($self, $codepoint) = @_;
  21         return $uc->{chr $codepoint} || eval {
  22                 require Unicode::UCD;
  23                 if (my $fullinfo = Unicode::UCD::charinfo($codepoint)) {
  24                         return [@$fullinfo{qw/category name - string/}];
  25                 }
  26         } || [];
  27 }
  28
  29 sub glyph_html {
  30         my ($self, $char) = @_;
  31         my $codepoint = ord $char;
  32         my $info = $self->glyph_info($codepoint);
  33         my ($class, $name, $mnem, $html, $string) = @$info;
  34
  35         my $cell = EscapeHTML($string || $char);
  36         my $title = sprintf 'U+%04X%s', $codepoint, $name && " ($name)";
  37
  38         $cell = "<span>$cell</span>" if $class =~ /\bZs\b/;
  39         $cell = '&nbsp;' if $cell eq '';
  40
  41         return ($cell, EscapeHTML($title), "X $class", $mnem, $html);
  42 }
  43
  44 sub glyphs_html {
  45         my $self = shift;
  46
  47         return $self->glyph_html(@_) if length $_[0] <= 1;
  48
  49         my @chars = map { [ $self->glyph_html($_) ] } split //, $_[0];
  50         return (
  51                 EscapeHTML($_[0]), # cell
  52                 join(' | ', map { $_->[1] } @chars), # title
  53                 $chars[0][2], # class
  54                 join(' ',  grep { defined } map { $_->[3] } @chars), # digraph
  55         );
  56 }
  57
  58 sub glyph_cell {
  59         my ($self, $char) = @_;
  60         return sprintf('<td class="%3$s" title="%2$s">%s', $self->glyph_html($char));
  61 }
  62
  63 sub cell {
  64         my ($self, $input, $html) = @_;
  65         my (@class, $title, $cell, $mnem, $entity);
  66
  67         if ($input eq '-') {
  68                 $cell = '';
  69         }
  70         elsif ($input eq '=') {
  71                 push @class, 'u-invalid';
  72                 $cell = '';
  73         }
  74         else {{
  75                 push @class, 'X';
  76
  77                 if ($input =~ s/^-//) {
  78                         push @class, 'ex'; # discouraged
  79                 }
  80
  81                 $input =~ s/^\\//;  # escaped char
  82                 ($cell, $title, my $class, $mnem, $entity) = $self->glyphs_html($input);
  83                 my $codepoint = ord(substr $input, 0, 1);
  84
  85                 if ($self->{style} eq 'univer') {
  86                         if ($input =~ /\p{age=unassigned}/) {
  87                                 # check include for assignments after unicode 6.0 (perl v5.14)
  88                                 state $agemap = do 'unicode-age.inc.pl';
  89                                 my $version = $agemap->{$codepoint};
  90                                 push @class, $version ? 'l2' : 'l1';
  91                         }
  92                         elsif ($input =~ /^\p{in=1.1}*$/) {
  93                                 push @class, 'l5';  # first release 1993
  94                         }
  95                         elsif ($input =~ /^\p{in=3.0}*$/) {
  96                                 push @class, 'l4';  # 20th century
  97                         }
  98                         elsif ($input =~ /^\p{in=4.1}*$/) {
  99                                 push @class, 'l4';  # over 10 years ago
 100                         }
 101                         elsif ($input =~ /^\p{in=6.0}*$/) {
 102                                 push @class, 'l3';  # before 2012
 103                         }
 104                         else {
 105                                 push @class, 'l2';  # more recent
 106                         }
 107                         next;
 108                 }
 109
 110                 if ($self->{style} eq 'di') {
 111                         if ($class =~ /\bu-di\b/) {
 112                                 push @class, ('l3', 'u-di'); # standard digraph
 113                         }
 114                         elsif ($class =~ /\bu-prop\b/) {
 115                                 push @class, ('l2', 'u-prop'); # unofficial
 116                         }
 117                 }
 118                 elsif ($self->{style} eq 'html') {
 119                         if (defined $entity) {
 120                                 push @class, ('l3', 'u-html');
 121                         }
 122                 }
 123                 else {
 124                         if ($codepoint <= 0xFF) {
 125                                 push @class, 'l3', 'u-lat1';  # latin1
 126                         }
 127                         elsif ($codepoint <= 0xD7FF) {
 128                                 push @class, 'l2', 'u-bmp';  # bmp
 129                         }
 130                 }
 131
 132                 if ($input =~ /[ -~]/) {
 133                         push @class, 'l4', 'u-ascii'; # ascii
 134                 }
 135                 else {
 136                         push @class, 'l1'; # basic unicode
 137                 }
 138         }}
 139
 140         my $anno = '';
 141         if ($cell ne '') {
 142                 for (@{ $self->{anno} }) {
 143                         if (/html$/) {
 144                                 if (defined $entity) {
 145                                         $entity = "&$entity;" if /^&/;
 146                                         $anno = sprintf(' <small class="digraph">%s</small>', EscapeHTML($entity));
 147                                         last;
 148                                 }
 149                         }
 150                         elsif ($_ eq 'xml') {
 151                                 $anno = sprintf(' <small class="digraph">%s</small>',
 152                                         sprintf '#%d', ord($cell)
 153                                 );
 154                                 last;
 155                         }
 156                         elsif ($_ eq '&xml') {
 157                                 $anno = sprintf(' <small class="digraph">%s</small>',
 158                                         sprintf '&amp;#%d;', ord($cell)
 159                                 );
 160                                 last;
 161                         }
 162                         elsif ($_ eq 'di') {
 163                                 if (defined $mnem and length $mnem) {
 164                                         $anno = sprintf(' <small class="digraph">%s</small>', EscapeHTML($mnem));
 165                                         last;
 166                                 }
 167                         }
 168                         else {
 169                                 if ($_ eq 'hex' or $cell =~ /^[^a-zA-Z]$/) {
 170                                         $anno = sprintf(' <small class="%s">%04X</small>', 'value', ord $cell);
 171                                         last;
 172                                 }
 173                         }
 174                 }
 175         }
 176
 177         return sprintf('<td%s%s%s>%s%s',
 178                 defined $title  ? qq{ title="$title"}  : '',
 179                 @class ? sprintf(' class="%s"', join ' ', @class) : '',
 180                 $html || '',
 181                 $cell eq '' ? '&nbsp;' : $cell,
 182                 $anno,
 183         );
 184 }
 185
 186 sub table {
 187         my ($self, $digraphs) = @_;
 188
 189         my @rows;
 190
 191         my @colheads;
 192         while ($digraphs->[0] !~ /^\./) {
 193                 my $cell = shift @$digraphs or last;
 194                 push @colheads, sprintf(
 195                         '<%s%s>%s',
 196                         $cell =~ s/^-// ? 'td' : 'th',
 197                         $cell =~ s/:(.*)// ? qq{ title="$1"} : '',
 198                         $cell eq '_' ? '&nbsp;' : $cell
 199                 );
 200         }
 201         push @rows, sprintf '<thead><tr>%s<tbody>', join '', @colheads if @colheads;
 202
 203         my $colspan = 1;
 204         for my $cell (@$digraphs) {
 205                 if ($cell =~ s/^\.//) {
 206                         # dot indicates start of a new row
 207                         push @rows, '<tr>';
 208                         if ($cell =~ s/^>//) {
 209                                 # header cell text follows
 210                                 $cell =~ s/_/ /g;  # underscores may be used instead of whitespace (for qw//ability)
 211                                 my $class = $cell =~ s/^-// && ' class="ex"';
 212                                 $rows[-1] .= "<th$class>".($cell || '&nbsp;');
 213                         }
 214                         next;
 215                 }
 216                 elsif ($cell eq '>') {
 217                         # merge this cell to the next column
 218                         $colspan++;
 219                         next;
 220                 }
 221
 222                 $rows[-1] .= $self->cell($cell,
 223                         $colspan > 1 && qq{ colspan="$colspan"},
 224                 );
 225
 226                 $colspan = 1;
 227         }
 228
 229         return sprintf qq{<table class="glyphs%s">\n%s</table>\n},
 230                 @{ $self->{anno} } ? ' dilabel' : '',
 231                 join '', map {"$_\n"} @rows;
 232 }
 233
 234 sub print {
 235         my $self = shift;
 236         while (@_) {
 237                 print '<div class="section">';
 238                 printf '<h2>%s</h2>', shift unless ref $_[0];
 239                 print "\n\n";
 240                 while (ref $_[0] and $_ = shift) {
 241                         print $self->table($_);
 242                 }
 243                 print "\n</div>";
 244         }
 245 }
 246
 247 1;
 248