termimg

   1 #!/usr/bin/perl
   2 use 5.014;
   3 my ($file, $size) = @ARGV;
   4
   5 my @info = eval {
   6         require Image::ExifTool;
   7         my $exif = Image::ExifTool->new->ImageInfo($file);
   8         return (
   9                 " $exif->{MIMEType}",
  10                 $exif->{ImageSize} ? " $exif->{ImageSize} ($exif->{Megapixels}MP)" : (),
  11                 join(' ', '',
  12                         $exif->{YCbCrSubSampling} // (),
  13                         $exif->{Interlace} // (),
  14                         $exif->{Compression} // $exif->{FileType},
  15                         $exif->{SVGVersion} // $exif->{PDFVersion} // (),
  16                 ),
  17                 $exif->{ColorType} ? " $exif->{BitDepth}bpp $exif->{ColorType}" : (),
  18                 sprintf(' exif x%d', scalar %{$exif}),
  19                 $exif->{Thumb} ? " thumb $exif->{ThumbnailLength}B" : (),
  20                 (map " @ $_",
  21                         $exif->{DateCreated} //
  22                         $exif->{CircaDateCreated} //
  23                         $exif->{ModifyDate} //
  24                         $exif->{ZipModifyDate} //
  25                         (),
  26                 ),
  27                 $exif->{GPSPosition} ?  " $exif->{GPSPosition}" =~ s/ deg/./gr :
  28                 $exif->{Location} ? " $exif->{Location}" : (),
  29                 $exif->{GPSAltitude} ? " $exif->{GPSAltitude}" : (),
  30                 (map " hw $_", join(' ',
  31                         $exif->{Make} // (), $exif->{Model} // (),
  32                         $exif->{FOV} ? "(FOV $exif->{FOV})" : (),
  33                 ) || ()),
  34                 (map " sw $_", $exif->{Software} // $exif->{Application} // ()),
  35                 (map " > $_", $exif->{'Description-nl'} // ()),
  36                 $exif->{Warning} ? " ! $exif->{Warning}" : (),
  37         );
  38 } or warn $@;
  39
  40 eval {
  41         require Digest::MD5;
  42         open my $bin, '<', $file;
  43         binmode $bin;
  44         my $md5 = Digest::MD5->new->addfile($bin);
  45         push @info, ' # '.$md5->b64digest;
  46 } or warn $@;
  47
  48 open my $pgm, '-|', convert => (
  49         -compress => 'none',
  50         '+distort' => SRT => '0,0 1,.56 0',
  51         -thumbnail => $size || '66x23',
  52         $file => 'pgm:-'
  53 ) or die $!;
  54
  55 if (<$pgm> eq "P2\n") {
  56         my ($width, $height) = split ' ', <$pgm>;
  57         <$pgm>;  # ignore depth
  58         my @ch = split //, " .:coO@";
  59         while (<$pgm>) {
  60                 print $ch[ $_ * @ch >> 8 ] for /\d+/g;
  61                 say shift @info;
  62         }
  63         substr $_, 0, 0, ' ' x $width for @info;
  64 }
  65 say for @info;