Shiar's Git - sc2-widget/blob - getsc2clan

   1 #!/usr/bin/env perl
   2 use 5.024;
   3 use warnings;
   4 use utf8;
   5
   6 use Data::Dump qw( pp );
   7 use LWP::Authen::OAuth2;
   8 use JSON qw( decode_json );
   9 use List::MoreUtils qw( all part sort_by nsort_by );
  10
  11 if (@ARGV and all { m[/] } @ARGV) {
  12         say pp blizget($_) for @ARGV;
  13         exit;
  14 }
  15
  16 my ($profiles, $clanmatches) = part { /\D/ } @ARGV;  # separate numbers
  17 $profiles && @{$profiles}
  18         or die "Usage: $0 <profile id>... [<clan name>...]\n";
  19 my ($clanmatch) = map { $_ && qr/\A(?:$_)\z/i } join '|', @{$clanmatches || []};
  20
  21 my @realmget = (profile => 2 => 1); # common request path for european data
  22 sub blizget {
  23         state $bliz = do {
  24                 my @authdata = do './.blizzard.passwd.pl' and not $@ || $!
  25                         or die "No auth setup: ", $@ || $!, "\n";
  26                 my %auth = @authdata;
  27                 my $bliz = LWP::Authen::OAuth2->new(%auth,
  28                         token_endpoint          => 'https://eu.battle.net/oauth/token',
  29                         request_required_params => [qw( client_id client_secret grant_type )],
  30                 );
  31                 $bliz->request_tokens(grant_type => 'client_credentials');
  32                 $bliz;
  33         };
  34
  35         my $args = join('/', @_);
  36         my $res = $bliz->get("https://eu.api.blizzard.com/sc2/$args");
  37         $res->is_success or die $res->status_line;
  38         my $json = $res->decoded_content;
  39         return decode_json($json);
  40 }
  41
  42 # prefer deprecated interface to prevent costly ladder search
  43 my @ladderdata = map {
  44         blizget(legacy => @realmget => $_ => 'ladders')
  45 } @{$profiles};
  46
  47 # merge relevant ladder data of all users
  48 my %ladders;
  49 for my $season (qw[ currentSeason previousSeason ]) {
  50         for my $row (map { $_->{$season}->@* } @ladderdata) {
  51                 $row->{ladder}->[0]->{division} or next;
  52                 $row->{season} = $season;
  53                 $ladders{ $row->{ladder}->[0]->{ladderId} } //= $row;
  54         }
  55 }
  56
  57 my @ladders = (
  58         nsort_by { $_->{ladder}->[0]->{ladderId} } # stable order
  59         grep {
  60                 !$clanmatch or
  61                 all { $_->{clanName} =~ $clanmatch } $_->{characters}->@*
  62         } # members
  63         values %ladders
  64 ) or die "No matching groups found\n";
  65
  66 my (@members, %memberidx);
  67 $memberidx{ $_->{id} } //= push(@members, $_) && $#members
  68         for map { $_->{characters}->@* } @ladders;
  69
  70 my @games;
  71 for my $member (map { $_->{id} } @members) {
  72         my $usergames = blizget(legacy => @realmget => $member => 'matches');
  73         for ($usergames->{matches}->@*) {
  74                 $_->{player} = $memberidx{$member};
  75                 push @games, $_;
  76         }
  77 }
  78
  79 say JSON->new->canonical->pretty->encode({
  80         name     => $members[0]->{clanName},
  81         tag      => $members[0]->{clanTag},
  82         ladders  => [
  83                 map {{
  84                         id       => $_->{ladder}->[0]->{ladderId},
  85                         league   => lc $_->{ladder}->[0]->{league},
  86                         division => $_->{ladder}->[0]->{ladderName},
  87                         rank     => $_->{ladder}->[0]->{rank},
  88                         members  => [map { $memberidx{$_->{id}} } $_->{characters}->@*],
  89                         wins     => $_->{ladder}->[0]->{wins},
  90                         losses   => $_->{ladder}->[0]->{losses},
  91                         (season  => -1) x ($_->{season} eq 'previousSeason'),
  92                 }}
  93                 sort_by { $_->{season} } # season
  94                 nsort_by {
  95                         -($_->{ladder}->[0]->{wins} + $_->{ladder}->[0]->{losses})
  96                 } # activity desc
  97                 @ladders
  98         ],
  99         members  => [map {
 100                 blizget(metadata => @realmget => $_->{id})
 101                 # lacks mmr, fav race (available in new api)
 102         } @members],
 103         matches  => [nsort_by { -$_->{date} } @games],
 104 }) =~ s/(?: \G \d,? | \[ ) \K \s+ (?=\d|\])/ /grx; # concat arrays of single digits