#!/usr/bin/perl
use 5.014;
my ($file, $size) = @ARGV;

my @info = eval {
	require Image::ExifTool;
	my $exif = Image::ExifTool->new->ImageInfo($file, {
		CoordFormat => '%.5f',
		DateFormat => '%Y-%m-%d %H:%M:%S',
	});
	die "exiftool: $exif->{Error}\n" if $exif->{Error};
	return (
		$exif->{MIMEType},
		$exif->{ImageSize} ? "$exif->{ImageSize} ($exif->{Megapixels}MP)" : (),
		join(' ',
			$exif->{YCbCrSubSampling} // (),
			$exif->{Interlace} // (),
			$exif->{Compression} // $exif->{FileType},
			$exif->{SVGVersion} // $exif->{PDFVersion} // (),
		),
		$exif->{ColorType} ? "$exif->{BitDepth}bpp $exif->{ColorType}" : (),
		sprintf('exif x%d', scalar %{$exif}),
		$exif->{Thumb} ? "thumb $exif->{ThumbnailLength}B" : (),
		(map "@ $_",
			$exif->{DateTimeOriginal} //
			$exif->{DateCreated} //
			$exif->{CircaDateCreated} //
			$exif->{ModifyDate} //
			$exif->{ZipModifyDate} //
			(),
		),
		join(', ',
			$exif->{GPSPosition} // $exif->{Location} // (),
			$exif->{GPSAltitude} // (),
		),
		(map "hw $_", join(' ',
			$exif->{Make} // (), $exif->{Model} // (),
			$exif->{FOV} ? "(FOV $exif->{FOV})" : (),
		) || ()),
		(map "sw $_", $exif->{Software} // $exif->{Application} // ()),
		(map "> $_", $exif->{'Description-nl'} // ()),
		$exif->{Warning} ? "! $exif->{Warning}" : (),
	);
};
warn $@ if $@;

my $filesize = (stat $file)[7];
eval {
	require Digest::MD5;
	open my $bin, '<', $file;
	binmode $bin;
	my $md5 = Digest::MD5->new->addfile($bin)->b64digest;
	push @info, "# $md5 ($filesize)";
} or warn $@;

open my $pgm, '-|', convert => (
	$file =>
	-delete => '1--1',
	'+distort' => SRT => '0,0 1,.56 0',
	-thumbnail => $size || '40x12',
	-colorspace => 'gray',
	'-normalize',
	-background => 'black',
	-layers => 'flatten',
	-compress => 'none',
	'pgm:-'
) or die $!;

if (<$pgm> eq "P2\n") {
	my ($width, $height) = split ' ', <$pgm>;
	<$pgm>;  # ignore depth
	my @ch = split //, " .:oO@";
	while (<$pgm>) {
		print $ch[ $_ * @ch >> 8 ] for /\d+/g;
		print ' ', shift @info if @info;
		print $/;
	}
	substr $_, 0, 0, ' ' x ($width + 1) for @info;
}
say for @info;