#!/usr/bin/env perl
use 5.024;
use warnings;
use utf8;

use Data::Dump qw( pp );
use LWP::Authen::OAuth2;
use JSON qw( decode_json );
use List::MoreUtils qw( all part );

my ($profiles, $clanmatches) = part { /\D/ } @ARGV;  # separate numbers
@{$profiles}
	or die "Usage: $0 <profile id>... [<clan name>...]\n";
my ($clanmatch) = map { $_ && qr/\A(?:$_)\z/i } join '|', @{$clanmatches};

my %auth = do './.blizzard.passwd.pl' or die "no auth setup: $!\n";
my $bliz = LWP::Authen::OAuth2->new(%auth,
	token_endpoint          => 'https://eu.battle.net/oauth/token',
	request_required_params => [qw( client_id client_secret grant_type )],
);
$bliz->request_tokens(grant_type => 'client_credentials');

sub blizget {
	my $args = join('/', @_);
	my $res = $bliz->get("https://eu.api.blizzard.com/sc2/$args");
	$res->is_success or die $res->status_line;
	my $json = $res->decoded_content;
	return decode_json($json);
}

# prefer deprecated interface to prevent costly ladder search
my @ladderdata = map {
	blizget(legacy => profile => 2 => 1 => $_ => 'ladders')
} @{$profiles};
my %ladders = (
	map { $_->{ladder}->[0]->{ladderId} => $_ } # unique
	grep { $_->{ladder}->[0]->{division} }
	map { $_->{currentSeason}->@* } @ladderdata
);
my @ladders = (
	sort {
		$b->{ladder}->[0]->{wins}+$b->{ladder}->[0]->{losses} <=>
		$a->{ladder}->[0]->{wins}+$a->{ladder}->[0]->{losses}
	} # activity desc
	grep {
		!$clanmatch or
		all { $_->{clanName} =~ $clanmatch } $_->{characters}->@*
	} # members
	values %ladders
) or die "No matching groups found\n";

my (@members, %memberidx);
$memberidx{ $_->{id} } //= push(@members, $_) && $#members
	for map { $_->{characters}->@* } @ladders;

say JSON->new->canonical->pretty->encode({
	name     => $members[0]->{clanName},
	tag      => $members[0]->{clanTag},
	ladders  => [map {{
		league   => lc $_->{ladder}->[0]->{league},
		division => $_->{ladder}->[0]->{ladderName},
		rank     => $_->{ladder}->[0]->{rank},
		members  => [map { $memberidx{$_->{id}} } $_->{characters}->@*],
		wins     => $_->{ladder}->[0]->{wins},
		losses   => $_->{ladder}->[0]->{losses},
	}} @ladders],
	members  => [map {
		blizget(metadata => profile => 2 => 1 => $_->{id})
		# lacks mmr, fav race (available in new api)
	} @members],
}) =~ s/(?: \G \d,? | \[ ) \K \s+ (?=\d|\])/ /grx; # concat arrays of single digits