Shiar_Sheet/Keyboard.pm

   1 package Shiar_Sheet::Keyboard;
   2
   3 use strict;
   4 use warnings;
   5 no  warnings 'uninitialized';  # save some useless checks for more legible code
   6 use Carp;
   7
   8 our $VERSION = 'v2.02';
   9
  10 my @casedesc = (undef, qw/shift ctrl meta/, 'shift meta');
  11 my @rowdesc = qw(numeric top home bottom);
  12 my %keyrows = do 'keys.inc.pl';
  13 # add first two cases of each row again with each char prepended by + (alt)
  14 push @$_, map { [map {"+$_"} @$_] } @$_[0,1] for map {@$_} values %keyrows;
  15
  16 my %keytrans = qw(
  17         ^@ NUL ^a SOH ^b STX ^c ETX  ^d EOT ^e ENQ ^f ACK ^g BEL
  18         ^h BS  ^i tab ^j LF  ^k VT   ^l FF  ^m CR  ^n SO  ^o SI
  19         ^p DLE ^q DC1 ^r DC2 ^s DC3  ^t DC4 ^u NAK ^v SYN ^w ETB
  20         ^x CAN ^y EM  ^z SUB ^[ ESC  ^\ FS  ^] GS  ^^ RS  ^_ US
  21         ^? DEL
  22 );
  23
  24 sub new {
  25         my $class = shift;
  26         my ($self) = @_;
  27
  28         croak 'Invalid keyboard definitions specified' unless ref $self eq 'HASH';
  29         croak 'No key definitions specified' unless ref $self->{def} eq 'HASH';
  30         $self->{map} ||= 'qwerty';
  31
  32         my $parent = (caller)[0];  # calling module
  33         my $sign = do {
  34                 no strict 'refs';  # temporarily allow variable references
  35                 \%{ $parent.'::sign' };  # return %sign from parent
  36         };
  37         croak "%${parent}::sign not found" unless %$sign;
  38         $self->{sign} = $sign;
  39
  40         bless $self, $class;
  41 }
  42
  43 sub map {
  44         my $self = shift;
  45         my ($mapname) = @_;
  46
  47         return $self->{map} = $mapname if defined $keyrows{$mapname};
  48         return undef;
  49 }
  50
  51 sub escapeclass {
  52         local $_ = shift;
  53         s/\^/_c/g;
  54         s/\+/_m/g;
  55         s/\[/_sbo/g;
  56         s/\]/_sbc/g;
  57         s/^$/_/;
  58         return $_;
  59 }
  60
  61 sub escapehtml {
  62         local $_ = shift;
  63         s/</&lt;/g;
  64         s/>/&gt;/g;
  65         s/  / &nbsp;/g;
  66         return $_;
  67 }
  68
  69 sub keyunalias {
  70         my $self = shift;
  71         my ($key, $ancestry) = @_;
  72
  73         $key =~ s/(\S*?)(\+?\^?\S)($|\s.*)/$2/;
  74         my $mode = $1;
  75         my $keyinfo = $self->{def}->{$mode}->{$key};
  76
  77         return unless defined $keyinfo;
  78         return $keyinfo->[0] if ref $keyinfo;
  79         return '' if $ancestry->{$key}++;  # endless loop failsafe
  80         return $self->keyunalias($keyinfo, $ancestry);
  81 }
  82
  83 sub print_key {
  84         my $self = shift;
  85         my ($mode, $key, $flags) = @_;
  86
  87         if (not defined $flags) {
  88                 $flags = [$key eq '^0' ? 'ni' : 'no'];
  89         }
  90         elsif (not ref $flags) { # alias
  91                 my $desc = $self->{sign}->{alias};
  92                 $desc .= $flags eq "\e" ? 'esc' : $flags;
  93                 $flags = [$self->keyunalias($flags) . ' alias', $desc];
  94         }
  95         my ($flags, $desc, $mnem) = @{$flags};
  96         if (my $txt = $self->{key}->{$mode.$key}) {
  97                 ($desc, $mnem) = @{$txt};
  98         }
  99
 100 #       $key = $keytrans{$key} if defined $keytrans{$key};
 101         my $keytxt = $key eq "\e" ? 'Esc' : $self->{def}{$mode}{lead} . escapehtml($key) if $key ne '^0';
 102            $keytxt .= $self->{sign}->{$1} while $flags =~ s/(?:^| )(arg[a-ln-z]?)\b//;  # arguments
 103            $keytxt .= "<small>$self->{sign}->{motion}</small>" if $flags =~ s/ ?\bargm\b//;  # motion argument
 104            $keytxt =~ s{\^(?=.)}{<small>^</small>};  # element around ctrl-identifier
 105            $keytxt =~ s{\+(?=.)}{<small>+</small>};  # meta
 106         my $keyhint = defined($mnem) && qq{ title="$mnem"};
 107            $keytxt  = "<b$keyhint>$keytxt</b>";
 108            $keytxt .= ' '.$desc if defined $desc;
 109            $keytxt = qq{<a href="/$1">$keytxt</a>} if $flags =~ s/ ?\blink(\S*)//;
 110         my $onclick = $flags =~ s/ ?\bmode(\S*)// && defined $self->{def}{$1} && sprintf(
 111                 ' onclick="setmode(%s)"',
 112                 $1 eq '' ? '' : sprintf(q{'mode%s'}, escapeclass($1))
 113         );
 114         $flags .= ' chr'.ord(substr $key, -1) if $key ne '^0';
 115
 116         print qq{\t\t<li class="$flags"$onclick>$keytxt};
 117         print "\n";
 118 }
 119
 120 sub print_rows {
 121         my $self = shift;
 122         my %moderows = (
 123                 -DEFAULT => !@_ ? '' : split(/(?:\s*([^=\s]*)=\s*)/, shift),
 124                 # plus specific mode overrides prefixed by '='
 125         );
 126         my $defrows = shift || [2, 1, 0];
 127         my @modes = sort keys %{ $self->{def} };
 128
 129         print '<ul id="rows">'."\n\n";
 130
 131         for (my $row = -1; $row <= $#{ $keyrows{$self->{map}} }; $row++) {
 132                 my $keyrow = $row < 0 ? [["\e"]] : $keyrows{$self->{map}}->[$row];
 133
 134                 printf qq{<li class="row row%d"><ul>\n}, $row+1;
 135                 for my $basemode (@modes) {
 136                         my @moderows = split /\s+/,
 137                                 $row < 0 ? "0" :
 138                                 defined $moderows{$basemode} ? $moderows{$basemode} : $moderows{-DEFAULT};
 139
 140                 for my $submode (@moderows ? @moderows : '') {
 141                         my $mode = $basemode . $submode;
 142                         my @caserows = $mode =~ s/(\d+)(?:-(\d+))?$//
 143                                 ? (map {$_ - 1} split //, $row == 0 && $2 || $1)  # user override
 144                                 : @$defrows;  # default
 145                         my $modekeys = $self->{def}{$mode};
 146
 147                         for my $case (@caserows) {
 148                                 my $keycase = $keyrow->[$case] or next;
 149                                   @$keycase or next;
 150
 151                                 printf "\t<li%s>", $basemode ne '' && sprintf(
 152                                         ' class="%s"', 'mode mode' . escapeclass($basemode)
 153                                 );
 154                                 printf('<h3>%s<small>: %s</small></h3>', # XXX insert &nbsp; here to fix msie<=6
 155                                                 $self->{mode}->{$mode} || "mode $basemode",
 156                                                 "$rowdesc[$row] row $casedesc[$case]"
 157                                 ) unless $row < 0;
 158                                 print "\n";
 159                                 my $caseclass = 'keys';
 160                                    $caseclass .= ' lead' if defined $modekeys->{lead};  # leading command key shown
 161                                    $caseclass .= " $casedesc[$case]" if defined $casedesc[$case];
 162                                 print qq{\t\t<ul class="$caseclass">\n};
 163                                 $self->print_key($mode, $_, $modekeys->{$_}) for @$keycase;
 164                                 print qq{\t\t</ul>\n};
 165                         } # case
 166
 167                 } # submode
 168
 169                 } # basemode
 170                 print qq{\t</ul>\n};
 171         } # row
 172
 173         print "</ul>\n";
 174 }
 175
 176 sub print_legend {
 177         my $self = shift;
 178         my ($class, $flags) = @_;
 179
 180         print qq{\t\t<dl class="legend $class">\n};
 181         printf("\t\t".'<dt class="%s">%s'."\n\t\t\t".'<dd>%s'."\n",
 182                 $_, @{ $self->{flag}->{$_} || ["($_)", '...'] }
 183         ) for @$flags;
 184         print "\t\t</dl>";
 185 }
 186
 187 1;
 188
 189 =head1 NAME
 190
 191 Shiar_Sheet::Keyboard - Output HTML for key sheets
 192
 193 =head1 SYNOPSIS
 194
 195         our %sign = (alias => 'see: ');
 196
 197         my $keys = Shiar_Sheet::Keyboard({
 198                 def => {
 199                         'lead' => {
 200                                 'A' => 'a', # alias
 201                                 'a' => ['classes'],
 202                         },
 203                 },
 204                 key => {
 205                         'leada' => ['description', 'comments (on hover)'],
 206                 },
 207                 mode => {
 208                         'lead' => 'mode description',
 209                 },
 210         });
 211         $keys->map('dvorak') or die "Keyboard map not found";
 212
 213         $keys->print_rows;
 214
 215 =head1 DESCRIPTION
 216
 217 Used by http://sheet.shiar.nl to display keyboard sheets.
 218 Assumes specific stylesheets and javascript from this site,
 219 so probably not of much use elsewhere.
 220
 221 =head1 AUTHOR
 222
 223 Mischa POSLAWSKY <perl@shiar.nl>
 224
 225 =head1 LICENSE
 226
 227 Licensed under the GNU Affero General Public License version 3.
 228