+#define cal call ;just to make it harder for you to understand
+#define psh push ; ^:D
+#define dnz djnz ;Dec&Jump while NonZero becomes Do w.Non-Zero
+
+#define teacherkey ;compiled with teacher key: 88 bytes extra
+
+dispbuffer = $8400 ;$C9FA ;virtual screen (MUST be mod$400=0!!)
+
+_clrWindow = $4a86 ;_clrLCD and _clrScrn
+_ex_ahl_bde = $45f3 ;exchange values between AHL and BDE
+_shracc = $4383 ;like _shlacc but just the opposite :P
+_dispahl = $4a33 ;display value in ahl <100000 (cheap TI)
+_asapvar = $d6fc ;our own variable name (likely "nemesis")
+
+storepos = _asm_exec_ram+7000 ;1024 bytes needed to store things
+
+;---------------------- in-game vars ----------------------------------------
+
+just_fired = storepos ; +0 ;counts how long a blast lasts
+hiscorepos = storepos ; +0 ;entering hiscore name
+
+x = storepos+1 ; +1 ;your ship's position
+y = x+1 ; +2 ;your y-pos
+firex = y+1 ; +3 ;(1 byte)
+firey = firex+1 ; +4 ;(1 byte)
+
+eventleft = firey+1 ; +5 ;nr. of enemies still to come
+level_enemy = eventleft+1 ; +6 ;enemy type
+level_info = level_enemy+1 ; +7 ;ceiling/ground (%00) present
+spacespace = level_info+1 ; +8
+groundinfo = spacespace+1 ; +9
+stars1 = groundinfo+1 ; +10 ;slow stars byte (<< %1)
+stars2 = stars1+1 ; +11 ;fast stars byte (<<< %1)
+groundpos = stars2+1 ; +12 $10
+ceilingpos = groundpos+16 ; +28 $10
+nrstars1 = 10
+starx1 = ceilingpos+16 ; +44 ;20
+nrstars2 = 10
+starx2 = starx1+(nrstars1*2) ; +64 ;20
+
+mm = 4 ;max. number of multiples
+your_prevpos = starx2+(nrstars2*2) ; +84 ;14*mm+2 ;previous positions
+
+
+enemies = storepos+200 ;+200 ;info about each enemy
+enemysize = 11 ;infobytes per enemy
+nrenemies = 16 ;max. nr of enemies
+
+ybullets = enemies+(nrenemies*enemysize) ;60 bytes = 20(state,damg,x,y)
+nrybuls = 128 ;+376\
+ebullets = ybullets+(nrybuls*4) ;+888 ;30 bytes = 10(state,x,y)
+nrebuls = 48
+lvlenemies = ebullets+(nrebuls*3) ;-1032
+
+;enemies:
+; [HP64] [000000:HP left 00:(00=no enemy 01=exploding 1X=normal)]
+; [ship sprite (DW!) or explosion frame] [x] [y] [movetype] [movecounter]
+; [firecounter] [firefreq] [firetype]
+
+;---------------------- introduction ----------------------------------------
+
+ nop ;hello yas/ase/rascall/whathever
+ jp init ;here's the program, but first: a description
+ .dw $0001 ;description type 2 (description + YASicon)
+ .dw Title ;pointer to description (all shells)
+ .dw Icon ;pointer to YAS icon
+
+Title: .db "Nemesis v0.99.99 by SHIAR",0
+
+Icon: .db 8,1 ;icon for YAS: width = 1byte; height = 7bytes
+ .db %11100000 ; ███
+ .db %01111000 ; ████
+ .db %00111110 ; █████
+ .db %01111001 ; ████ █
+ .db %00111110 ; █████
+ .db %01111000 ; ████
+ .db %11100000 ; ███ ;recommend 80x50 screen mode
+ .db 0 ;YAS 0.92 compatibility
+
+;---------------------- init ------------------------------------------------
+
+int_handler: ;new interrupt proc
+ ex af,af' ;just af only (no need for exx)
+ in a,($03) ;read bit 3 port 3
+ bit 3,a ;is ON key pressed?
+ jp z,$0039 ;no: np, return
+ res 0,a ;yes: then we have a problem (freeze), so...
+ out ($03),a ;...mask the ON key interrupts!
+ jp $0039 ;all done, return
+int_end:
+
+init: cal BUSY_OFF ;turns the run-indicator off, obviously
+ cal _clrScrn ;clean the screen
+ xor a ;ld a,0
+ res 2,(iy+13) ;don't scroll the screen
+ cal _flushallmenus ;remove TI menus
+
+FixKeys: ;fixes some key problems like left+down bug
+ im 1
+ ld a,$D4
+ ld bc,$0100
+ ld h,a
+ ld l,c ;ld hl,$D400 (user silent link routine space)
+ ld d,a
+ ld e,b ;ld de,$D401
+ dec a ;ld a,$D3
+ ld (hl),a
+ ldir ;fill $D400-D500 with $D3s (slink/user on)
+ ld hl,int_handler ;new interrupt handler
+ ld d,a
+ ld e,a ;ld de,$D3D3
+ ld bc,int_end-int_handler
+ ldir ;load new handler at ($D3D3)
+ inc a ;ld a,$D4
+ ld i,a
+ im 2
+
+;---------------------- main menu -------------------------------------------
+
+LogoPut:
+ xor a ;white bitmask (a=0)
+ ld hl,logo_nemesis ;from...
+ ld de,VIDEO_MEM+16 ;...to one line from top
+ ld b,e ;ld b,16: one line
+AboveLogo:
+ ld (de),a ;clear/n byte
+ inc de ;next
+ dnz AboveLogo ;repeat for the first line
+ ld bc,16*19 ;logo size
+ ldir ;display one line of logo
+
+ ld hl,16*$33+VIDEO_MEM ;$33 rows down
+ ld b,16*7 ;draw black 7 lines
+ ld a,%11111111 ;horizontal line mask
+underline:
+ ld (hl),a ;draw one piece of the divider-line
+ inc hl ;move right (8 pixels = 1 byte)
+ dnz underline ;repeat
+
+ ld hl,_txt_email ;at the very bottom of tha screen
+ ld (_penCol),hl
+ ld hl,txt_email ;hey, my e-mail address so SEND ME SOMETHING!!
+ cal _vputs ;VERY important, so display in small font ?:}
+
+ set 3,(iy+5) ;set white on black
+ ld de,_txt_about ;near the bottom of the screen
+ ld (_penCol),de ;hl=txt_email++=txt_about
+ cal _vputs ;display version + me
+ res 3,(iy+5) ;return to default black on white
+
+dispmenu:
+ ld de,$0304
+ ld (_curRow),de
+ ld hl,txt_menu1 ;NEW GAME
+ cal _puts
+ ld de,$0305
+ ld (_curRow),de
+ ld hl,txt_menu2 ;CONTINUE GAME
+ cal _puts
+
+menuloop:
+ ld a,0 ;current menu item (0 or 1); 0 by default
+menuitem =$-1
+ ld h,$01 ;selector (*) x-coord. = 1
+ add a,4
+ ld l,a ;y-coord. = sel menu item + 4 = 4/5
+ ld (_curRow),hl ;set position
+ ld a,5 ;'*'
+ cal _putmap ;mark selected menu item
+
+ ld a,l ;y-pos 4/5
+ xor 1 ;invert (4=5; 5=4)
+ ld (_curRow),a ;set new row position
+ ld a,32 ;' ' (empty, just remove any * present)
+ cal _putc
+
+ cal getsomekeys ;read keys (z if enter/2nd pressed)
+ ld hl,menuitem
+ jr z,start_tha_freakin_game
+ cp K_EXIT
+ jr z,menuexit ;exit goes to the g/o screen (first score=0)
+ cp K_UP
+ jr z,menuchange ;up changes selected menu item
+ cp K_DOWN ;down as well
+ jr nz,menuloop ;anything else just loops
+menuchange:
+ ld a,(hl) ;(menuitem)
+ xor 1 ;0=1; 1=0
+ ld (hl),a ;set new menu item
+ jr menuloop ;continue looping
+
+start_tha_freakin_game:
+ ld a,(hl) ;(menuitem)
+ dec a ;new game=0; so that gives -1 = NZ
+ cal nz,New_game ;NEW GAME
+ jp samelevel ;CONTINUE: game_main_loop
+
+menuexit:
+ ld hl,0 ;reset score
+ ld (your_score),hl ;(prevents hiscore while never played)
+ jp game_over ;and go to game over screen
+
+do_invert: ;invert screen (b<>w)
+ psh hl
+ psh af ;can't destroy b
+ ld hl,_invert
+ ld a,$98
+ xor (hl) ;$2F (cpl) <-> $B7 (or a)
+ ld (hl),a
+ pop af
+ pop hl
+ ret
+
+mode_invert:
+ ld hl,invertmode ;change invert mode (will be stored)
+ ld a,$98
+ xor (hl) ;$2F (cpl) <-> $B7 (or a)
+ ld (hl),a
+ ld de,1
+ psh de ;size
+ psh hl ;dest (invertmode)
+ ld hl,4+invertmode-_asm_exec_ram
+ psh hl ;src
+ jp storesmtn
+
+;----------------------------------------------------------------------------
+;---------------------- game loop -------------------------------------------
+;----------------------------------------------------------------------------
+
+game_main_loop: ;REPEATS FROM HERE EVERY FRAME
+ ld hl,timer ;update time
+ inc (hl) ;increase by 1
+
+Clear_screen:
+ ld hl,dispbuffer ;move from (hl) = top left
+ ld (hl),0 ;first pixel will be copied all over the screen
+ ld de,dispbuffer+1 ;(de) = next pixel, thus clearing whole screen
+ ld bc,16*56-1 ;loop 896 times = (128/8) * (64-8 for scorebar)
+ ldir ;all clear!
+
+ ld a,0 ;current frame/turn 0-255
+timer =$-1
+ and %11 ;a=0 once every 4 turns
+ jr z,movestarsdone ;don't move stars once every 4 frames
+ cal movestars1 ;move the stars on the FRONT layer
+ cal movestars2 ;move the distant stars
+movestarsdone:
+ ld a,(stars1) ;star positions (the missing byte...)
+ ld b,nrstars1 ;how many stars? now we know.
+ ld hl,starx1 ;points to the position of the stars
+ cal DisplayStars ;display front layer stars
+ ld a,(stars2) ;weren't you paying attention five lines ago?
+ ld b,nrstars2 ;that many?! whow!
+ ld hl,starx2 ;and there they are
+ cal DisplayStars ;use the same procedure to display back layer
+
+ ld a,(level_info) ;level info
+ rra ;ground present? (%1)
+ jr nc,game_stuff ;no, so both non-present
+ rra ;bit representing the presence of any ceiling
+ cal nz,Handle_ceiling ;scroll the ceiling (if any) +check4collision
+ cal Handle_ground ;scroll the ground and check if we're dead
+
+game_stuff:
+ cal Handle_Ship ;move you
+ ld a,(your_occ) ;are you 100% OK?
+ or a ;a=0??
+ jr nz,_gamestuff1 ;then don't check for movements/fires/...
+
+check_keys:
+ ld a,%10111111 ;function keys (MORE,EXIT,2ND,F1,F2,F3,F4,F5)
+ out (1),a ;ask for them
+ nop \ nop ;delay 8 clocks
+ in a,(1) ;gettem!
+
+check_exitkey:
+ bit 6,a ;test bit 6 = exit-key = EXIT
+ jp z,game_over ;<exit> pressed, so be it
+check_morekey: ;another unused label... poor compiler
+ bit 7,a ;test bit 7 = more-key = PAUSE
+ psh af
+ cal z,Pause ;yes, go to pause
+ pop af
+
+check_firekey:
+ bit 5,a ;test bit 5 = 2nd-key = FIRE
+ ld hl,check_selkey ;where to continue after executing Fire_bullet
+ psh hl ;push hl on stack (instead of cal Fire_bullet)
+ jp z,Fire_bullet ;fire smtn (bulletstaillasermultiples+stuff..)
+ pop hl ;no cal to Fire_bullet made, so pop stack
+ ld hl,just_fired ;no:
+ ld (hl),5 ;able to fire (five turns = laser duration)
+laserdur =$-1 ;SMC laser duration
+
+check_selkey:
+ ld a,%01011111 ;look at first column of keys (ALPHA to STO)
+ out (1),a
+ in a,(1) ;our precious keys
+
+#ifdef teacherkey ;should we check for the teacherkey?
+ bit 6,a ;'bout the GRAPH key...
+ cal z,Teacher ;you didn't _press_ it, did you?!?
+#endif
+
+ rla ;test bit7 so we know f ALPHA has been pressed
+ cal nc,select ;yeppy, select the currently selected upgrade
+
+ cal Enemies_hit ;check for collision with enemies
+ cal inc_weapdamage
+
+_gamestuff1:
+ cal Handle_enemies ;move enemies
+
+ cal Handle_bullets ;move your bullets + check for hits
+ cal Enemy_bullets ;move enemy bullets
+
+ cal Level_event ;insert enemies
+ cal Display_Screen ;display all
+
+delay:
+ halt ;delay and preserve batteries :)
+ jp game_main_loop ;LOOP ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
+
+;------- weapon -------
+
+inc_weapdamage:
+ ld a,0
+weapincs =$-1
+ inc a
+ cp 97 ;max. 96 times (=96/16=6 increases)
+ ret nc ;return if already maxed
+ ld (weapincs),a ;save new incs
+
+ and %11110000 ;clear last 4 bits so no cf when rotating
+ ;btw: AND resets cf
+ rra ;rotate acting as shift (srl a) but just 1B
+ rra
+ rra
+ rra ;increase once just every 16 turns
+ ld b,a ;times to increase
+incthedamage:
+ add a,1 ;increase damage for one increase
+weapdaminc =$-1
+ dnz incthedamage ;a=total increase damage
+ ld b,1 ;minimal damage
+weapdamage =$-1
+ add a,b ;a=total damage
+ ld (curweapdamage),a ;safe the current damage
+
+
+disp_charge: ;display charge bar
+ ld hl,(58*16)+VIDEO_MEM+3
+ ld b,3
+chargebarclr:
+ dec hl
+ ld (hl),0
+ dnz chargebarclr
+
+ ld a,(weapincs) ;load bar size (0-80)
+ srl a ;half the size (0-40)
+ srl a ;again half that size (0-20 pixels)
+ ld c,a ;psh a
+ srl a ;/2
+ srl a ;/4
+ srl a ;/8: don't display last 3 bits of a (later)
+ jr z,nochargebar ;if a=0 then it would loop 256x so skip it
+ ld b,a ;loop b=a times
+chargebar: ;starting at ($39*16)+VIDEO_MEM
+ ld (hl),%11111111 ;draw a piece of the bar
+ inc hl ;next position
+ dnz chargebar ;loop it b times
+nochargebar:
+ ld a,c ;pop a
+ and %111 ;display last bits of chargebar
+ ret z ;if armor=0 then bit = %00000000 (don't disp)
+ ld b,a ;into B
+ xor a ;bit = %00000000
+chargebarbit:
+ scf ;set carry flag
+ rra ;rotates A right and sets bit 7 (c-flag)
+ dnz chargebarbit ;repeat B times (so if B=6 then a=%11111100)
+chargebarready: ; (an if B=3 then a=%11100000)
+ ld (hl),a ;draw this last byte
+ ret
+
+;--------------------------- ground -----------------------------------------
+
+Handle_ground:
+ ld a,(timer)
+ and %111 ;once every 8 frames
+ jr nz,Display_ground ;otherwise skip the scroll
+ ld bc,15 ;scroll all 16 bytes minus one (teh new byte)
+ ld hl,groundpos+1 ;from..
+ ld de,groundpos ;to (one byte to the left)
+ ldir ;LoaDIncreaseRepeat = scroll!
+
+ ld a,(groundpos+14) ;last ground on right
+ ld d,a ;as default ground
+ ld hl,spacespace
+ ld bc,$500 ;range=0..4
+ cal Random ;a=0..4
+ dec a ;a=-1..3
+ dec a ;a=-2..2
+ ld b,a
+ add a,(hl) ;substract to spacesize
+ cp 57
+ jr nc,newground ;if nothing left then don't change
+ ld c,a
+ add a,b ;add offset (2 higher/lower) => new position
+ or a ;=0?
+ jr z,newground ;may not be 0 (=256)
+ cp -10 ;>246?
+ jr nc,newground ;and not be <0
+ ld d,a
+ ld (hl),c
+newground:
+ ld a,d
+ ld (groundpos+15),a ;save new byte on the right
+
+Display_ground:
+ ld b,16 ;screen width
+ ld de,groundpos-1 ;height of current byte (previous actually)
+ psh de ;use later
+ ld hl,dispbuffer+(56*16)-1 ;screen position
+ psh hl
+
+groundloopright:
+ ld c,b ;push b for groundloopup
+ pop hl \ inc hl ;get screen position and go one right
+ pop de \ inc de ;get height info and set to the next byte
+ psh de \ psh hl ;save these for the next time
+ ld a,(de) ;height of current byte
+ ld b,a ;save in b
+
+ ld de,-16 ;to substract to go one line up
+ ld a,%11111111 ;bitmask black
+groundloopup:
+ ld (hl),a ;display black byte
+ add hl,de ;go up (sbc must be used for 16-bit sub)
+ dnz groundloopup ;and loop >groundpos< times
+
+ ld b,c ;pop b used by groundloopup
+ dnz groundloopright ;loop right for entire screen (16x)
+ pop hl \ pop hl ;restore stack
+
+CheckGround: ;check for collision with the ground
+ ld a,(x)
+ srl a
+ srl a
+ srl a
+ inc a
+ ld l,a
+ ld h,0
+ ld de,groundpos
+ add hl,de
+ ld a,(y)
+ sub 57-7
+ neg
+ cp (hl)
+ ret nc
+ ld b,auch_ground
+ jp damage_you
+
+;--------------------------- ceiling ----------------------------------------
+
+Handle_ceiling:
+ ld a,(timer)
+ and %111 ;once every 8 frames
+ jr nz,Display_ceiling ;otherwise skip the scroll
+ ld bc,15 ;scroll all 15 bytes (16th is new position)
+ ld hl,ceilingpos+1 ;from..
+ ld de,ceilingpos ;to (one byte to the left)
+ ldir ;LoaDIncreaseRepeat = scroll!
+
+ ld a,(ceilingpos+14)
+ ld d,a ;d=new ceiling
+ ld hl,spacespace
+
+ ld bc,$201 ;range=1..3
+ cal Random ;a=1-3
+ dec a
+ jr z,newceiling ;1:same
+ dec a
+ jr z,ctunnelup ;2:up
+ctunneldown: ;3:down
+ ld a,(hl)
+ or a ;(spacespace)=0:
+ jr z,newceiling+2 ;keep same ceiling
+ inc (hl)
+ inc d
+ jr newceiling
+ctunnelup:
+ ld a,1
+ cp d ;if size=1 then don't
+ jr z,newceiling
+ dec d
+ dec (hl)
+newceiling:
+ ld a,d
+ ld (ceilingpos+15),a ;save the new byte
+
+Display_ceiling:
+ ld b,16 ;screen width
+ ld de,ceilingpos-1 ;height of current byte
+ psh de ;use later
+ ld hl,dispbuffer-17 ;screen position
+ psh hl
+
+ceilingloopright:
+ ld c,b ;push b for ceilingloopdown
+ pop hl \ inc hl ;get screen position and go one right
+ pop de \ inc de ;get height info and set to the next byte
+ psh de \ psh hl ;save these for the next time
+ ld a,(de) ;height of current byte
+ ld b,a ;save in b
+
+ ld de,16 ;to substract to go one line up
+ ld a,%11111111 ;bitmask black
+ or a
+ceilingloopdown:
+ ld (hl),a ;display black byte
+ add hl,de ;go down
+ dnz ceilingloopdown ;and loop >ceilingpos< times
+
+ ld b,c ;pop b used by ceilingloopdown
+ dnz ceilingloopright ;loop right for entire screen (16x)
+ pop hl \ pop hl ;restore stack
+
+CheckCeiling: ;check for collision with the ceiling
+ ld a,(x) ;your x
+ srl a ;x/2
+ srl a ;x/4
+ srl a ;x/8 (current ceiling-byte)
+ inc a ;correction
+
+ ld l,a ;hl = a
+ ld h,0 ;"
+ ld de,ceilingpos ;first ceiling-byte
+ add hl,de ;current ceiling-byte
+ ld a,(y) ;your y-pos
+ inc a
+ cp (hl) ;compare with ceiling
+ ret nc ;carry if ceiling is above you
+ ld b,auch_ground
+ jp damage_you ;otherwise you don't wanna be in that ship
+
+;--------------------------- move stars -------------------------------------
+
+DisplayStars: ;inputs: hl=starx# a=stars# b=nrstars#
+ ld e,(hl)
+ inc hl
+ ld d,(hl)
+ ld (de),a
+ inc hl
+ dnz DisplayStars
+ ret ;let's comment this: returns
+
+movestars2:
+ ld ix,starx2
+ ld a,(stars2)
+ rlca ;move bits (star) left
+ ld (stars2),a
+ ret nc ;if star didn't went from left to right bit
+ ld b,nrstars2 ;otherwise move all stars one byte left
+ jr movestars_loop
+
+movestars1:
+ ld ix,starx1
+ ld a,(timer)
+ rra
+ ld a,(stars1)
+ ret c
+ rlca
+ ld (stars1),a
+ ret nc
+ ld b,nrstars1
+
+movestars_loop:
+ ld h,(ix+1)
+ ld l,(ix)
+ dec hl
+
+ ld a,l
+ and %00001111
+ cp (dispbuffer&15)-1 ;$C9FAand15-- = 9
+ jr nz,newstarok
+ cal RandomY
+
+newstarok:
+ ld (ix),l
+ ld (ix+1),h
+ inc ix \ inc ix
+ dnz movestars_loop
+ ret ;for stupid people, here's another comment...
+
+;--------------------------- pause ------------------------------------------
+
+Pause:
+ ld hl,_txt_pause
+ ld (_penCol),hl
+ ld hl,txt_pause
+ cal _vputs ;display small font
+ ld hl,_txt_pressenter ;top centered
+ ld (_curRow),hl
+ ld hl,txt_pressenter ;"Enter to continue"
+ cal _puts ;display message
+pause:
+ cal getsomekeys ;GET_KEY w/ halts and checks for enter
+ ret z ;enter/second pressed: continue game
+ cp K_F1 ;F1 pressed?
+ jr nz,notinvert
+ cal do_invert ;if so then change invert screen (AF saved)
+ cal mode_invert ;and screen mode (will be saved)
+notinvert:
+ ld hl,CONTRAST ;contrast setting (0-31)
+ ld b,(hl) ;load contrast into b
+ cp K_UP ;+ key changes contrast up
+ jr nz,contr_not_up
+ inc b ;increase contrast
+ jr setcontrast ;set
+contr_not_up:
+ cp K_DOWN ;- key
+ jr nz,pause ;nope: loop
+ dec b ;decrease contrast
+setcontrast:
+ ld a,b
+ ld (hl),a
+ out (2),a ;and set it
+ cal releasekeys
+ jr pause ;and loop
+
+;--------------------------- teacher ----------------------------------------
+
+#ifdef teacherkey ;can be disabled to save space if not needed
+ ;DO NOT RELEASE NEMESIS COMPILED W/O TEACHERKEY!!!!!
+Teacher:
+ ld (iy+12),5 ;enable flashing cursor
+ cal _clrWindow ;top left
+ ld hl,txt_teacher
+ cal _puts ;display message
+ cal releasekeys
+
+teacherloop:
+ cal _getkey ;enter low-power mode and wait for key
+ cp kEnter ;enter pressed?
+ jr z,teacherans
+ cp kGrMenu ;keypressed = graph?
+ jr nz,teacherloop ;no, wait some more
+
+ ld (iy+12),0 ;disable cursor
+ cal releasekeys
+ jp disp_icons ;+ret
+
+teacherans: ;enter displays the answer
+ ld a,' ' ;the cursor could still be displayed (█)
+ cal _putc ;so remove it by displaying a ' ' over it
+
+ ld hl,$0701
+ ld (_curRow),hl ;below the equation, aligned right
+ ld hl,txt_teacherans ;the answer text
+ cal _puts ;display
+ jr teacherloop ;and continue loop
+#endif
+
+;--------------------------- exit -------------------------------------------
+
+quit: im 1 ;release keyfix procedure
+ set 2,(iy+13) ;set back screen scrolling
+ xor a
+ ld (_asapvar+1),a ;next Asm( run will reload the program
+ ld hl,dispbuffer ;graph-screen location
+ ld de,dispbuffer+1
+ ld (hl),a
+ ld bc,1024-1 ;do it 1024 times = entire screen
+ ldir
+ jp _clrWindow ;as _clrLCD but also clears TEXT_MEM (like the
+ ;_clrScrn) AND also executes _homeup and ret
+
+;--------------------------- display ----------------------------------------
+
+Display_Screen:
+ ld hl,dispbuffer ;from buffer (top left)
+ ld de,VIDEO_MEM ;to real screen (top left)
+ ld c,56 ;display height = 64 bytes (minus 8 for bar)
+displayloop:
+ ld b,16 ;display width = 16 bytes (16*8bits=256pixels)
+displaytloop:
+ ld a,(hl) ;copy byte from (hl)
+_invert: ;SMC: cpl <-> or a
+ cpl ;xor $ff: invert byte (white<=>black)
+ ld (de),a ;to (de)
+ inc hl \ inc de ;next byte
+ dnz displaytloop ;16x hl >> de
+ dec c ;next line
+ jr nz,displayloop ;loop 56x
+
+ ld hl,time2invert
+ ld a,(hl)
+ or a ;(time2invert)=0:
+ jr z,noinvert ; do nothing
+ dec a ;otherwise decrease
+ cal z,do_invert ;if it became 0 then invert
+ ld (hl),a ;save new value
+noinvert:
+
+ ld hl,$396b ;Display Score
+ ld (_penCol),hl ;bottom right of screen
+ ld hl,(your_score)
+
+_D_HL_DECI: ;------- display 5-digit value -------
+ ld de,savestr+4 ;savenr saves number string
+ ld b,5 ;five digits
+ldhld: cal UNPACK_HL ;one digit of hl
+ add a,'0' ;make number
+ ld (de),a ;save into savenr
+ dec de ;point to next digit
+ dnz ldhld ;repeat for all digits
+
+ ld hl,savestr ;we (the program) saved the value righthere
+ jp _vputs ;the only thing left to do is to display it
+
+savestr: ;@here the score will be stored
+ .db "00000",0 ;don't worry, it's just temporary
+
+;------------------------- handle ship --------------------------------------
+
+Handle_Ship:
+ ld a,(your_occ) ;are
+ or a ;you
+ jr z,ok ;ok?
+
+ inc a ;no! next (explosion)frame
+ ld (your_occ),a ;save
+
+ cp 64+1 ;last explosion frame? (1-16=1st;49-64=4th)
+ jp c,exploding_you ;not yet: display explosion
+ cp 64+16 ;delay finished?
+ jp z,You_die ;yes = game over
+ ret ;don't display anything
+
+;----move----
+ok: ;we are
+ ld a,%01111110 ;get arrow keys
+ out (1),a ;it's cold outside
+ ld hl,y ;instead of nop\nop do something usefull
+ in a,(1) ;come back in
+
+ ld b,a ;psh a (keys)
+ xor -1 ;inverted a: 0 if arrow-key has been pressed
+ ld a,(your_multiples) ;(btw: CPL doesn't set any flags)
+ res 7,a ;reset move bit (no flags changed)
+ jr z,adv_ok ;if so, leave the multiples where they are
+ set 7,a ;set move bit
+adv_ok: ld (your_multiples),a
+
+ ld a,(timer) ;framecounter
+ and %1 ;switches 0<>1 each frame
+ inc a ;a = 1 or 2 (1.5 avg)
+ ld c,a ;c = your_speed
+
+ ld a,b ;pop a (keys)
+ rra ;rotate right (put last bit in c)
+ ld b,a ;we need a later
+
+ jr c,no_down
+ ld a,(hl)
+ add a,c
+ cp 50 ;56-6 = bottom of screen
+ jr nc,no_down
+ ld (hl),a
+no_down:
+ dec hl
+ rr b ;because we now use b, it's rr instead of rra
+ jr c,no_left
+ ld a,(hl)
+ sub c ;<dec a> doesn't affect c-flag
+ jr c,no_left ;-1 = left side
+ ld (hl),a
+no_left:
+ rr b
+ jr c,no_right
+ ld a,(hl)
+ add a,c
+ cp 122 ;128-6 = right side
+ jr nc,no_right
+ ld (hl),a
+no_right:
+ ld d,(hl) ;d=x
+ inc hl
+ rr b
+ jr c,no_up
+ ld a,(hl)
+ sub c ;<dec a> doesn't affect carry-flag
+ jr c,no_up ;-1 = top of screen
+ ld (hl),a ;save new y
+
+no_up: ld e,(hl) ;e=y
+ ld ix,spr_ship01 ;normal ship sprite
+your_shipspr =$-2
+ ld hl,your_shield ;shielded?
+ ld a,(hl) ;load time in a
+ or a ;is it 0?
+ jr z,disp_ship ;yes so ship = normal (display \ continue)
+
+ ld a,(timer) ;load frame nr.
+ and %00000111 ;a=0 once every four frames
+ jr nz,not_time ;a<>0 = not time to update counter
+ dec (hl) ;decrease inv-time left
+not_time:
+ and %00000100 ;a switches 0<->1 every 2 frames
+ jr z,disp_ship ;show normal ship
+inv_flicker:
+ ld bc,spr_ship01i-spr_ship01
+ add ix,bc ;display invulnerable ship
+disp_ship:
+ cal safeputsprite ;display your ship; save de
+
+;----multiples----
+
+handle_multiples:
+ ld a,(your_multiples) ;do you have multiples
+ ld b,a ;save a for 2nd check
+ and %1111 ;no? (last four bits = nr of multiples)
+ ret z ;then don't handle them either
+ bit 7,b ;move the multiples??? (=move bit set?)
+ jr z,mult_adv ;nope, just let them (saves (y)in y, (x)in x)
+
+ psh de ;current position = needed later
+ ld hl,mm*14+1+your_prevpos ;previous positions
+ ld de,mm*14+3+your_prevpos ;move all positions one back
+ ld bc,mm*14+2
+ lddr ;change 0-57 -> 2-59 (if mm=4 that is)
+ inc hl ;your_prevpos+0
+ pop de
+ ld (hl),d ;x-pos
+ inc hl ;=current position
+ ld (hl),e ;y-pos
+
+mult_adv:
+ ld ix,spr_multiple ;normal sprite
+ ld hl,timer
+ bit 3,(hl) ;change sprites every 8 turns
+ jr z,disp_multiples
+ ld ix,spr_multiple2 ;second sprite
+disp_multiples:
+ ld hl,your_prevpos+16 ;first pos.
+dispmultiplesloop:
+ psh af
+ psh hl
+ ld d,(hl) ;load coords
+ inc hl
+ ld e,(hl)
+ psh ix
+ cal putsprite ;display
+ pop ix ;same sprite next time ;)
+ pop hl
+ ld de,14
+ add hl,de ;next multiple
+ pop af ;counter
+ dec a
+ ret z ;return if all done
+ jr dispmultiplesloop ;loop
+
+;----explode----
+
+exploding_you:
+ srl a ;half the framerate
+ srl a ;half that framerate
+ srl a ;and half again that framerate
+ ld hl,x-1
+ ld ix,spr_yexplosion ;base sprite
+
+explosion_stuff: ;in:a=frame*2+(0 to 1); (hl)=xpos-- ix=sprite
+ and %11111110
+ add a,a
+ add a,a ;frame*8
+ ld c,a
+ ld b,0 ;bc=a
+ add ix,bc ;go to correct sprite (each spr. is 8 bytes)
+ inc hl ;@x
+ ld d,(hl) ;load xpos
+ inc hl ;@y
+ ld e,(hl) ;and y
+ jp putsprite ;and display it too
+
+;----hit----
+
+damage_you: ;damages you B points
+ ld a,(your_occ) ;return if already dead (prevents exploding
+ or a ; twice, or stucking in exploding state)
+ ret nz ;0 = you're normal
+
+ ld a,(hardcore) ;hardcore mode?
+ or a
+ jr z,damageok ;0 = no = don't modify
+; sla b ;1 = yes = double tha damage (b shifted left)
+ .db $CB,$30 ;sll b ;damage=2b|1 (CB3r = unsupported SLL r)
+damageok:
+ ld a,(your_shield) ;shield left?
+ or a
+ jr z,dothadamage ;no shield
+ srl b ;shield: half the damage
+dothadamage:
+ ld hl,time2invert
+ xor a ;a=0
+ cp (hl) ;not already inverted?
+ cal z,do_invert ;then invert screen
+ ld (hl),2 ;change back 2 frames from now
+
+ ld hl,your_armor ;armor left
+ ld a,(hl) ;load hp in A
+ sub b ;decrease hp by B
+ jr nc,newarmor ;>=0hp left so don't explode
+ ld a,%01 ;occ %xxxxxx01 = explode
+ ld (your_occ),a ;too bad, you're dead meat
+newarmor:
+ ld (hl),a ;save decreased hp
+ jp disp_armor ;and display new value
+
+;------------------------- place multiples ----------------------------------
+
+Place_multiples:
+ ld hl,your_prevpos ;place all previous positions
+ ld b,mm*7+2 ;all saved positions of them (14 per multiple)
+place_multiples:
+ ld (hl),e ;set prev-x to d
+ inc hl ;next
+ ld (hl),d ;set prev-y to e
+ inc hl ;next
+ dnz place_multiples ;repeat
+ ret
+
+;------------------------- select upgrade -----------------------------------
+
+inc_armor:
+ ld a,(your_armor) ;load current armor
+ cp maxarmor-5 ;may not become >=maxarmor
+ jr c,doincarmor ;ok then just add 6
+ ld a,maxarmor-6 ;set to maximum (6 will be added below)
+doincarmor:
+ add a,6 ;add 6 to armor
+ ld (your_armor),a ;change armor
+ ret
+
+select:
+ ld de,your_weapon ;current weapon, required for most selections
+ ld hl,your_pickup ;select pickups
+ ld a,(hl) ;load pickups taken so far
+ dec a ;is it 1?
+ ret m ;return if it's 0 (no pickups)
+
+ jr nz,selectlaser ;no, carry on
+ ld (hl),a ;reset pickups
+ ld a,(de) ;(your_weapon)
+ inc a ;next
+ cp maxweapon
+ jr c,selectedbeam ;weapon OK
+ jr z,disp_icons ;weapon maxed out
+ xor a ;laser was selected: set to first weapon
+selectedbeam:
+ ld (de),a ;set new weapon
+ cal loadweapon ;load it (damage and stuff)
+ xor a
+ ld (your_multiples),a ;no multiples with beam
+ jr disp_icons ;display n return
+selectlaser:
+ dec a ;is it 2?
+ ld (hl),0 ;reset pickups
+ jr nz,selectextra ;no, carry on again
+ ld (your_extra),a ;no extra beams (tailbeam/up-double)
+ ld a,(de) ;(your_weapon)
+ cp maxweapon ;upgrade from bullet?
+ jr nc,upgradelaser ;nope, just upgrade
+ ld a,maxweapon-1 ;yes, set laser #1
+upgradelaser:
+ inc a ;next laser
+ cp maxlaser
+ jr nc,disp_icons ;laser maxed out
+ ld (de),a
+ cal loadweapon
+ jr disp_icons ;display + return
+selectextra:
+ ld a,(de) ;(your_weapon)
+ cp maxweapon+1 ;laser or beams?
+ jr c,selectXbeam ;if beamweap then no multiples but extra beam
+ ld hl,your_multiples
+ ld a,(hl) ;multiples you already got
+ and %1111 ;reset movebit so (your_multiples)=real value
+ inc a ;one more
+ cp mm+1
+ jr nc,enoughmultiples ;maxed out
+ ld (hl),a
+enoughmultiples:
+ ld de,(x)
+ dec a ;if this is your first multiple then...
+ cal z,Place_multiples ;reset multiples positions
+ jr disp_icons ;display, return
+selectXbeam:
+ ld a,(your_extramode) ;indicates whether this is tailbeam/double
+ ld (your_extra),a ;ready extra beam
+; jr disp_icons ;display 'n return
+
+;--------------------------- show icon --------------------------------------
+
+disp_icons: ;destroyes: abcdehlix
+ ld a,VIDEO_MEM/$400 ;directly on screen
+ ld (PutWhere),a ;place icons at normal screen
+ ld hl,VIDEO_MEM+(16*56);56 rows down = eight rows from bottom
+ ld b,16 ;draw 16x (screen width)
+ ld a,%11111111 ;horizontal line mask
+ cal drawline ;draw divider-line
+
+ ld b,16*7 ;draw 16x (screen width) 7x (height)
+ xor a ;blank line mask
+ cal drawline ;clear scorebar
+
+disp_lives:
+ ld de,$003C ;(0,4)
+ ld a,(your_lives) ;nr of lives
+ or a
+ jr z,displivesdone ;no lives
+ ld b,a
+displivesloop:
+ psh bc
+ ld ix,spr_lship
+ cal safeputsprite ;put li'l ship
+ ld a,lshipsize+1
+ add a,d
+ ld d,a ;x=x+5
+ pop bc
+ dnz displivesloop ;one ship per life
+displivesdone:
+ cal disp_armor ;display bar
+
+ ld ix,spr_icon00
+ ld a,(your_weapon) ;ur weapon
+ cp maxweapon ;laser?
+ psh af ;a=(your_weapon); cf=bullets
+ jr nc,no_bullets ;=laser
+ ld hl,$3945 ;position to display bullet-type digit
+ pop af ;digit=(your_weapon)
+ psh af
+ inc a ;1 = weapon #1 (=0)
+ ld (_penCol),hl ;set location
+ add a,'0' ;make digit
+ cal _vputmap ;display char
+ ld ix,spr_icon03 ;bulletIcon
+no_bullets:
+ ld de,$3939 ;icon #1
+ cal putwidesprite ;display icon (beamweap)
+
+ ld ix,spr_icon00 ;emptyIcon
+ pop af ;ld a,(your_weapon)
+ ld b,a
+ jr c,no_laser ;popped carry
+ ld hl,$3955 ;position to display bullet-type digit
+ ld (_penCol),hl ;set location
+ ld a,b ;(your_weapon) ;load = faster than push
+ sub maxweapon-1 ;1 = laser #1 (=maxweapon)
+ add a,'0' ;make digit
+ cal _vputmap ;display char
+ ld ix,spr_icon04 ;laserIcon
+no_laser:
+ ld de,$4939 ;icon #2
+ cal putwidesprite ;(laser)
+
+ ld ix,spr_icon00 ;emptyIcon
+ ld a,(your_multiples) ;number of multiples
+ and %111 ;<8
+ jr z,no_multiples ;none, check for beam extras
+ ld ix,spr_icon05 ;multiples-icon
+ jr no_tail ;display
+no_multiples: ;no multiples
+ ld a,(your_extra) ;extra weapon
+ or a ;0?
+ jr z,no_tail ;nothing
+ ld ix,spr_icon02a ;tailbeamIcon
+ dec a
+ jr z,no_tail ;(your_extra)=1 = tailbeam
+ ld ix,spr_icon02b ;updoubleIcon
+no_tail: ;display
+ ld de,$5939 ;icon #3
+ cal putwidesprite
+
+ ld ix,spr_dividerline
+ ld de,$6939
+ cal putwidesprite
+
+ ld a,(your_pickup) ;pickups taken
+ add a,a ;picks*2 (sets z-flag)
+ jr z,iconsdone ;return if no pickups
+ add a,a ;picks*4
+ add a,a ;picks*8
+ add a,a ;picks*$10
+ add a,$29 ;add 29h
+ ld d,a ;y-pos = picks * $10 + $29 (3a,4a,5a)
+ ld e,$39 ;x-pos = bottom (3a39,4a39,5a39)
+
+ ld ix,spr_icon
+ cal putwidesprite
+iconsdone:
+ ld a,dispbuffer/$400 ;normal game-screen
+ ld (PutWhere),a ;set sprite-position to normal screen
+ jp disp_charge ;display weapon charge bar
+
+
+disp_armor:
+ ld de,16 ;line size
+ ld hl,(58*16)+VIDEO_MEM+6
+ ld c,5 ;5 lines down
+armorbarclrY:
+ ld b,4 ;four bytes right
+ psh hl
+armorbarclrX:
+ ld (hl),0 ;clear
+ dec hl ;next byte
+ dnz armorbarclrX ;4x
+ pop hl ;old position
+ add hl,de ;one pixel down
+ dec c ;5x
+ jr nz,armorbarclrY ;loop
+
+ ld hl,VIDEO_MEM+(58*16)+6
+ ld a,(your_armor) ;load your armor (<maxarmor)
+ srl a ;divide by 2 (barsize halved)
+ psh af
+ and %111 ;display last bits of armor
+ jr z,armorbarbitok ;if b=0 then prevent looping 256x
+ ld b,a ;into B
+ xor a ;bit = %00000000
+armorbarbit:
+ scf ;set carry flag
+ rla ;rotates A left and sets bit 0 (c-flag)
+ dnz armorbarbit ;repeat B times (so if B=6 then a=%00111111)
+armorbarbitok: ; (an if B=3 then a=%00000111)
+ ld c,a ;save last bit in c
+ pop af ;now we'll make the byte
+ and %11111000 ;clear last three bits
+ rra ;so we can use rotate instead of shift right
+ rra ;which saves 3(-2) bytes and speed
+ rra ;/8: don't display last 3 bits of a (later)
+
+ ld b,5 ;bar height
+armorbarloop1:
+ psh bc ;yloop counter
+ psh hl ;begin x-position
+ ld b,a ;loop b=a times per line
+ or a ;<1 bytes
+ jr z,lastarmorbit ;then don't display bytes (would be 256x)
+armorbarbyte:
+ ld (hl),%11111111 ;draw a piece of the bar
+ dec hl ;next position
+ dnz armorbarbyte ;loop it b times
+lastarmorbit:
+ ld (hl),c ;draw the last byte
+ pop hl ;recall first byte
+ add hl,de ;one down
+ pop bc ;recall yloop-counter
+ dnz armorbarloop1 ;display again
+ ret
+
+
+drawline:
+ ld (hl),a ;draw one piece of the divider-line
+ inc hl ;move right (8 pixels = 1 byte)
+ dnz drawline ;repeat (16bytes * 8pixels =128= screen width)
+ ret
+
+;------------------------- fire bullet --------------------------------------
+
+fire_multiple:
+ psh af
+ psh ix ;save ix for next fire
+ cal fireany ;fire from multiple position
+ pop ix ;saving ix is much faster than recalculating
+ pop af ;number of multiples
+ dec a ;one just displayed
+ pop hl ;ret
+ ret z ;ret2 if none left
+ jp (hl) ;real ret
+
+fire_multiples:
+ ld hl,(your_prevpos+16);then, fire from multiple position
+ cal fire_multiple
+ ld hl,(your_prevpos+30)
+ cal fire_multiple
+ ld hl,(your_prevpos+44)
+ cal fire_multiple
+ ld hl,(your_prevpos+58)
+ cal fire_multiple ;no JP: that messes up the stack
+ ret
+
+Fire_bullet:
+ ld hl,just_fired ;=for how long you may hold fire (2nd)
+ ld a,(hl) ;a = time left
+ dec a ;decrease timer
+ ret z ;may not fire when (just_fired) became 0
+ ld (hl),a ;save new decreased value
+
+ ld a,(your_weapon) ;if you have bullets.....
+ cp maxweapon
+ jr nc,fireOK ;>weapons = laser
+ ld (hl),1 ;bullet may last one turn (just fire 1 bullet)
+fireOK:
+ ld a,(your_weapon) ;weapon nr.
+ ld ix,weapondata+2
+ add a,a ;weap*2
+ add a,a ; *4
+ add a,a ; *8
+ ld c,a
+ ld b,0 ;go to current weapon (bc=a)
+ add ix,bc ;ix=weapon ptr
+
+ ld a,(your_multiples) ;any multiples?
+ and %1111 ;nr. of multiples
+ cal nz,fire_multiples ;if >0 then fire them too
+ ld hl,(x) ;fire from ship position (x)
+fireany: ;HL=(x,y)
+ ld (firex),hl ;set position to fire from
+ ld b,3 ;or use the proc at fireOK with ld ix,weapondata+2-(256*3)
+fire_weapon:
+ psh bc ;save counter
+ ld a,(ix) ;load this weapon
+ ld c,a ;save bulletType in c
+ and %11100000 ;%111?????=laser
+ cp %11100000 ;is it?
+ cal z,fire_laser ;fire laser (will set c=0 when done)
+ xor a ;<>0=bullet
+ cp c ;c<>0?
+ cal nz,fire_ybullet ;then fire bullet
+ inc ix ;otherwise fire next weapon
+ inc ix
+ pop bc ;weapon counter (do 3 weapons)
+ dnz fire_weapon
+
+fire_tail:
+ ld ix,extrabulletpos-1 ;extra bullet's position
+ ld hl,your_extra ;data
+ ld a,(hl)
+ or a
+ ret z
+ ld c,tailbeam ;tailbeam weapon data
+ dec a ;(your_extra)=1
+ jr z,fire_ybullet ;=tail
+ ld c,doublebeam ;up double data
+ ;(your_extra)=2 =double
+;-----fire BULLETs-----
+
+fire_ybullet: ;fire bullet type=C dam=(curweapdamage) at (firex/y)
+ ld hl,ybullets ;check for unused bullet
+ ld de,4
+ ld b,nrybuls
+find_ybullet:
+ ld a,(hl)
+ or a
+ jr z,found_ybullet ;0 = no bullet here
+ add hl,de
+ dnz find_ybullet ;look next bullet
+ ret ;none found, return don't fire
+
+found_ybullet:
+ ld (hl),c ;use the bullet and set correct bullet-type
+ inc hl ;@damage
+ ld (hl),1 ;set bullet damage
+curweapdamage =$-1
+ ld a,(firex) ;your x-pos
+ add a,5 ;place bullet in front of you
+ inc hl ;go to bullet-x
+ ld (hl),a ;set x
+
+ ld a,(firey) ;your y-pos
+ add a,(ix+1) ;place bullet at the middle of your ship
+ inc hl ;go to bullet-y
+ ld (hl),a ;set y
+
+ xor a
+ ld (weapincs),a ;reset damage
+ ret
+
+;-----fire LASER-----
+
+fire_laser:
+ ld b,0 ;overflow counter
+ ld hl,firex
+ ld d,(hl) ;d = your x-pos
+ inc hl
+
+ ld a,(hl) ;base y-coord (firey)
+ add a,(ix+1) ;at specified offset (most likely the middle)
+ ld e,a ;save laser-y in e
+ psh de ;save unmodified (x,y)
+ add a,a ;y*2
+ add a,a ;y*4
+ add a,a ;y*8
+ rl b ;b (=0) =b*2+overflow (if y>32 then bc=bc+256)
+ add a,a ;y*16 (width of screen)
+ rl b ;b=b*2+overflow (if y>64 then bc=bc+512)
+ inc a ;8 pixels to right (a=even so no overflow)
+
+ srl d ;X/2
+ srl d ;X/4
+ srl d ;X/8
+ add a,d ;a = (Y*16+X/8) mod 256 (c set on overflow)
+
+ jr nc,_nolc ;jump if no carry = no overflow = a<=255
+ inc b ;a>255 so increase bc by 256
+_nolc: ld c,a ;c = (Y*16+X/8) mod 256
+ ld hl,dispbuffer ;save-location
+ add hl,bc ;bc = Y*16+X/8: hl=screen address
+ ld a,15 ;128/8=16=screen width ** minus one (inc a ^^)
+ sub d ;minus x-start (d=X/8)
+ ld b,a
+drawlaser:
+ ld (hl),%11111111
+ inc hl ;Go to next byte
+ dnz drawlaser
+handle_laser:
+ pop de ;de=(firex): x-pos unmodified
+
+check_laserhits: ;de = (x,y)
+ psh ix
+ ld b,nrenemies ;check all enemies
+ ld hl,enemies+1 ;enemy#1+occ/hp00
+laserhits: ;hits with normal enemies
+ psh hl
+ ld a,(hl) ;occ+hp00
+ and %11 ;normal enemy occ = %11
+ cp %11
+ jr nz,nolashit ;no hit when enemy_occ <> 11
+
+ inc hl ;@type
+ cal find_sprite ;ix=sprite to enemy (hl)
+ inc hl ;@x
+ ld a,(hl) ;check x
+ sub d
+ jr c,nolashit ;no hit when enemy is left of you
+ inc hl ;@y
+ ld a,(hl) ;check y
+ sub e
+ jr z,enemy_lashit ;a-e=0 = laser on top line of enemy = hit
+ jr nc,nolashit ;a-e>0 = enemy above laser = no hit
+ dec a ;minus one
+ add a,(ix+1) ;add enemy height (according to sprite @ix)
+ jp m,nolashit ;a-e>0 = hit
+enemy_lashit:
+ ld a,(curweapdamage) ;damage
+ cal enemy_hit ;hl=enemy+y
+nolashit:
+ pop hl ;enemy+1
+ ld a,b ;psh bc
+ ld bc,enemysize
+ add hl,bc ;go to next enemy
+ ld b,a ;pop bc
+ dnz laserhits ;check all enemies
+ xor a
+ ld (weapincs),a ;reset damage
+ pop ix
+ ld c,a ;c=0
+ ret
+
+;------------------------ handle bullets ------------------------------------
+
+Handle_bullets:
+ ld hl,ybullets
+ ld b,nrybuls
+scan_bullets:
+ ld a,(hl) ;@bulletType
+ or a ;bulletType=0 >> no bullet
+ jp z,next_ybullet+2 ;skip pops (+2); jP for speed
+
+ psh bc ;bullet counter
+ psh hl ;save enemy+type
+ ld (temp1),hl ;needed for check_bullethits
+ inc hl ;@damage
+ ld c,(hl) ;damage
+ dec c ;c=damage-1
+ jp m,bullethitbullet ;damage<=0 (=no bullet)
+ inc hl ;@x
+
+;move_bullet
+ ld c,a ;c=type
+ and %11111 ;pixels to move
+ add a,(hl) ;a = X + (hl) to the right
+ sub 16 ;and 16 to the left (so -16..+15)
+ jr c,remove_bullet ;remove if x<0
+ cp 128
+ jr nc,remove_bullet ;or x>=128
+ ld (hl),a ;save new pos.
+ ld d,a ;d = X
+
+ inc hl ;@y-pos
+ ld a,c
+ cal _shracc ;%11100000->1110
+;Note: a _shracc procedure inside Nemesis itself would be 27 cycles faster
+ srl a ;%1110->111
+ dec a
+ jr z,bullet_noymove ;1=straight forward
+ dec a
+ jr z,bullet_up ;2=up
+ dec a
+ jr z,bullet_halfup ;3=1/2up
+ dec a
+ jr z,bullet_down ;4=down
+bullet_halfdown: ;5=1/2down
+ ld a,(timer)
+ rra ;carry once every other turn
+ jr c,bullet_noymove
+bullet_down:
+ ld a,(hl)
+ inc a
+ cp 55
+ jr z,bullet_noymove
+ ld (hl),a
+bullet_halfup:
+ ld a,(timer)
+ rra ;CF every other turn
+ jr c,bullet_noymove
+bullet_up:
+ ld a,(hl)
+ dec a
+ jr z,bullet_noymove
+ ld (hl),a
+bullet_noymove:
+ ld e,(hl) ;e = Y
+
+display_bullet:
+ dec hl ;@x
+ dec hl ;@damage
+ ld a,(hl) ;bullet damage=size
+ ld hl,bullettable ;pointer to first bullet
+ srl a
+ srl a ;per 4
+ ld b,0
+ ld c,a ;->16bit (de=a)
+ add hl,bc ;point to correct bullet offset
+ ld a,(hl) ;load bullet offset
+ ld c,a ;convert to 16bit (d=0)
+ ld ix,spr_bullet01 ;first sprite
+ add ix,bc ;add offset (go to correct sprite)
+
+ ld a,(ix) ;bullet x-size
+ ld (bulletxsize),a ;used at check_bullethits
+ ld a,(ix+1) ;bullet y-size...
+ ld (bulletysize),a ;...too
+
+ cal safeputsprite ;display bullet; DE used for check_bullethits
+
+ cal check_bullethits
+
+next_ybullet:
+ pop hl ;restore enemy+type
+ pop bc ;b=counter
+ ld de,4
+ add hl,de
+ dnz scan_bullets ;next bullet (loop)
+ ret
+
+remove_bullet:
+ pop hl ;enemy+type
+ ld (hl),0 ;dump this bullet!
+ jr next_ybullet+1 ;+1:skip pop hl at next_ybullet
+
+bullethitbullet: ;"bullet" just displaying a bullet hit
+ inc c ;restore damage (to -5..0)
+ jp z,remove_bullet ;if it's 0 remove it
+ inc c ;increase to next frame
+ ld (hl),c ;save new
+ ld a,c
+ neg ;make positive value (frame nr. 0..4)
+ add a,a ;*2
+ ld e,a
+ add a,a ;*4
+ add a,e ;*6
+ ld e,a
+ ld d,0 ;de=a
+ ld ix,spr_hit ;first hit sprite
+ add ix,de ;add frame nr*8 (goto correct sprite)
+ inc hl ;@x
+ ld d,(hl)
+ inc hl ;@y
+ ld e,(hl) ;load position into de
+ cal putsprite ;display hit-sprite
+ jr next_ybullet ;handle the other bullets
+
+;--------------------------- check bullethits -------------------------------
+
+check_bullethits: ;INPUT: de=X,Y; (temp1)=bullet
+ ld b,nrenemies
+ ld hl,enemies+1
+
+hit_enemies: ;Hits with normal enemies
+ psh bc ;enemy counter
+ psh hl
+
+ ld a,(hl)
+ and %11
+ cp %11
+ jr nz,nohit ;no hit when enemy_occ <> %11
+
+ inc hl ;enemy type
+ cal find_sprite ;set ix to the sprite of this enemy
+
+ inc hl ;@x
+ ld a,(hl) ;check x
+ sub d ;minus bullet x-position
+ ld b,a ;psh a
+ sub 5 ;minus bullet x-size
+bulletxsize =$-1
+ jp p,nohit ;miss
+ ld a,b ;pop a
+ add a,(ix) ;add enemy width
+ jp m,nohit ;miss
+
+ inc hl ;@y
+ ld a,(hl) ;check y
+ sub e ;minus bullet y-position
+ ld b,a ;psh a
+ sub 3 ;substract bullet height
+bulletysize =$-1
+ jp p,nohit ;nope, missed it
+ ld a,b ;pop a
+ add a,(ix+1) ;add enemy height
+ dec a ;minus one
+ jp m,nohit ;missed after all
+
+ ;---bullet hits enemy (auch-time!)---
+ psh hl
+ ld hl,0 ;@bulletType
+temp1 =$-2
+ inc hl ;@damage
+ ld a,(hl) ;damage to inflict on enemy
+ ld (hl),-(hitsprites+1);make this bullet exploding (damage = -5)
+ pop hl ;enemy+y
+ cal enemy_hit
+nohit:
+ pop hl
+ ld bc,enemysize
+ add hl,bc
+ pop bc
+ dnz hit_enemies ;check next enemy
+ ret
+
+enemy_hit: ;*in:a=damage;hl=enemy+y
+ add a,a ;a=damage to inflict
+ add a,a ;first 2 bits used for occ.
+ ld b,a
+
+ dec hl ;@x
+ dec hl ;@sprite+1
+ dec hl ;@sprite
+ dec hl ;@hp00 (occ)
+ ld a,(hl) ;load hp00
+ sub b ;decrease HP (if <0xx then c is set)
+ ld (hl),a ;save (no flag-changes)
+ dec hl ;@hp64; no change in c
+ ld a,(hl) ;load; no c-change
+ sbc a,0 ;if cf then decrease a
+ ld (hl),a ;save back the new value
+ ret nc ;if a>=0 then return, otherwise explode
+
+ inc hl ;goto occ again
+ ld (hl),%01 ;set to explode
+
+ ld a,(pickuptimer) ;counts enemies destroyed
+ dec a ;enough destroyed for a pickup?
+ psh af ;save flags and a=0
+ jr nz,pickupdone ;otherwise just explode
+ ld a,pickupfreq ;reset enemies counter
+pickupdone:
+ ld (pickuptimer),a ;save new enemiescounter value
+ inc hl ;@sprite (=explosionFrame)
+ ld (hl),0 ;explosionFrame 0 or enemy #0=pickup
+ pop af
+ cal z,place_enemy ;place pickup (enemy#=0=a cuz ZF)
+
+ ld hl,1 ;increase score by one
+ jp scoreInc ;+ret
+
+;--------------------------- level events -----------------------------------
+
+Level_event:
+ ld a,0 ;time to next event
+nextevent =$-1
+ dec a ;decrease counter
+ ld (nextevent),a ;store new value
+ ret nz ;hasn't reached zero yet: get outta here!
+
+ ld bc,0 ;enemy frequency (lvl)
+eventtime =$-2
+ cal Random
+ ld (nextevent),a ;set time to next event
+ ld hl,eventleft
+ dec (hl) ;update enemy-counter
+
+ ld a,(hl) ;look at counter
+ or a ;has it reached 0?
+ jp z,Next_level ;yes: level finished
+ dec a ;has it reached 1?
+ jr z,standby_event ;yes: wait until no enemies present/left
+ dec a ;has it reached 2?
+ jr z,place_boss ;yep: place the BigBossTM!
+ dec a ;has it reached 3?
+ jr nz,place_ranenemy ;nope: >3 = place an enemy
+ inc hl ;nextevent located behind eventleft
+ ld (hl),193 ;3: set delay for next boss to appear
+ ret ;don't place any more enemies
+
+standby_event:
+ ld b,nrenemies
+ ld hl,enemies+1-enemysize
+ ld de,enemysize
+ xor a
+chk_enemyleft:
+ add hl,de ;go to next enemy
+ cp (hl) ;0 = no enemy present
+ jr nz,enemyleft ;if enemy present (<>0) then quit checking
+ dnz chk_enemyleft ;loop for all enemies
+ ld hl,nextevent ;time 'til next event
+ ld (hl),157 ;next time to check is in 157 turns/frames
+ inc a ;no enemies left: place upgrade pickup
+ jr place_enemy ;place enemy #1(=a) = big pickup
+enemyleft:
+ ld hl,eventleft
+ inc (hl)
+ ret
+
+
+place_ranenemy:
+ ld hl,1 ;increase score by 1
+ cal scoreInc
+ ld bc,0 ;0..nrlvlenemies
+nrlvlenemies =$-1 ;=nr of enemies minus 1
+ cal Random ;random enemy b..b+c = 0..nrenemies-1
+ ld b,0
+ ld c,a ;bc=a
+ ld hl,lvlenemies
+ add hl,bc ;go to a random enemy
+ ld a,(hl) ;load enemy nr of this mysterious random enemy
+ jr place_enemy
+
+place_boss:
+ ld hl,(levelp) ;the leveldata (including the boss)
+ dec hl ;points to leveldata\boss\enemynr
+ ld a,(hl) ;load enemy# of boss
+
+place_enemy: ;places enemy #=a
+ psh af
+ ld hl,enemies+1-enemysize
+ ld bc,enemysize
+ xor a ;a=0
+chk_noenemy: ;find an unused (no) enemy
+ add hl,bc ;check next enemy
+ cp (hl) ;(hl) = 0 ??
+ jr nz,chk_noenemy ;jump if enemy present (non-0)
+ ex de,hl ;de=hl=usable enemy +1
+ pop af ;enemy# to place
+ cal findenemyspecs ;hl = enemy #a specs
+
+ dec de ;goto hp64 (before occ)
+ ldi ;set hp64
+ ldi ;set hitpoints+occ of enemy class
+ ld a,(hl)
+ .db $DD,$6F ;ld hx,a
+ ldi ;set sprite
+ ld a,(hl)
+ .db $DD,$67 ;ld lx,a
+ ldi ;set sprite + 1
+ ldi ;set x-position
+
+ ld a,(hl) ;load placeInfo
+ inc hl
+ dec a ;is it 1?
+ jr z,random_enemy ;yes: create random value <51 in a
+ dec a ;is it 2?
+ jr z,lure_enemy ;yes: create a 100% luring enemy
+ ;otherwise?
+halflure_enemy: ;yes (of course it is): pick one (50% lure)
+ ld a,(timer) ;look at frame-number
+ rra ;make random if odd frame nr.
+ jr nc,random_enemy ;1st possibility: random enemy
+lure_enemy: ;2nd possibility: luring enemy
+ ld a,(y) ;place at same y-pos as YOUR ship
+ jr ypos_OK
+random_enemy:
+ ld a,64-8 ;=57=screen height (8 is scorebar)
+ sub (ix+1) ;minus sprite height=bottom
+ ld c,b ;range=0 to...
+ ld b,a ;...57-y
+ cal Random ;random value on screen
+ypos_OK: ;random value successfully created
+ ld (de),a ;save y-position
+ inc de ;@movecounter
+ ldi ;set move-type
+ ld a,1 ;movecounter = 1
+ ld (de),a ;set
+ inc de ;@firecounter
+ ldi ;set time-to-1st-fire
+ ldi ;set firefreq
+ ldi ; " firetype
+ ret ;return
+
+;--------------------------- enemy fires ------------------------------------
+
+Enemy_fires: ;de = x,y; c = type; ix = enemy_sprite
+ ld hl,ebullets ;first bullet to check
+ ld b,nrebuls
+ dec d
+ dec d ;d = x of firing enemy minus 2
+
+ ld a,(ix+1) ;the height of the enemy firing this bullet
+ srl a ;halved
+ add a,e ;added to his y-position
+ ld e,a ;into e
+ dec e ;minus one (bullet height)
+
+enemy_fires_again: ;same but hl = first bullet possibly free
+ xor a
+find_ebullet:
+ cp (hl)
+ jr z,found_ebullet ;0 = not used
+ inc hl \ inc hl \ inc hl
+ dnz find_ebullet ;look next bullet
+ ret
+
+found_ebullet:
+ ld a,c
+ sub 6
+ jp c,bulletok ;type #0-5 = done (normal/diag)
+ or a
+ jr z,bulletaiming ;type #6 = aiming = type#2..5
+ dec a
+ jr z,bullettriple ;type #7 = triple
+ dec a
+ jr z,bulletdouble ;type #8 = double
+ dec a
+ jr z,bulletquad ;type #9 = quad
+ dec a
+ jr z,bulletdquad ;type #10 = double-quad
+ dec a
+ jr z,bulletran ;type #11 = random
+
+firesenemies: ;type #12 = mine / Dquad
+ ld a,(timer)
+ rra ;if odd turn (50% chance)
+ jr c,bulletdquad ;then fire 6x
+ ld a,bossenemy ;otherwise place enemy #[bossenemy]
+ jp place_enemy
+
+bulletran:
+ ld c,1
+ ld b,4
+ cal Random
+ ld (hl),a
+ jr _bulletok
+
+bulletdquad: ;type #10 = double-quad
+ cal bulletquad ;fire type #1 to 5
+ inc hl
+ ld a,e
+ sub 5
+ ld e,a ;offset 5 up
+ ld c,1 ;type #1 = normal
+ cal enemy_fires_again
+ inc hl
+ ld a,e
+ add a,10
+ ld e,a ;offset 10 down (5 total)
+ jr enemy_fires_again
+
+bulletquad: ;type #9 = quad
+ cal bullettriple ;fire type #1, 4 and 5
+ inc hl ;next bullet
+ ld c,2 ;type #2 = down
+ cal enemy_fires_again
+ inc hl
+ ld c,3 ;type #3 = up
+ jr enemy_fires_again
+
+bulletdouble: ;type #8 = double
+ dec e ;one up
+ ld c,1 ;type #1
+ cal bulletok ;fire bullet
+ inc hl ;next bullet position
+ inc e
+ inc e ;two px down
+ jr enemy_fires_again ;find and fire another bullet
+
+bullettriple: ;type #7 = triple
+ ld (hl),1 ;type #1 = normal
+ cal _bulletok ;fire
+ inc hl ;next bullet
+ ld c,4 ;type #4 = down 50%
+ cal enemy_fires_again
+ inc hl
+ ld c,5 ;type #5 = up 50%
+ jr enemy_fires_again
+
+bulletaiming: ;type #6 = aiming = type#2..5
+ ld a,(y)
+ sub e ;a = yourY-bulY = pixels bullet is above you
+ add a,10
+ jp p,bulletnotup ;jump when 10 pixels below you or higher
+ ld (hl),5 ;go slightly down
+ add a,10 ;10 to 20 pixels below you
+ jp p,_bulletok ;yes: all done.
+ ld (hl),3 ;otherwise move down even more
+ jr _bulletok
+bulletnotup:
+ ld (hl),1 ;normal bullet...
+ sub 20 ;...when...
+ jp m,_bulletok ;...10 pixels below you to 20 pixels above
+ ld (hl),4 ;bullet going slightly up...
+ sub 10 ;...when...
+ jr c,_bulletok ;...20 to 30 pixels above you
+ ld c,2 ;else (more than 30 pixels) move up more
+
+bulletok:
+ ld (hl),c ;set bullet direction
+_bulletok:
+ inc hl
+ ld (hl),d ;set x-pos
+ inc hl
+ ld (hl),e ;set y-pos
+ ret
+
+;----------------------------- enemy bullets --------------------------------
+
+Enemy_bullets:
+ ld hl,ebullets ;hl=bullet pointer
+ ld b,nrebuls ;number of bullets (or _possible_ bullets)
+handle_bullet:
+ psh bc
+ psh hl
+ ld a,(hl) ;load bulletType in a
+ or a ;bullet present?
+ cal nz,enemy_bullet ;non-0: handle bullet
+ pop hl ;enemy_bullet could've added one or two to hl
+ pop bc ;bullet counter
+ inc hl \ inc hl \ inc hl ;next bullet (3 bytes per bullet)
+ dnz handle_bullet ;loop for each and every bullet
+ ret
+
+enemy_bullet:
+ inc hl ;@x
+ ld d,(hl) ;check if it has reached the left side of scrn
+ bit 7,d ;x<0?
+ jr nz,remove_ebullet ;yes, remove bullet
+ dec d ;move one pixel left
+ dec d ;and another one (that makes 2)
+ ld (hl),d ;save new x-coordinate in (HL) and D
+ inc hl ;@y (BTW: x >= -2)
+ ld e,(hl) ;e=y
+
+ dec a
+ jr z,ebullet_common ;type 1: normal bullet
+ dec a
+ jr z,ebullet_down ;type 2: moving down
+ dec a
+ jr z,ebullet_up ;type 3: moving up
+
+ ld b,a ;save bulletType
+ ld a,(timer) ;load timer
+ rra ;half speed (CF set every other turn)
+ jr c,ebullet_common ;if bit then normal bullet
+
+ dec b
+ jr z,ebullet_down ;type 4: moving down 50%
+ ;type 5: moving up 50%
+ebullet_up:
+ dec e ;move up
+ jp m,ebullet_common ;y<top; don't save new value (so y=0)
+ ld (hl),e
+ jr ebullet_common
+ebullet_down:
+ inc e ;move down
+ ld a,e ;a=y too
+ cp 58-3 ;y>bottom?
+ jr z,ebullet_common ;then keep it there
+ ld (hl),e ;otherwise save new y
+
+ebullet_common:
+ ld ix,spr_bullete1 ;display enemy bullet
+ psh hl
+ cal putsprite
+ pop hl ;we'll need it again
+
+ebullet_hits:
+ ld a,(your_occ)
+ or a
+ ret nz ;0 = you're normal
+
+ ld a,(y) ;check y collision
+ sub (hl)
+ add a,6
+ ret m
+ cp 9
+ ret nc
+
+ dec hl ;check x
+ ld a,(x)
+ sub (hl)
+ add a,6
+ ret m
+ cp 9
+ ret nc
+
+ ld b,auch_bullet ;set damage-amount
+ psh hl
+ cal damage_you ;HIT!!
+ pop hl ;save hl to remove the bullet
+remove_ebullet:
+ dec hl ;points to bullettype again
+ ld (hl),0 ;bullet > unused
+ ret
+
+;--------------------------- handle enemies ---------------------------------
+
+Handle_enemies:
+ ld hl,enemies+1
+ ld b,nrenemies ;handle all enemies
+
+handle_enemy:
+ psh bc
+ psh hl
+
+ ld a,(hl)
+ and %11
+ jr z,next_enemy ;occ "no enemy" 00
+ dec a
+ jr z,exploding_enemy ;occ "exploding" 01
+
+normal_enemy:
+ ld c,a ;c = occ-1 = %10 (normal) or %01 (pickup)
+ inc hl ;@sprite
+ cal find_sprite
+
+ inc hl ;@x
+ ld d,(hl) ;x
+ inc hl ;@y
+ ld e,(hl) ;y
+
+ inc hl ;@movetype
+ cal moving_enemy
+ dec hl
+
+ ld a,e ;new y value
+ cp 57
+ jr c,enemyonscreenY ;=on screen
+ cp -20 ;moved off at top
+ ld e,0 ;reset to top
+ jr nc,enemyonscreenY
+ ld e,57 ;otherwise reset to bottom
+enemyonscreenY:
+ ld (hl),e ;store new y
+ dec hl ;@x
+
+ ld a,d ;new x value
+ cp 129 ;x<=128
+ jr c,enemyonscreenX ;=on screen
+ cp -7 ;x<=-8
+ jr c,remove_enemy ;=off screen
+enemyonscreenX:
+ ld (hl),d ;store new x
+ dec c ;is this a pickup? (c=%01 so ZF=1)
+ jr nz,check_enemyfire ;no, a normal enemy; let em fire
+ jr firing_done ;continue
+
+check_enemyfire:
+ ld bc,4 ;4x inc hl
+ add hl,bc ;@firecount
+ ld a,(hl) ;counter till next blast
+ dec a ;decrease it
+ ld (hl),a ;save new value
+ jr nz,firing_done ;finished if not reached 0 yet
+
+ inc hl ;@firefreq
+ ld a,(hl) ;=time 'til next blast
+ inc hl ;@firetype
+ ld c,(hl) ;in c
+ dec hl
+ dec hl ;@firecount again
+ ld (hl),a ;reset counter for next blast
+ psh de ;save registers for firing-use
+ cal Enemy_fires ;fires bullet
+ pop de ;restore (destroyed by Enemy_fires)
+firing_done:
+ cal putwidesprite ;display sprite @ix
+
+next_enemy:
+ pop hl
+ ld bc,enemysize
+ add hl,bc
+ pop bc
+ dnz handle_enemy
+ ret
+
+exploding_enemy:
+ inc hl
+ ld a,(hl)
+ cp 16
+ jr nz,keep_enemy ;remove when at last frame
+remove_enemy:
+ pop hl
+ ld (hl),$0000 ;bye bye enemy
+ jr next_enemy+1 ;continue AFTER pop hl (already done)
+keep_enemy:
+ inc a
+ ld (hl),a ;next frame
+ dec a ;1-16 -> 0-15
+ ld ix,spr_explosion ;base sprite
+ inc hl ;@x
+ cal explosion_stuff ;display explosion
+ jr next_enemy
+
+;--------------------------- moving enemies ---------------------------------
+
+moving_enemy:
+ dec d ;move left once
+ ld a,(hl) ;how does this enemy move?
+ and a
+ ret z ;0 = (1<)
+ ld b,a
+ ld a,(timer)
+ dec b
+ jr z,movetype_updown ;1 = (1<) up / down
+ dec b
+ jr z,movetype_vslow ;2 = (.25<)
+ dec b
+ jr z,movetype_slow ;3 = (.5 <)
+ dec b
+ jr z,movetype_lslow ;4 = (.75<)
+ dec b
+ jr z,movetype_fast ;5 = (1.5<)
+ dec b
+ jr z,movetype_vfast ;6 = (2 <)
+ dec b
+ jr z,movetype_slowlure ;7 = (1<) move y towards you 50%
+
+ inc d ;speed 0
+ dec b
+ jr z,movetype_lure ;8 = (0) move y towards you
+ dec b
+ jr z,movetype_slowlure ;9 = (0) lure 1/2 speed
+ dec b
+ jr z,movetype_fulllure ;10 = x+y towards you 1/2 speed
+ dec b
+ jr z,movetype_right ;11 = (.5>)
+ dec b
+ jr z,movetype_fright ;12 = (1>)
+
+movetype_right:
+ rra
+ ret c ;speed 0 50%
+movetype_fright:
+ inc d ;move right one px
+ ret
+
+movetype_fulllure:
+ rra
+ ret c ;50% speed
+ cal movetype_lure
+ ld a,(x)
+ cp d
+ jr c,movetype_vfast ;moves left (again)
+lure_right:
+ inc d ;move right
+ ret
+
+movetype_slowlure:
+ rra ;half the time
+ ret c
+movetype_lure:
+ ld a,110
+ cp d
+ jr nc,dothelurethingy
+ dec d ;x>109: move left
+dothelurethingy:
+ ld a,(y)
+ cp e
+ ret z ;don't move vertically if equal
+ jr c,lure_up ;below you then move up
+lure_down: ;above then move down
+ inc e
+ ret
+lure_up:dec e
+ ret
+
+movetype_smart:
+ inc hl ;@movecount
+ ld a,(hl)
+ inc a
+ and %1111
+ ld (hl),a
+
+ or a ;reset carry flag
+ dec hl ;reset hl to <y>
+ and %11111100
+ jr z,movetype_fast
+
+movetype_lslow:
+ and %11
+ ret nz
+ inc d ;don't move 25% of the time
+ ret
+movetype_slow:
+ rra
+ ret c
+ inc d ;don't move 50%
+ ret
+movetype_vslow:
+ and %11
+ ret z
+ inc d ;don't move 75%
+ ret
+
+movetype_fast:
+ rra
+ ret c ;once every other turn
+movetype_vfast:
+ dec d ;move left twice
+ ret
+
+movetype_updown:
+ inc hl ;@movecount
+ ld a,(hl)
+ dec a
+ and 127 ;range 0..127
+ ld (hl),a ;store new movecounter
+ dec hl ;reset hl to @movetype
+ and %00100000 ;ZF changes once every 64 turns
+ ld a,e ;load current y-position
+ jr z,movedown
+moveup: dec a ;decrease y-pos (=move up)
+ ret m ;don't move off the screen (y<0)
+ dec e ;save new y-pos
+ ret ;finish
+movedown:
+ inc a ;increase y-pos
+ cp 55 ;compare with bottom
+ ret nc ;return if it has passed that line (>40)
+ inc e ;otherwise save new position
+ ret ;and return
+
+;--------------------------- check collision --------------------------------
+
+Enemies_hit:
+ ld hl,(x) ;e = X, d = Y
+ ld de,$0707 ;add 7 to both d and e
+ add hl,de
+ ex de,hl ;e = X+7, d = Y+7
+
+ ld hl,enemies+1
+ ld b,nrenemies ;check all 20 enemies
+check_collision:
+ psh bc ;counter
+ psh hl ;pointer
+ ld a,(hl)
+ and %10 ;enemy status (%11=normal; %10=pickup)
+ jr z,check_next ;2 or 3 = ok, otherwise: next enemy
+ inc hl ;@sprite
+
+collide_enemy: ;&&& include in Handle_enemy proc
+ cal find_sprite
+
+ inc hl ;@x
+ ld a,(hl) ;check x match
+ sub e ;enemy position minus yours minus 7
+ jp p,check_next
+ add a,6
+ add a,(ix) ;enemy width
+ jp m,check_next
+
+ inc hl ;@y
+ ld a,(hl) ;check y match
+ sub d ;same as with x-check
+ jr nc,check_next ;(=jp p)
+ add a,6
+ add a,(ix+1) ;enemy height
+ jp m,check_next
+ dec hl ;@x
+ dec hl ;@sprite+1
+ dec hl ;@sprite
+ dec hl ;@occ
+
+take_pickup:
+ ld a,(hl) ;load enemy occ
+ rra ;if occ = %10 (can't be %00) then pickup
+ jr c,collide ;otherwise normal enemy so you collide
+ ld (hl),0 ;remove
+ rra ;skip this bit (=%1)
+ rra ;this bit specifies the pickup ID (big/small)
+ jr nc,armorpickup ;%0 = pickup increases armor and shield
+ ;%1 = pickup selects (next) upgrade
+ ld hl,your_pickup ;your pickups
+ ld a,(hl) ;current
+ inc a ;go to next
+ cp 4 ;pickups >=4?
+ jr c,not_maxpickup
+ psh hl ;too much pickups
+ ld hl,250
+ cal scoreInc ;increase score by 250
+ pop hl
+ ld a,1 ;and reset to pickup #1
+not_maxpickup:
+ ld (hl),a ;save new
+ psh de
+ cal disp_icons ;display altered pickupicons
+ pop de ;ld de,$0707
+ jr check_next ;all done, next..
+
+armorpickup:
+ cal inc_armor ;increase armor (like at end of level)
+ ld a,30 ;activate shield for 30*4=120 frames
+ ld (your_shield),a
+ cal disp_icons ;display status bar (new armor value)
+ jr check_next
+
+collide:
+ ld a,(hl)
+ sub auch_ecollide
+ ld (hl),a
+ jr nc,enemydamaged ;enemy still ok (HP>=0)
+ ld (hl),%01 ;set to explode
+ inc hl
+ ld (hl),0 ;explosionFrame 0
+enemydamaged: ;damage to enemy delivered
+ ld b,auch_collide ;your damage
+ cal damage_you
+
+check_next:
+ pop hl ;current enemy base (unaltered)
+ ld bc,enemysize ;bytes per enemy
+ add hl,bc ;pointer to next enemy
+ pop bc ;restore counter
+ dnz check_collision ;loop for all enemies
+ ret
+
+;--------------------------- story ------------------------------------------
+
+storyPage:
+ psh hl ;hl will be destroyed by _clrLCD
+ cal _clrLCD ;clear screen
+ pop hl
+ ld a,(hl)
+ ld (curline),a ;begin line for special effect
+storyLine:
+ ld d,(hl) ;vertical position of text
+ inc hl
+ ld e,(hl) ;horizontal text-position
+ ld (_penCol),de ;set position
+ inc hl
+ cal _vputs ;display text
+
+ ld a,(hl) ;load next byte
+ inc hl
+ or a ;0 means more text
+ jr z,storyLine ;loop if there is
+
+ psh af
+ psh hl
+ ld hl,VIDEO_MEM ;copy text
+ ld de,dispbuffer ;to GRAPH_MEM
+ ld bc,1024 ;entire screen
+ ldir
+ cal _clrLCD ;clear VIDEO_MEM
+ pop hl
+ pop bc ;last byte (<>0) is lines to SFX
+ psh hl
+ cal DoSFX ;do special effects
+ cal getsomekeys ;wait for a key
+ pop hl
+ ret
+
+dostory:
+ cal storyPage ;do some story
+ ld a,(hl) ;load next byte in a
+ inc a ;set z-flag if a = $ff
+ jr nz,dostory ;otherwise loop
+ inc hl
+ inc hl ;set hl to beginning of the level
+ ld (levelp),hl ;set the level-pointer
+ ret ;and return