browser.plp

   1 <(common.inc.plp)><:
   2 use 5.010;
   3 use utf8;
   4 use List::Util qw(sum max);
   5
   6 Html({
   7         title => 'browser compatibility cheat sheet',
   8         version => 'v1.0',
   9         description =>
  10                 "caniuse.",
  11         keywords => [qw'html css browser feature'],
  12         stylesheet => [qw'circus dark mono red light'],
  13         data => ['browser-support.inc.pl'],
  14 });
  15
  16 :>
  17 <h1>Browser compatibility</h1>
  18
  19 <p>Alternate view of Fyrd's <a href="http://caniuse.com/">when can I use...</a> page
  20 <:
  21 my $canihas = do 'browser-usage.inc.pl'
  22         or printf "<p>Browser usage data not found: <em>%s</em>.</p>\n", $! || $@;
  23
  24 print "with $_ browser usage statistics." for map {
  25         my $ref = $_->{-source} || 'unknown';
  26         $ref = sprintf '<a href="%s">%s</a>', $_, $ref for $_->{-url} || ();
  27         $ref .= " $_" for $_->{-date} || ();
  28         $ref
  29 } $canihas || ();
  30 :>
  31 </p>
  32
  33 <div id="browser">
  34 <:
  35 my $caniuse = do 'browser-support.inc.pl' or die $! || $@;
  36
  37 my %CSTATS = (
  38         'n'   => 'l1',
  39         'y'   => 'l5',
  40         'y x' => 'l4',
  41         'a'   => 'l3',
  42         'a x' => 'l3',
  43         'p j' => 'l2',
  44         'j'   => 'l2',
  45         'p'   => 'l2',
  46         'u'   => 'l0',
  47 );
  48 my %CSTATUS = (
  49         unoff => 'l1', # unofficial
  50         wd    => 'l3', # draft
  51         cr    => 'l4', # candidate
  52         pr    => 'l4', # proposed
  53         rec   => 'l5', # recommendation
  54         other => 'l5', # non-w3
  55         ietf  => 'l5', # standard
  56 );
  57 my %versions;
  58 if (my ($somerow) = values %{ $caniuse->{data} }) {
  59         while (my ($browser, $row) = each %{ $somerow->{stats} }) {
  60                 $versions{$browser} = [ sort { paddedver($a) cmp paddedver($b) } keys %$row ];
  61         }
  62 }
  63 my @browsers = grep { $versions{$_} }
  64         qw(trident gecko webkit_saf ios_saf webkit_chr android presto op_mob op_mini);
  65
  66 $canihas ||= {
  67         map {
  68                 $_ => +{
  69                         map {
  70                                 my $zero = $#$_ - 2;  # baseline index
  71                                 ($_->[$zero - 2] =>  .5), # past
  72                                 ($_->[$zero - 1] => 10 ), # previous
  73                                 ($_->[$zero + 2] =>  0 ), # future
  74                                 ($_->[$zero + 1] =>  .5), # next
  75                                 ($_->[$zero    ] => 30 ), # current
  76                         } $caniuse->{agents}->{$_}->{versions}
  77                 }
  78         } @browsers
  79 }; # fallback hash based on release semantics
  80 my $scorediv = (max(map { ref $_ eq 'HASH' && sum(values %$_) } values %$canihas) // 1) / 100;
  81
  82 print '<table class="mapped">';
  83 print '<col>' x 3;
  84 printf '<colgroup span="%d">', scalar @{ $versions{$_} } for @browsers;
  85 print "\n";
  86
  87 my $header = join('',
  88         '<tr>',
  89         '<th colspan="3">feature',
  90         (map {
  91                 sprintf('<th colspan="%d" title="%.1f%%">%s',
  92                         scalar @{ $versions{$_} },
  93                         sum(values %{ $canihas->{$_} }),
  94                         do {
  95                                 my $name = $caniuse->{agents}->{$_}->{browser};
  96                                 length $name < 16 ? $name : $caniuse->{agents}->{$_}->{abbr};
  97                         },
  98                 )
  99         } @browsers),
 100         '<th>%',
 101 );
 102 print '<thead>', $header;
 103 # preceding row without any colspan to work around gecko bug
 104 print "\n<tr>";
 105 print '<td>' x 3;
 106 for my $browser (@browsers) {
 107         printf('<td title="%.1f%%">%s',
 108                 $canihas->{$browser}->{$_}, showversions($_),
 109         ) for @{ $versions{$browser} };
 110 }
 111 print '<td>' x 1;
 112 print "</thead>\n";
 113
 114 sub featurescore {
 115         # relative amount of support for given feature
 116         state $statspts = { y=>10, 'y x'=>9, a=>5, 'a x'=>5, j=>2, 'p j'=>2, p=>1 };
 117         my $rank = 0;
 118         if (my $row = shift) {
 119                 if ($canihas) {
 120                         while (my ($browser, $versions) = each %$row) {
 121                                 ref $versions eq 'HASH' or next;
 122                                 while (my ($version, $_) = each %$versions) {
 123                                         $rank += $canihas->{$browser}->{$version} * $statspts->{$_};
 124                                 }
 125                         }
 126                         return $rank;
 127                 }
 128
 129                 while (my ($browser, $vercols) = each %versions) {
 130                         my $div = 0;  # multiplier exponent (decreased to lower value)
 131                         my @vers = map { $row->{$browser}->{$_} } @$vercols;
 132                         if (my $current = $caniuse->{agents}->{$browser}->{versions}->[-3]) {
 133                                 my @future;  # find upcoming releases (after current)
 134                                 for (reverse @$vercols) {
 135                                         last if $_ eq $current;
 136                                         push @future, pop @vers;
 137                                         $_ eq 'u' and $_ = $vers[-1] for $future[-1];  # inherit latest value if unknown
 138                                 }
 139                                 splice @vers, -1, 0, @future;  # move ahead to decrease precedence
 140                         }
 141                         $rank += $statspts->{$_} * 2**($div--) for reverse @vers;
 142                 }
 143         }
 144         return $rank;
 145 }
 146
 147 for my $id (sort {
 148             featurescore($caniuse->{data}->{$b}->{stats})
 149         <=> featurescore($caniuse->{data}->{$a}->{stats})
 150 } keys %{ $caniuse->{data} }) {
 151         my $row = $caniuse->{data}->{$id};
 152         my $data = $row->{stats} or next;  # skip metadata [summary]
 153         printf '<tr id="%s">', $id;
 154         for ($row->{categories}) {
 155                 my $cell = $_ ? lc $_->[0] : '-';
 156                 print '<th>', $cell;
 157         }
 158         print '<td>', map {
 159                 sprintf('<a href="%s" onclick="%s">%s</a>',
 160                         "#$id",
 161                         sprintf("try { %s; return false } catch(err) { return true }",
 162                                 "document.getElementById('$id').classList.toggle('target')",
 163                         ),
 164                         $_,
 165                 );
 166         } $row->{title};
 167         print '<div class=aside>';
 168         s/\.?$/./, print "<p>$_</p>" for map { ref $_ ? @$_ : $_ || () }
 169                 $row->{description}, $row->{notes};
 170         printf 'Resources: %s.', join(', ',
 171                 map { qq(<a href="$_->{url}">$_->{title}</a>) } @$_
 172         ) for grep { @$_ } $row->{links} // ();
 173         print '</div>';
 174         for ($row->{status}) {
 175                 my $cell = $_ // '-';
 176                 $cell = sprintf '<a href="%s">%s</a>', $_, $cell for $row->{spec} // ();
 177                 printf '<td title="%s" class="%s">%s',
 178                         $caniuse->{statuses}->{$_}, $CSTATUS{$_} // '', $cell;
 179         }
 180         for my $browser (@browsers) {
 181                 my ($prev, @span);
 182                 for my $ver (@{ $versions{$browser} }, undef) {
 183                         unless (!defined $prev
 184                         or ref $data->{$browser} eq 'HASH'
 185                         && $data->{$browser}->{$prev} ~~ $data->{$browser}->{$ver}) {
 186                                 my $usage = sum(map { $canihas->{$browser}->{$_} } @span);
 187                                 printf '<td class="%s" colspan="%d" title="%.1f%%">%s',
 188                                         join(' ',
 189                                                 X => $CSTATS{
 190                                                         ref $data->{$browser} ne 'HASH' ? 'u' :
 191                                                                 $data->{$browser}->{$prev} // 'u'
 192                                                 },
 193                                                 !$usage ? ('p0') : ('p',
 194                                                         sprintf('p%01d', $usage / 10),
 195                                                         sprintf('p%02d', $usage),
 196                                                 ),
 197                                                 sprintf('pp%02d', $usage / $scorediv),
 198                                         ),
 199                                         scalar @span,
 200                                         $usage,
 201                                         showversions(@span),
 202                                 undef $prev;
 203                                 @span = ();
 204                         }
 205                         push @span, $ver;
 206                         $prev = $ver;
 207                 }
 208         }
 209         state $maxscore = featurescore({  # yes for every possible version
 210                 map { $_ => { map {$_ => 'y'} @{$versions{$_}} } } keys %versions
 211         });
 212         print '<td>', int featurescore($caniuse->{data}->{$id}->{stats}) / $maxscore * 100;
 213 }
 214 print '<tfoot>', $header;
 215 print '</table>';
 216
 217 sub paddedver {
 218         # normalised version number comparable as string (cmp)
 219         shift =~ /^(\d*)(.*)/;
 220         return sprintf('%02d', $1 || 0) . $2;
 221 }
 222
 223 sub showversions {
 224         my @span = ($_[0], @_>1 ? $_[-1] : ());
 225         for (@span) {
 226                 s/^\./0./;
 227                 s/x$/.*/;
 228         }
 229         return join('‒', @span);
 230 }
 231
 232 :></div>
 233
 234 <hr>
 235
 236 <div class="legend">
 237         <table class="glyphs"><tr>
 238         <td class="X l5">supported
 239         <td class="X l4">prefixed
 240         <td class="X l3">partial
 241         <td class="X l2">external (js/plugin)
 242         <td class="X l1">missing
 243         <td class="X l0">unknown
 244         </table>
 245
 246         <div>
 247                 Usage percentage:
 248                 <span class="  p0">0</span> -
 249                 <span class="p p0 p00">.01</span> -
 250                 <span class="p p0 p05">1-9</span> -
 251                 <span class="p p1">10</span> -
 252                 <span class="p p2">20</span> -
 253                 <span class="p p5">majority</span>
 254         </div>
 255
 256         <div class="right">
 257                 <ul class="legend legend-set">
 258                 <li>default <strong>style</strong> is
 259                         <:= defined $get{style} && 'set to ' :><em><:= $style :></em>
 260                 </ul>
 261         </div>
 262 </div>
 263