tools/mkfontinfo

   1 #!/usr/bin/env perl
   2 use 5.010;
   3 use strict;
   4 use warnings;
   5 use utf8;
   6
   7 use open OUT => ':utf8', ':std';
   8 use List::Util 'reduce';
   9 use File::Basename 'basename';
  10 use Data::Dump 'pp';
  11
  12 our $VERSION = '1.00';
  13
  14 my %font;
  15 my $incsuffix = '.inc.pl';
  16 for my $fontfile (glob 'ttfsupport/*'.$incsuffix) {
  17         my ($fontid) = basename($fontfile, $incsuffix);
  18         my ($fontmeta, @fontrange) = do $fontfile or next;
  19         $font{$fontid} = {
  20                 -id   => $fontmeta->{id} || $fontid,
  21                 -name => $fontmeta->{name},
  22                 map { (chr $_ => 1) } @fontrange
  23         };
  24 }
  25
  26 my %charlist;
  27
  28 my $chartables = do 'unicode-table.inc.pl' or warn $@ || $!;
  29 if ($chartables) {
  30         while (my ($tablegroup, $grouprow) = each %{$chartables}) {
  31                 while (my ($tablename, $chars) = each %{$grouprow}) {
  32                         next if $tablename =~ /^-/;
  33                         my $includerows;  # ignore rows before body row
  34                         for (@{$chars}) {
  35                                 $includerows ||= m/^[.]/ or next;
  36                                 next if /^[.-]/;
  37                                 next if $_ eq '>' or $_ eq '=';
  38                                 s/^\\//;  # escape
  39                                 push @{ $charlist{table}->{"$tablegroup/$tablename"} }, $_;
  40                                 push @{ $charlist{table}->{$tablegroup} }, $_;
  41                         }
  42                 }
  43 #               if ($tablegroup eq 'ipa') {
  44 #                       @chars = grep { !m/[a-zA-Z]/ } @chars;
  45 #               }
  46         }
  47 }
  48
  49 use Unicode::UCD 'charinfo';
  50 for my $code (0 .. 256**2) {
  51         my $charinfo = charinfo($code) or next;
  52         next if $charinfo->{category} =~ /^[MC]/;  # ignore Marks and "other" Control chars
  53         push @{ $charlist{$_}->{ $charinfo->{$_} } }, chr $code
  54                 for qw( script category block );
  55 }
  56
  57 for (values %charlist) {
  58 for my $chars (values %{$_}) {
  59         my %row = map {
  60                 my $fontcover = $font{$_};
  61                 ($_ => scalar grep { $fontcover->{$_} } @{$chars});
  62         } keys %font;
  63         $row{-count} = scalar @{$chars};
  64
  65         $row{-query} = eval {
  66                 my @query = map { ord } sort @{$chars};
  67                 my $i = 0;
  68                 while ($i < @query) {
  69                         my $j = $i + 1;
  70                         my $v = $query[$i];
  71                         while ($j < @query) {
  72                                 $v++;
  73                                 last if $query[$j] != $v;
  74                                 $j++;
  75                         }
  76                         if ($j - $i > 2) {
  77                                 splice(@query, $i, $j - $i, "$query[$i]-$query[$j-1]");
  78                         }
  79                         $i++;
  80                 }
  81                 return join '+', @query;
  82         };
  83
  84         $chars = \%row;
  85 }
  86 }
  87
  88 say 'use utf8;';
  89 say '+'.pp(\%charlist);
  90
  91 __END__
  92
  93 =head1 NAME
  94
  95 mkfontinfo - Prepare font coverage of various character groups
  96
  97 =head1 SYNOPSIS
  98
  99     mkfontinfo > unicode-cover.inc.pl
 100
 101 Test by finding the number of cyrillic characters in DejaVu Sans:
 102
 103     perl -E'$f = do "unicode-cover.inc.pl"; say $f->{Cyrillic}->{dvsans}'
 104
 105 =head1 AUTHOR
 106
 107 Mischa POSLAWSKY <perl@shiar.org>
 108
 109 =head1 LICENSE
 110
 111 Licensed under the GNU Affero General Public License version 3.
 112