Shiar_Sheet/Keyboard.pm

   1 package Shiar_Sheet::Keyboard;
   2
   3 use strict;
   4 use warnings;
   5 no  warnings 'uninitialized';  # save some useless checks for more legible code
   6 use Carp;
   7
   8 our $VERSION = 'v2.02';
   9
  10 my @casedesc = (undef, qw/shift ctrl meta/, 'shift meta');
  11 my @rowdesc = qw(numeric top home bottom);
  12 my %keyrows = do 'keys.inc.pl';
  13 # add first two cases of each row again with each char prepended by + (alt)
  14 push @$_, map { [map {"+$_"} @$_] } @$_[0,1] for map {@$_} values %keyrows;
  15
  16 my %keytrans = qw(
  17         ^@ NUL ^a SOH ^b STX ^c ETX  ^d EOT ^e ENQ ^f ACK ^g BEL
  18         ^h BS  ^i tab ^j LF  ^k VT   ^l FF  ^m CR  ^n SO  ^o SI
  19         ^p DLE ^q DC1 ^r DC2 ^s DC3  ^t DC4 ^u NAK ^v SYN ^w ETB
  20         ^x CAN ^y EM  ^z SUB ^[ ESC  ^\ FS  ^] GS  ^^ RS  ^_ US
  21         ^? DEL
  22 );
  23
  24 sub new {
  25         my $class = shift;
  26         my ($self) = @_;
  27
  28         croak 'Invalid keyboard definitions specified' unless ref $self eq 'HASH';
  29         croak 'No key definitions specified' unless ref $self->{def} eq 'HASH';
  30         $self->{map} ||= 'qwerty';
  31
  32         my $parent = (caller)[0];  # calling module
  33         my $sign = do {
  34                 no strict 'refs';  # temporarily allow variable references
  35                 \%{ $parent.'::sign' };  # return %sign from parent
  36         };
  37         croak "%${parent}::sign not found" unless %$sign;
  38         $self->{sign} = $sign;
  39
  40         bless $self, $class;
  41 }
  42
  43 sub map {
  44         my $self = shift;
  45         my ($mapname) = @_;
  46
  47         return $self->{map} = $mapname if defined $keyrows{$mapname};
  48         return undef;
  49 }
  50
  51 sub escapeclass {
  52         local $_ = shift;
  53         s/\^/_c/g;
  54         s/\+/_m/g;
  55         s/\[/_sbo/g;
  56         s/\]/_sbc/g;
  57         s/^$/_/;
  58         return $_;
  59 }
  60
  61 sub escapehtml {
  62         local $_ = shift;
  63         s/</&lt;/g;
  64         s/>/&gt;/g;
  65         s/  / &nbsp;/g;
  66         return $_;
  67 }
  68
  69 sub keyunalias {
  70         my $self = shift;
  71         my ($key, $ancestry) = @_;
  72
  73         $key =~ s/(\S*?)(\+?\^?\S)($|\s.*)/$2/;
  74         my $mode = $1;
  75         my $keyinfo = $self->{def}->{$mode}->{$key};
  76
  77         return unless defined $keyinfo;
  78         return $keyinfo->[0] if ref $keyinfo;
  79         return '' if $ancestry->{$key}++;  # endless loop failsafe
  80         return $self->keyunalias($keyinfo, $ancestry);
  81 }
  82
  83 sub print_key {
  84         my $self = shift;
  85         my ($mode, $key, $flags) = @_;
  86
  87         if (not defined $flags) {
  88                 $flags = [$key eq '^0' ? 'ni' : 'no'];
  89         }
  90         elsif (not ref $flags) { # alias
  91                 $flags = [$self->keyunalias($flags) . ' alias', $self->{sign}->{alias} . $flags];
  92         }
  93         my ($flags, $desc, $mnem) = @{$flags};
  94         if (my $txt = $self->{key}->{$mode.$key}) {
  95                 ($desc, $mnem) = @{$txt};
  96         }
  97
  98 #       $key = $keytrans{$key} if defined $keytrans{$key};
  99         my $keytxt = $key eq "\e" ? 'Esc' : $self->{def}{$mode}{lead} . escapehtml($key) if $key ne '^0';
 100            $keytxt .= $self->{sign}->{$1} while $flags =~ s/(?:^| )(arg[a-ln-z]?)\b//;  # arguments
 101            $keytxt .= "<small>$self->{sign}->{motion}</small>" if $flags =~ s/ ?\bargm\b//;  # motion argument
 102            $keytxt =~ s{\^(?=.)}{<small>^</small>};  # element around ctrl-identifier
 103            $keytxt =~ s{\+(?=.)}{<small>+</small>};  # meta
 104         my $keyhint = defined($mnem) && qq{ title="$mnem"};
 105            $keytxt  = "<b$keyhint>$keytxt</b>";
 106            $keytxt .= ' '.$desc if defined $desc;
 107            $keytxt = qq{<a href="/$1">$keytxt</a>} if $flags =~ s/ ?\blink(\S*)//;
 108         my $onclick = $flags =~ s/ ?\bmode(\S*)// && defined $self->{def}{$1} && sprintf(
 109                 ' onclick="setmode(%s)"',
 110                 $1 eq '' ? '' : sprintf(q{'mode%s'}, escapeclass($1))
 111         );
 112         $flags .= ' chr'.ord(substr $key, -1) if $key ne '^0';
 113
 114         print qq{\t\t<li class="$flags"$onclick>$keytxt};
 115         print "\n";
 116 }
 117
 118 sub print_rows {
 119         my $self = shift;
 120         my %moderows = (
 121                 -DEFAULT => !@_ ? '' : split(/(?:\s*([^=\s]*)=\s*)/, shift),
 122                 # plus specific mode overrides prefixed by '='
 123         );
 124         my $defrows = shift || [2, 1, 0];
 125         my @modes = sort keys %{ $self->{def} };
 126
 127         for (my $row = -1; $row <= $#{ $keyrows{$self->{map}} }; $row++) {
 128                 my $keyrow = $row < 0 ? [["\e"]] : $keyrows{$self->{map}}->[$row];
 129
 130                 printf qq{<li class="row row%d"><ul>\n}, $row+1;
 131                 for my $basemode (@modes) {
 132                         my @moderows = split /\s+/,
 133                                 defined $moderows{$basemode} ? $moderows{$basemode} : $moderows{-DEFAULT};
 134
 135                 for my $submode (@moderows ? @moderows : '') {
 136                         my $mode = $basemode . $submode;
 137                         my @caserows = $mode =~ s/(\d+)(?:-(\d+))?$//
 138                                 ? (map {$_ - 1} split //, $row == 0 && $2 || $1)  # user override
 139                                 : @$defrows;  # default
 140                         my $modekeys = $self->{def}{$mode};
 141
 142                         for my $case (@caserows) {
 143                                 my $keycase = $keyrow->[$case] or next;
 144                                   @$keycase or next;
 145
 146                                 printf "\t<li%s>", $basemode ne '' && sprintf(
 147                                         ' class="%s"', 'mode mode' . escapeclass($basemode)
 148                                 );
 149                                 printf('<h3>%s<small>: %s</small></h3>', # XXX insert &nbsp; here to fix msie<=6
 150                                                 $self->{mode}->{$mode} || "mode $basemode",
 151                                                 "$rowdesc[$row] row $casedesc[$case]"
 152                                 ) unless $row < 0;
 153                                 print "\n";
 154                                 my $caseclass = 'keys';
 155                                    $caseclass .= ' lead' if defined $modekeys->{lead};  # leading command key shown
 156                                    $caseclass .= " $casedesc[$case]" if defined $casedesc[$case];
 157                                 print qq{\t\t<ul class="$caseclass">\n};
 158                                 $self->print_key($mode, $_, $modekeys->{$_}) for @$keycase;
 159                                 print qq{\t\t</ul>\n};
 160                         } # case
 161
 162                 } # submode
 163
 164                 } # basemode
 165                 print qq{\t</ul>\n};
 166         } # row
 167 }
 168
 169 sub print_legend {
 170         my $self = shift;
 171         my ($class, $flags) = @_;
 172
 173         print qq{\t\t<dl class="legend $class">\n};
 174         printf("\t\t".'<dt class="%s">%s'."\n\t\t\t".'<dd>%s'."\n",
 175                 $_, @{ $self->{flag}->{$_} || ["($_)", '...'] }
 176         ) for @$flags;
 177         print "\t\t</dl>";
 178 }
 179
 180 1;
 181
 182 =head1 NAME
 183
 184 Shiar_Sheet::Keyboard - Output HTML for key sheets
 185
 186 =head1 SYNOPSIS
 187
 188         our %sign = (alias => 'see: ');
 189
 190         my $keys = Shiar_Sheet::Keyboard({
 191                 def => {
 192                         'lead' => {
 193                                 'A' => 'a', # alias
 194                                 'a' => ['classes'],
 195                         },
 196                 },
 197                 key => {
 198                         'leada' => ['description', 'comments (on hover)'],
 199                 },
 200                 mode => {
 201                         'lead' => 'mode description',
 202                 },
 203         });
 204         $keys->map('dvorak') or die "Keyboard map not found";
 205
 206         $keys->print_rows;
 207
 208 =head1 DESCRIPTION
 209
 210 Used by http://sheet.shiar.nl to display keyboard sheets.
 211 Assumes specific stylesheets and javascript from this site,
 212 so probably not of much use elsewhere.
 213
 214 =head1 AUTHOR
 215
 216 Mischa POSLAWSKY <perl@shiar.nl>
 217
 218 =head1 LICENSE
 219
 220 Licensed under the GNU Affero General Public License version 3.
 221