browser.plp

   1 <(common.inc.plp)><:
   2 use 5.010;
   3 use utf8;
   4 use List::Util qw(sum max first);
   5 no if $] >= 5.018, warnings => 'experimental::smartmatch';
   6
   7 Html({
   8         title => 'browser compatibility cheat sheet',
   9         version => '1.3',
  10         description => [
  11                 "Compatibility table of new web features (HTML5, CSS3, SVG, Javascript)",
  12                 "comparing support and usage share for all popular browser versions.",
  13         ],
  14         keywords => [qw'
  15                 web browser support compatibility usage matrix available feature
  16                 html html5 css css3 svg javascript js dom mobile
  17                 ie internet explorer firefox chrome safari webkit opera
  18         '],
  19         stylesheet => [qw'circus dark mono red light'],
  20         data => ['data/browser/support.inc.pl'],
  21 });
  22
  23 say "<h1>Browser compatibility</h1>\n";
  24
  25 my $caniuse = do 'data/browser/support.inc.pl' or die $@ || $!;
  26 $_->{verrelease} = {
  27         # mark last three (future) versions as unreleased, ensure current isn't
  28         map {
  29                 $_->[-1] => 0, $_->[-2] => 0, $_->[-3] => 0,
  30                 $_->[-4] => undef,
  31         } $_->{versions}
  32 } for values %{ $caniuse->{agents} };
  33
  34 my %CSTATS = (
  35         'n'   => 'l1',
  36         'n d' => 'l2',
  37         'n x d' => 'l2 ex',
  38         'p d' => 'l2',
  39         'a d' => 'l2',
  40         'y'   => 'l5',
  41         'y x' => 'l5 ex',
  42         'a'   => 'l3',
  43         'a x' => 'l3 ex',
  44         'p j' => 'l2',
  45         'j'   => 'l2',
  46         'p'   => 'l2',
  47         'p p' => 'l2',
  48         'u'   => 'l0',
  49 );
  50 my %DSTATS = (
  51         u => 'unknown',
  52         n => 'unsupported',
  53         p => 'plugin required',
  54         j => 'javascript required',
  55         a => 'partial',
  56         y => 'supported',
  57         d => 'disabled by default',
  58         x => sub {
  59                 join(' ',
  60                         'requires prefix',
  61                         map {"-$_-"}
  62                         ($caniuse->{agents}->{$_[0]}->{prefix_exceptions} // {})->{$_[1]}
  63                         // $caniuse->{agents}->{$_[0]}->{prefix} // (),
  64                 );
  65         },
  66 );
  67 my %PSTATS = (  # score percentage
  68         y => 1,  'y x' => .9,
  69         a => .5, 'a x' => .5, 'a d' => .1,
  70         j => .2, 'p j' => .2, 'n d' => .2, 'n x d' => .2,
  71         p => .2, 'p p' => .2, 'p d' => .1,
  72 );
  73 my %CSTATUS = (
  74         unoff => 'l1', # unofficial
  75         wd    => 'l2', # draft
  76         cr    => 'l3', # candidate
  77         pr    => 'l3', # proposed
  78         rec   => 'l5', # recommendation
  79         ls    => 'l4', # whatwg
  80         ietf  => 'l0', # standard
  81         other => 'l0', # non-w3
  82 );
  83 my %versions;
  84 if (my ($somerow) = values %{ $caniuse->{data} }) {
  85         while (my ($browser, $row) = each %{ $somerow->{stats} }) {
  86                 $versions{$browser} = [ sort { paddedver($a) cmp paddedver($b) } keys %$row ];
  87         }
  88 }
  89
  90 print <<'';
  91 <p id="intro">Alternate rendition of Fyrd's <a href="http://caniuse.com/">when can I use...</a> page
  92
  93 my ($canihas, $usage);
  94 my $minusage = $get{threshold} // .7;
  95 given ($get{usage} // 'wm') {
  96         when (!$_) {
  97                 # none
  98         }
  99         when (!m{ \A [a-z]\w+ (?:/\d[\d-]*\d)? \z }x) {
 100                 printf "<p>Invalid browser usage data request: <em>%s</em>",
 101                         'identifier must be alphanumeric name or <q>0</q>';
 102         }
 103         $canihas = do "data/browser/usage-$_.inc.pl" or do {
 104                 printf "<p>Browser usage data not found: <em>%s</em>", $@ || $!;
 105                 break;
 106         };
 107         $usage = $_;
 108         my $ref = $canihas->{-title} || 'unknown';
 109         $ref = sprintf '<a href="%s">%s</a>', $_, $ref
 110                 for $canihas->{-site} || $canihas->{-source} || ();
 111         $ref .= " $_" for $canihas->{-date} || ();
 112         print "\nwith $ref browser usage statistics";
 113 }
 114
 115 my @browsers;
 116 if ($usage) { # first() does not work inside given >:(
 117         # adapt version usage to actual support data
 118         my %engineuse;  # prefix => usage sum
 119         for my $browser (keys %versions) {
 120                 my $row = $canihas->{$browser} // {};
 121                 my $verlist = $versions{$browser} or next;
 122                 if ($minusage and sum(values %$row) < $minusage) {
 123                         delete $versions{$browser};
 124                         next;
 125                 }
 126                 my %supported = map { $_ => 1 } @$verlist;
 127
 128                 # cascade unknown versions
 129                 $row->{$_} //= undef for @$verlist;  # ensure stable keys during iteration
 130                 while (my ($version, $usage) = each %$row) {
 131                         next if defined $supported{$version};
 132                         my $next = first { paddedver($_) ge paddedver($version) } @$verlist
 133                                 or warn("No fallback found for $browser v$version; $usage% ignored"), next;
 134                         $row->{$next} += $usage;
 135                         $row->{$version} = 0;  # balance browser total
 136                 }
 137
 138                 # build row list for each version
 139                 if ($minusage) {
 140                         my @vershown;  # $verlist replacement
 141                         my ($rowusage, @verrow) = (0);  # replacement row tracking
 142                         for (@$verlist) {
 143                                 push @verrow, $_;  # queue each version
 144                                 if (($rowusage += $row->{$_}) >= $minusage) {
 145                                         push @vershown, [@verrow];   # add row
 146                                         ($rowusage, @verrow) = (0);  # reset row tracking
 147                                 }
 148                         }
 149                         push @vershown, \@verrow if @verrow;  # always add latest
 150                         @$verlist = @vershown;
 151                 }
 152                 else {
 153                         @$verlist = map { [$_] } @$verlist;
 154                 }
 155
 156                 # reusable aggregates (grouped by prefix (engine) and browser)
 157                 $engineuse{ $caniuse->{agents}->{$browser}->{prefix} } +=
 158                 $row->{-total} = sum(values %$row);
 159         }
 160
 161         # order browser columns by usage grouped by engine
 162         @browsers = sort {
 163                 $engineuse{ $caniuse->{agents}->{$b}->{prefix} } <=>
 164                 $engineuse{ $caniuse->{agents}->{$a}->{prefix} }
 165                         ||
 166                 $canihas->{$b}->{-total} <=> $canihas->{$a}->{-total}
 167         } keys %versions;
 168 }
 169 else {
 170         # order browser columns by name grouped by engine
 171         @{$_} = map { [$_] } @{$_} for values %versions;
 172         @browsers = sort {
 173                 $caniuse->{agents}->{$b}->{prefix} cmp
 174                 $caniuse->{agents}->{$a}->{prefix}
 175                         ||
 176                 $a cmp $b
 177         } keys %versions;
 178 }
 179 :>.
 180 </p>
 181
 182 <:
 183 $canihas ||= {
 184         map {
 185                 $_ => +{
 186                         map {
 187                                 my $zero = $#$_ - 2;  # baseline index
 188                                 ($_->[$zero - 2] =>  .5), # past
 189                                 ($_->[$zero - 1] => 10 ), # previous
 190                                 ($_->[$zero + 2] =>  0 ), # future
 191                                 ($_->[$zero + 1] =>  .5), # next
 192                                 ($_->[$zero    ] => 30 ), # current
 193                         } $caniuse->{agents}->{$_}->{versions}
 194                 }
 195         } @browsers
 196 }; # fallback hash based on release semantics
 197 my $usagemax = (max(map { ref $_ eq 'HASH' && sum(values %$_) } values %$canihas) // 1) / 100;
 198
 199 my $usagepct = 1;  # score multiplier for 0..100 result
 200 # normalise usage percentage to only include shown browsers
 201 $usagepct = 100.01 / featurescore({  # yes for every possible version
 202         map { $_ => { map {$_ => 'y'} map { @{$_} } @{$versions{$_}} } } keys %versions
 203 });
 204
 205 print '<table class="mapped">';
 206 print '<col span="3">';  # should match first thead row
 207 printf '<colgroup span="%d">', scalar @{ $versions{$_} } for @browsers;
 208 say '</colgroup><col>';
 209
 210 my $header = join('',
 211         '<tr>',
 212         '<th colspan="3" rowspan="2">feature',
 213         (map {
 214                 my $name = $caniuse->{agents}->{$_}->{browser};
 215                 sprintf('<th colspan="%d" class="%s" title="%s">%s',
 216                         scalar @{ $versions{$_} },
 217                         join(' ', map {"b-a-$_"} grep {$_}
 218                                 $_, @{ $caniuse->{agents}->{$_} }{'prefix', 'type'},
 219                         ),
 220                         join(' ',
 221                                 sprintf('%.1f%%', $canihas->{$_}->{-total} * $usagepct),
 222                                 $name,
 223                         ),
 224                         do {
 225                                 length $name <= (3 * @{ $versions{$_} }) ? $name
 226                                         : $caniuse->{agents}->{$_}->{abbr};
 227                         },
 228                 )
 229         } @browsers),
 230         '<th rowspan="2">%',
 231 );
 232 print '<thead>', $header;
 233 # preceding row without any colspan to work around gecko bug
 234 print "\n<tr>";
 235 for my $browser (@browsers) {
 236         for (@{ $versions{$browser} }) {
 237                 my $lastver = $_->[-1];
 238                 my $release = $caniuse->{agents}->{$browser}->{verrelease}->{$lastver};
 239                 my $future = defined $release;
 240                 printf('<td title="%s"%s>%s',
 241                         join(' ',
 242                                 sprintf('%.1f%%', sum(@{ $canihas->{$browser} }{@$_}) * $usagepct),
 243                                 $future ? 'development' : (),
 244                                 'version ' . join(', ', @{$_}),
 245                         ),
 246                         $future && ' class="ex"',
 247                         showversions($lastver),
 248                 );
 249         }
 250 }
 251 say '</thead>';
 252 say '<tfoot>', $header;
 253 {
 254         # prefix indicates browser family; count adjacent families
 255         my (@families, %familycount);
 256         for my $browser (@browsers) {
 257                 my $family = $caniuse->{agents}->{$browser}->{prefix};
 258                 push @families, $family unless $familycount{$family};
 259                 $familycount{$family} += @{ $versions{$browser} };
 260         }
 261
 262         print "\n", '<tr class="cat">';
 263         printf '<th colspan="%d">%s', $familycount{$_}, $_ for @families;
 264 }
 265 say '</tfoot>';
 266
 267 sub featurescore {
 268         # relative amount of support for given feature
 269         my $rank = 0;
 270         if (my $row = shift) {
 271                 if ($canihas) {
 272                         while (my ($browser, $versions) = each %$row) {
 273                                 ref $versions eq 'HASH' or next;
 274                                 while (my ($version, $status) = each %$versions) {
 275                                         $status =~ s/\h\#\d+//;
 276                                         $rank += ($canihas->{$browser}->{$version} || .001) * $PSTATS{$status};
 277                                 }
 278                         }
 279                         return $rank;
 280                 }
 281
 282                 while (my ($browser, $vercols) = each %versions) {
 283                         my $div = 0;  # multiplier exponent (decreased to lower value)
 284                         my @vers = map { $row->{$browser}->{$_} } @$vercols;
 285                         if (my $current = $caniuse->{agents}->{$browser}->{versions}->[-3]) {
 286                                 my @future;  # find upcoming releases (after current)
 287                                 for (reverse @$vercols) {
 288                                         last if $_ eq $current;
 289                                         push @future, pop @vers;
 290                                         $_ eq 'u' and $_ = $vers[-1] for $future[-1];  # inherit latest value if unknown
 291                                 }
 292                                 splice @vers, -1, 0, @future;  # move ahead to decrease precedence
 293                         }
 294                         $rank += $PSTATS{$_} * 2**($div--) for reverse @vers;
 295                 }
 296         }
 297         return $rank;
 298 }
 299
 300 sub formatnotes {
 301         my @html = @_;
 302         for (@html) {
 303                 s/\r\n?/\n/g;  # windows returns
 304                 s/\h* $//gmx;  # trailing whitespace
 305                 s/(?<= [^.\n]) $/./gmx;  # consistently end each line by a period
 306                 Entity($_);
 307                 s{  ` ([^`]*)  ` }{<code>$1</code>}gx;
 308                 s{ \[ ([^]]*) \] \( ([^)]*) \) }{<a href="$2">$1</a>}gx;
 309         }
 310         return @html;
 311 }
 312
 313 sub saytitlecol {
 314         my ($id) = @_;
 315         my $row = $caniuse->{data}->{$id};
 316
 317         for ($row->{categories}) {
 318                 my $cell = $_ ? lc $_->[0] : '-';
 319                 $cell =~ s/ api$//;  # trim unessential fluff in 'js api'
 320                 printf '<th title="%s">%s', join(' + ', @$_), $cell;
 321         }
 322
 323         print '<td>', map {
 324                 sprintf('<a href="%s" onclick="%s">%s</a>',
 325                         "#$id",
 326                         sprintf("try { %s; return false } catch(err) { return true }",
 327                                 "document.getElementById('$id').classList.toggle('target')",
 328                         ),
 329                         Entity($_),
 330                 );
 331         } $row->{title};
 332         print '<div class=aside>';
 333         print "<p>$_</p>"
 334                 for formatnotes($row->{description}, $row->{notes} || ());
 335         if (my %notes = %{ $row->{notes_by_num} }) {
 336                 say '<p>Browser-specific notes:';
 337                 say "<br>#$_: ", formatnotes($notes{$_}) for sort keys %notes;
 338                 say '</p>';
 339         }
 340         printf 'Resources: %s.', join(', ', map {
 341                 sprintf '<a href="%s">%s</a>', EscapeHTML($_->{url}), $_->{title}
 342         } @$_) for grep { @$_ } $row->{links} // ();
 343         printf '<br>Parent feature: %s.', join(', ', map {
 344                 sprintf '<a href="%s">%s</a>', EscapeHTML("#$_"), $caniuse->{data}->{$_}->{title}
 345         } $_) for $row->{parent} || ();
 346         print '</div>';
 347 }
 348
 349 sub saystatuscol {
 350         my ($id) = @_;
 351         my $row = $caniuse->{data}->{$id};
 352
 353         for ($row->{status}) {
 354                 my $cell = $_ // '-';
 355                 $cell = sprintf '<a href="%s">%s</a>', $_, $cell for $row->{spec} // ();
 356                 printf '<td title="%s" class="l %s">%s',
 357                         $caniuse->{statuses}->{$_}, $CSTATUS{$_} // '', $cell;
 358         }
 359 }
 360
 361 sub saybrowsercols {
 362         my ($id, $browser) = @_;
 363         my $feature = $caniuse->{data}->{$id};
 364         my $data = $feature->{stats}->{$browser};
 365         if (ref $data eq 'ARRAY') {
 366                 # special case for unsupported
 367                 my $release = $caniuse->{agents}->{$browser}->{verrelease};
 368                 $data = {
 369                         map { $_ => defined $release->{$_} ? 'u' : 'n' } keys %$release
 370                 };
 371         }
 372
 373         my ($prev, @span);
 374         for my $ver (@{ $versions{$browser} }, undef) {
 375                 my $compare = (
 376                         !defined $ver ? undef :      # last column if nameless
 377                         ref $data ne 'HASH' ? '' :   # unclassified if no support hash
 378                         $data->{ $ver->[-1] } // $prev  # known or inherit from predecessor
 379                         // (grep { defined } @{$data}{ map { $_->[0] } @{ $versions{$browser} } })[0]
 380                            ~~ 'n' && 'n'             # first known version is unsupported
 381                         || 'u'                       # unsure
 382                 );
 383                 unless (!defined $prev or $prev ~~ $compare) {
 384                         my $usage = sum(@{ $canihas->{$browser} }{ map { @{$_} } @span });
 385
 386                         # strip #\d note references from support class
 387                         my @notes;
 388                         push @notes, $feature->{notes_by_num}->{$1}
 389                                 while $prev =~ s/\h \# (\d+) \b//x;
 390
 391                         # prepare version hover details
 392                         my $title = sprintf('%.1f%% %s', $usage * $usagepct, join(', ',
 393                                 map { ref $_ eq 'CODE' ? $_->($browser, $span[0]->[0]) : $_ }
 394                                 map { $DSTATS{$_} // () }
 395                                 map { split / /, $_ }
 396                                 $prev
 397                         ));
 398                         $title .= "\n".EscapeHTML($_) for @notes;
 399
 400                         printf('<td class="%s" colspan="%d" title="%s">%s',
 401                                 join(' ',
 402                                         X => $CSTATS{$prev},
 403                                         !$usage ? ('p0') : ('p',
 404                                                 sprintf('p%01d', $usage * ($usagepct - .0001) / 10),
 405                                                 sprintf('p%02d', $usage * ($usagepct - .0001)),
 406                                         ),
 407                                         sprintf('pp%02d', $usage / $usagemax),
 408                                 ),
 409                                 scalar @span,
 410                                 $title,
 411                                 showversions($span[0]->[0], @span > 1 ? ($span[-1]->[-1]) : ()),
 412                         );
 413                         undef $prev;
 414                         @span = ();
 415                 }
 416                 push @span, $ver && [ grep { $data->{ $_ } eq $data->{ $ver->[-1] } } @{$ver} ];
 417                 $prev = $compare;
 418         }
 419 }
 420
 421 sub sayusagecol {
 422         my ($id) = @_;
 423         print '<td>', int featurescore($caniuse->{data}->{$id}->{stats}) * $usagepct;
 424 }
 425
 426 say '<tbody>';
 427 for my $id (sort {
 428             featurescore($caniuse->{data}->{$b}->{stats})
 429         <=> featurescore($caniuse->{data}->{$a}->{stats})
 430 } keys %{ $caniuse->{data} }) {
 431         $caniuse->{data}->{$id}->{stats} or next;  # skip metadata [summary]
 432         printf '<tr id="%s">', $id;
 433         saytitlecol($id);
 434         saystatuscol($id);
 435         saybrowsercols($id, $_) for @browsers;
 436         sayusagecol($id);
 437         say '</tr>';
 438 }
 439 say '</tbody>';
 440 say '</table>';
 441
 442 sub paddedver {
 443         # normalised version number comparable as string (cmp)
 444         shift =~ /(?:.*-|^)(\d*)(.*)/;
 445         # matched (major)(.minor) of last value in range (a-B)
 446         return sprintf('%02d', $1 || 99) . $2;
 447 }
 448
 449 sub showversions {
 450         my @span = ($_[0], @_>1 ? $_[-1] : ());
 451         s/-.*// for $span[0];
 452         for (@span) {
 453                 s/^\./0./;
 454                 s/x$/.*/;
 455                 s/.*-//;
 456         }
 457         return join('‒', @span);
 458 }
 459
 460 :>
 461 <hr>
 462
 463 <div class="legend">
 464         <table class="glyphs"><tr>
 465         <td class="X l5">supported
 466         <td class="X l3">partial
 467         <td class="X l2">optional
 468         <td class="X l1">missing
 469         <td class="X l0">unknown
 470         <td class="X ex">prefixed
 471         </table>
 472
 473         <p><: if ($usage) { :>
 474                 Usage percentage:
 475                 <span class="  p0">0</span> -
 476                 <span class="p p0 p00">.01</span> -
 477                 <span class="p p0 p05">1-9</span> -
 478                 <span class="p p1">10</span> -
 479                 <span class="p p2">20</span> -
 480                 <span class="p p5">majority</span>
 481 <: } else { :>
 482                 <table class="glyphs"><tr>
 483                         <td class="p p1">previous version</td>
 484                         <td class="p p3">current</td>
 485                         <td class="p p0 p00">upcoming (within months)</td>
 486                         <td class="  p0">future (within a year)</td>
 487                 </table>
 488 <: } :> </p>
 489
 490         <div class="right">
 491                 <ul class="legend legend-set">
 492                 <li>default <strong>style</strong> is
 493                         <:= defined $get{style} && 'set to ' :><em><:= $style :></em>
 494                 <li><strong>usage</strong> source is
 495                         <:= !defined $get{usage} && 'default ' :><:= defined $usage ? "<em>$usage</em>" : 'not included (<em>0</em>)' :>
 496                 <li>usage <strong>threshold</strong> is
 497                         <:= defined $get{threshold} && 'changed to ' :><em><:= $minusage :>%</em>
 498                 </ul>
 499         </div>
 500 </div>
 501
 502 <script type="text/javascript" src="/searchlocal.js"></script>
 503 <script type="text/javascript"> prependsearch(document.getElementById('intro')) </script>
 504