chars.plp

   1 <(common.inc.plp)><:
   2
   3 Html({
   4         title => 'character support sheet',
   5         version => 'v1.0',
   6         keywords => [qw'
   7                 unicode glyph char character reference common ipa symbol sign mark table digraph
   8         '],
   9         stylesheet => [qw'light dark mono circus red'],
  10         data => [qw( unicode-cover.inc.pl ttfsupport unicode-char.inc.pl )],
  11 });
  12
  13 use 5.010;
  14 use Shiar_Sheet::FormatChar;
  15 my $glyphs = Shiar_Sheet::FormatChar->new;
  16
  17 my $groupinfo = do 'unicode-cover.inc.pl' or die $@ || $!;
  18
  19 my @ossel = @{ $groupinfo->{osdefault} };
  20 my @fontlist = map { $_->{file} }
  21         @{ $groupinfo->{fonts} }[ map { @{ $groupinfo->{os}->{$_} } } @ossel ];
  22
  23 my %font;
  24 for my $fontid (@fontlist) {
  25                 my ($fontmeta, @fontrange) = do "ttfsupport/$fontid.inc.pl";
  26                 $fontmeta or next;
  27                 $font{$fontid} = {
  28                         (map { (-$_ => $fontmeta->{$_}) } keys %{$fontmeta}),
  29                         map { (chr $_ => 1) } @fontrange
  30                 };
  31 }
  32
  33 # parse input
  34
  35 my ($title, $parent) = ('Character overview');
  36 my $query = eval {
  37         for ($ENV{PATH_INFO} || ()) {
  38                 s{^/}{};
  39                 return $_ if m{^[0-9 +-]+$};
  40
  41                 my ($cat, $name) = split m{/}, $_, 2 or die "invalid query\n";
  42                 if (!$name) {
  43                         ($cat, $name) = ('table', $cat);
  44                 }
  45
  46                 my $row = $groupinfo->{$cat}->{$name}
  47                         or die "unknown character group $cat/$name\n";
  48
  49                 $title = ucfirst EscapeHTML($name).' characters';
  50                 $parent = $cat;
  51                 return EscapeHTML($row->{query});
  52         }
  53 } || $get{q};
  54
  55 say "<h1>$title</h1>";
  56
  57 if (!$query) {
  58         say "<p>Unicode group not specified: $@</p>";
  59         exit;
  60 };
  61
  62 for ($parent || 'Unicode range') {
  63         my %CATDESC = (
  64                 block    => '<a href="/charset/unicode">Unicode block</a>',
  65                 script   => 'Unicode script',
  66                 category => 'Unicode category',
  67                 table    => '<a href="/unicode">Unicode preset group</a>',
  68         );
  69         say sprintf('<p>List %s in selected %s.</p>',
  70                 'characters and <a href="/font">font support</a>',
  71                 $CATDESC{$parent} || $parent,
  72         );
  73 }
  74
  75 my @chars;
  76 for (map { split /[^\d-]/ } $query) {
  77         my @range = split /-/, $_, 2;
  78         m/^[0-9]+$/ or die "Invalid code point $_ in query $query\n" for @range;
  79         push @chars, chr $_ for $range[0] .. ($range[1] // $range[0]);
  80 }
  81
  82 @chars or die "No match for query $query\n";
  83
  84 @chars <= 1500 or die sprintf(
  85         'Too many matches (%d) for query %s'."\n",
  86         scalar @chars, $query,
  87 );
  88
  89 # output character list
  90
  91 say '<div>';
  92 print '<table class=mapped>';
  93 print '<col>' x 3;
  94 print "<colgroup span=$_>"
  95         for 2, map { scalar @{ $groupinfo->{os}->{$_} } } @ossel;
  96
  97 print '<thead><tr>';
  98 print '<td colspan=3>character';
  99 print '<td colspan=2>input';
 100 printf '<td colspan=%d>%s', scalar @{ $groupinfo->{os}->{$_} }, $_
 101         for @ossel;
 102
 103 print '<tr>';
 104 print '<td colspan=2>unicode';
 105 print '<td>name';
 106 print '<td><a href="/digraphs" title="digraph">di</a><td>html';
 107 printf('<td title="%s">%s', map { EscapeHTML($_) }
 108         join("\n", $font{$_}->{-name}, $font{$_}->{-description}),
 109         $font{$_}->{-abbr},
 110 ) for @fontlist;
 111 say '</thead>';
 112
 113 for my $chr (@chars) {
 114         my $codepoint = ord $chr;
 115         my $ascii = $codepoint <= 127;
 116
 117         print "<tr><th>$chr\n";
 118         my $info = $glyphs->glyph_info($codepoint);
 119         my ($class, $name, $mnem, $html, $string) = @$info;
 120         print "<td>$_" for sprintf('%X', $codepoint), EscapeHTML($name || '?');
 121         printf '<td class="%s">%s', @$_ for (
 122                 [$ascii ? 'l0' : defined $mnem ? $class =~ /\bu-di\b/ ? 'l4' : 'l3' : 'l1',
 123                         EscapeHTML($mnem) // ''],
 124                 [$ascii ? 'l0' : defined $html ? 'l4' : 'l1', $html // ''],
 125                 (map {
 126                         !defined $font{$_}->{-name} ? [l0 => '?'] :
 127                         $font{$_}->{$chr} ? [l4 => '✔'] : [l1 => '✘']
 128                 } @fontlist),
 129         );
 130 }
 131
 132 say "</table>\n";
 133 say "</div>\n";
 134