Shiar's Git - sc2-widget/blob - getsc2clan

   1 #!/usr/bin/env perl
   2 use 5.024;
   3 use warnings;
   4 use utf8;
   5
   6 use Data::Dump qw( pp );
   7 use LWP::Authen::OAuth2;
   8 use JSON qw( decode_json );
   9 use List::MoreUtils qw( all part nsort_by );
  10
  11 my ($profiles, $clanmatches) = part { /\D/ } @ARGV;  # separate numbers
  12 @{$profiles}
  13         or die "Usage: $0 <profile id>... [<clan name>...]\n";
  14 my ($clanmatch) = map { $_ && qr/\A(?:$_)\z/i } join '|', @{$clanmatches};
  15
  16 my %auth = do './.blizzard.passwd.pl' or die "no auth setup: $!\n";
  17 my $bliz = LWP::Authen::OAuth2->new(%auth,
  18         token_endpoint          => 'https://eu.battle.net/oauth/token',
  19         request_required_params => [qw( client_id client_secret grant_type )],
  20 );
  21 $bliz->request_tokens(grant_type => 'client_credentials');
  22
  23 sub blizget {
  24         my $args = join('/', @_);
  25         my $res = $bliz->get("https://eu.api.blizzard.com/sc2/$args");
  26         $res->is_success or die $res->status_line;
  27         my $json = $res->decoded_content;
  28         return decode_json($json);
  29 }
  30
  31 # prefer deprecated interface to prevent costly ladder search
  32 my @ladderdata = map {
  33         blizget(legacy => profile => 2 => 1 => $_ => 'ladders')
  34 } @{$profiles};
  35 my %ladders = (
  36         map { $_->{ladder}->[0]->{ladderId} => $_ } # unique
  37         grep { $_->{ladder}->[0]->{division} }
  38         map { $_->{currentSeason}->@* } @ladderdata
  39 );
  40 my @ladders = (
  41         nsort_by {
  42                 -($_->{ladder}->[0]->{wins} + $_->{ladder}->[0]->{losses})
  43         } # activity desc
  44         grep {
  45                 !$clanmatch or
  46                 all { $_->{clanName} =~ $clanmatch } $_->{characters}->@*
  47         } # members
  48         values %ladders
  49 ) or die "No matching groups found\n";
  50
  51 my (@members, %memberidx);
  52 $memberidx{ $_->{id} } //= push(@members, $_) && $#members
  53         for map { $_->{characters}->@* } @ladders;
  54
  55 say JSON->new->canonical->pretty->encode({
  56         name     => $members[0]->{clanName},
  57         tag      => $members[0]->{clanTag},
  58         ladders  => [map {{
  59                 league   => lc $_->{ladder}->[0]->{league},
  60                 division => $_->{ladder}->[0]->{ladderName},
  61                 rank     => $_->{ladder}->[0]->{rank},
  62                 members  => [map { $memberidx{$_->{id}} } $_->{characters}->@*],
  63                 wins     => $_->{ladder}->[0]->{wins},
  64                 losses   => $_->{ladder}->[0]->{losses},
  65         }} @ladders],
  66         members  => [map {
  67                 blizget(metadata => profile => 2 => 1 => $_->{id})
  68                 # lacks mmr, fav race (available in new api)
  69         } @members],
  70 }) =~ s/(?: \G \d,? | \[ ) \K \s+ (?=\d|\])/ /grx; # concat arrays of single digits